home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format CD 42 / Amiga Format AFCD42 (Issue 126, Aug 1999).iso / -serious- / hardware / whichamiga / whichamiga.asm < prev    next >
Assembly Source File  |  1999-05-17  |  111KB  |  5,366 lines
  1. ; FILE: Source:WhichAmiga.ASM          REV: 772 --- Identify which Amiga model you're running
  2. ; Hist
  3. ; 0-17    Prehistoric revisions. Working hard(?) 19.7.95.
  4. ;  18     Fixed a bug, it would have caused an enforcer hit under
  5. ;         KS 1.3. ;-)
  6. ;  30     Added Workbench startup.
  7. ;  41     Machine evaluation works.
  8. ;  47     Added more machine formulas about 3.00 AM 20.7.95.
  9. ;  52     Added waterproof A3000 check (ramsey&gary test). Fixed machine
  10. ;         formulas. Fixed CD³² KS version to V40.
  11. ;  57     Added FindConfigDev routine. Added A2500 and A500old.
  12. ;  71     Added all machine formulas.
  13. ;  74     Fixed MMU disable/enable as much as possible.
  14. ;  93     Aaargh! Movec with TC doesn't work! Use pmove.l (an) instead!!
  15. ;  96     GetCPU surrounded with DisableMMU/EnableMMU pair.
  16. ; 97-148  MUCH improved.
  17. ;  149    Added better console output code for running under V37 or better.
  18. ;         CD³² users aren't forced to press return anymore... :- )
  19. ;  183    Added correct 68EC020 test.
  20. ;  197    Added real 68060 test and fixed MMU codes.
  21. ;  214    Fixed 68060 test and MMU codes.
  22. ;  228    Bug?: Sometimes can't disable MMU!?
  23. ;  275    Fixed MMU code a *lot*! Now display is blanked when display doesn't
  24. ;         have 4x bandwidth. Now WhichAmiga works with Enforcer, CPU FASTROM and
  25. ;         VMM etc.
  26. ;  281    Now checks cardslot via hardware.
  27. ;  282    Added test for stock model Walker.
  28. ;  301    Added display for Paula, Ramsey, Gary and Gayle. Now checks IDE
  29. ;         connection via hardware.
  30. ; 302-304 Added DraCo support.
  31. ;  305    A4000 also has Ramsey chip, but no Gary chip! (I guess!)
  32. ;  309    Now should be 100% HW  i ndependent, if needed (DraCo!) 
  33. ;  313    Added display for Akiko.
  34. ;  328    Really fixed GetAddressBits and moved all VMEM critical code
  35. ;         into CODE_C hunk.
  36. ;  331    Real support for DraCo... It wouldn't have worked...
  37. ;  333    Fixed CDTV test.
  38. ;  347    Tried to fix 68040/060 MMU code as much as possible.
  39. ;  364    A3000 and A4000 have both Ramsey and Gary, A4000 has Ramsey rev $F.
  40. ;  371    Few things added/fixed.
  41. ;  377    Fixed bad 040/060 MMU test.
  42. ;  384    Added very flexible CPU/FPU/MMU support.
  43. ;  427    Added support for boards.library and several gfx boards.
  44. ;  459    Rewritten MMU disable/enable code.
  45. ;  462    Added correct 68060 speed index.
  46. ;  466    Added special support for Blizzard boards' MAPROM.
  47. ;  471    Doesn't turn off write allocate... Turns on BERR timeout if Gary
  48. ;         chip is present.
  49. ;  482    Added (hopefully) correct 68040/68060 MMU code.
  50. ;  486    Whops! Turned on BERR not DSACK! :-\
  51. ;  499    Added some extensive debug stuff...
  52. ;  514    Fixed bug in 68040/68060 MMU test code.
  53. ;  512    Finally works with 060 (and 040 too :). Fixed to test bit 15 of
  54. ;         TC in MMU activity test on 040 and 060.
  55. ;  529    Fixed Ramsey&Gary test. Added other graphics systems.
  56. ;  535    Now adjusts comparisation CPU automagically.
  57. ;  538    Fixed A3000 machine formula to accept any ECS agnus.
  58. ;  543    Separated Ramsey and Gary test. Added correct KS 3.2 version
  59. ;         information.
  60. ;  547    Fixed loads of OldOpenLibrary, lea (LibList,a6), (ThisTask,a6)...
  61. ;         Cached SysBase etc.
  62. ;  560    Added SetPatch version info.
  63. ;  561    Fixed CloseLibrary(0) bug. Crashed on pre-36 kickstarts.
  64. ;  562    Added identification for UAE and phase5's PowerUP boards.
  65. ;  566    Added proper identification for PowerUP boards.
  66. ;  569    Added support for GigaMem (Max Virtmem).
  67. ;  578    Fixed "CNOP 0,4 in code" bug.
  68. ;  591    Fiddled a bit with 030 MMU code. Fixed UAE detection. Added
  69. ;         6 new gfxcards. Added display for sound cards. 7 sound cards
  70. ;         detected as of now.
  71. ;  596    Added support for CyberGraphX V3.
  72. ;  608    Fiddled again with 030 MMU code. This time I found a bug from it :)
  73. ;         Also tried to fix Ramsey & Gary code.
  74. ;  616    Fixed A3000/A4000 (=Ramsey&Gary) test (hopefully!)
  75. ;  619    Hopefully _finally_ fixed 030 MMU test for defective 68030 chips.
  76. ;         Thanks to [Angel] for testing!
  77. ;  626    Fixed A4000T rom version.
  78. ;  631    Really fixed A4000 test. For some reason my AGA test required rev
  79. ;         13 Gayle chip to be present. Uh-oh.
  80. ;  632    Fixed A1000 ROM version because it can be changed.
  81. ;  633    Hopefully fixed UAE detection.
  82. ;  644    Defective 68030 MMU test (hopefully) fixed.
  83. ;  645    Added Delfina LITE sound card.
  84. ;  646    retina.library is bad... Added check for Retina boards. Thanks to
  85. ;         Hurtman for the tip.
  86. ;  653    Added hardware clock detection. Suggested by Hurtman.
  87. ;  654    Removed one A500 board from A2000 expboardslist. Removed GVP kludge.
  88. ;  655    Removed two A500/A2000 boards from A500 list. Added one (hopefully)
  89. ;         A2000 only board. Thanks to pyksy.
  90. ;  656    Finally got ppc.library autodocs&includes. Fixed PowerPC CPU version
  91. ;         display.
  92. ;  744    13th May 1998: Made the source public in hope someone would continue
  93. ;         the development. At least you can find some interesting routines from
  94. ;         here. ;)
  95. ;  748    Fixed PPC detection, now support for multiple PPC cpus & fixed 604e
  96. ;         not to show as '?'. Fixed some minor bugs.
  97. ;  753    Fixed pre-SetPatch 060 test.
  98. ;  755    Added brand new 0x0 MHz calculation. Should work well with all 0x0
  99. ;         systems.
  100. ;  760    Fixed some bugs. Added PPL display to ppc processor display. Added
  101. ;         revision display for 060. Added Blizzard PPC serial number display.
  102. ;  762    Added CyberVision PPC to gfxboard list.
  103. ;  772    2nd May 1999: Fixed ppc revision display + now displays busclock MHz
  104. ;         instead of PPL number.
  105. ;
  106.  
  107.     IFGT    0
  108.  
  109. Found this inside ppc.library : =)
  110.  
  111.                         PowerUP                         
  112. Now you hold it in your hands which took a lot sweat,   
  113. internal Phase5 conflicts and the lack of motivation    
  114. devil made his appearance several times during the      
  115. 2 years this project was ...running...                  
  116.  
  117. ...a product which goals were changed several times     
  118. until it was released.                                  
  119.  
  120. PowerUP/Phase5 project history censored and deleted.    
  121.  
  122. ppc.library by Ralph Schmidt                            
  123. SW/HW Debugging and food supply by Gerald Carda         
  124. Debugging,Suggestions and mental support by Frank Mariak
  125. Debugging and some examples by Andre Osterhues          
  126.  
  127. Private Greetings are going to:
  128. Dirk Leschner, Arne Meier, Matthias Scheler and all my  
  129. Innernet-#grapevine friends
  130.  
  131.  
  132.  
  133.  A3000:
  134.  
  135.  CHIPS:
  136.   Denise - 8373 SuperDenise
  137.   Paula  - Standard Paula
  138.   Agnus  - 8372B Agnus for 2 meg CHIP RAM
  139.   Gary   - Fat Gary
  140.   Amber  - De-interlacing chip to provide 31KHz video
  141.   Buster - SuperBuster -07, -09 and -11
  142.   DMAC   - SuperDMAC -02, -04
  143.   Ramsey - Ramsey -04 and -07
  144.  
  145.                           -===- Amiga 4000/040 -===-
  146.  
  147.     Processor : Motorola 68040 / 25Mhz
  148.  Custom Chips : (6): Super Gary, Super Ramsey, Super Amber, Lisa, Alice,
  149.                      Paula.
  150.           RAM : 6mb Ram [2mb Chip/ 4mb Fast]
  151.  
  152.  
  153.     ENDC
  154. ; TODO:
  155. ; o Add CGFX4 BlizzardVision PPC to gfxboard list
  156. ; o Fix FPU speed calculation and enable it
  157. ; o Add WarpOS support
  158. ; o Fix bugs...
  159.  
  160. ; BUGS:
  161. ; o Crashes on GVP 1230!! (works sometimes) ;-((  *KLUDGEFIXED*
  162. ; o No support for:
  163. ; Amber / Super Amber    ECS
  164. ; Buster        Zorro III DMA Controller
  165. ; SuperIO        "Walker project"
  166. ; Super Agnus (8375)    2MB chip PLCC A500+
  167. ; Portia        A1000
  168. ; Daphne        A1000
  169. ; 
  170.  
  171. ; Compiling options:
  172.  
  173. WA_USE_INCLUDES    SET    1    ; 0=Use my custom system, 1=Use standard includes
  174. WA_DEBUG    SET    1    ; 0=No debug, 1=Enable debug mode
  175.  
  176.  
  177.  
  178.  
  179.     IFEQ    WA_USE_INCLUDES
  180.     include    "Devpac:Gen.gs"
  181.     ELSE
  182.     include    "exec/memory.i"
  183.     include    "exec/exec_lib.i"
  184.     include    "dos/dos_lib.i"
  185.     include    "libraries/graphics_lib.i"
  186.     IFND    MYMACROS_I
  187. call    MACRO
  188.     jsr (_LVO\1,a6)
  189.     ENDM
  190.     ENDC
  191.     ENDC
  192.     include    "exec/execbase.i"
  193.     include    "libraries/expansion_lib.i"
  194.     include    "libraries/configvars.i"
  195.     include    "libraries/configregs.i"
  196.     include    "dos/dosextens.i"
  197.     include    "graphics/gfxbase.i"
  198.     IFEQ    WA_USE_INCLUDES
  199.     include    "hardware/demo.i"
  200.     ELSE
  201.     include    "hardware/cia.i"
  202.     include    "hardware/custom.i"
  203.     ENDC
  204.     include    "hardware/intbits.i"
  205.     include    "hardware/dmabits.i"
  206. ;    include    "libraries/boards.i"
  207. ;    include    "libraries/boards_lib.i"
  208.  
  209.  
  210.     include    "powerup/ppclib/ppc.i"
  211. _LVOPPCGetInfo    EQU    -$8A
  212.  
  213.     IFND    _LVOBestCModeIDTagList
  214. _LVOBestCModeIDTagList    EQU    -$3C
  215.     ENDC
  216.     IFND    CYBRBIDTG_MONITORID
  217. CYBRBIDTG_MONITORID    EQU    $80050003
  218.     ENDC
  219.  
  220.  
  221.     IFND    ciacra
  222. ciapra    EQU    PRA
  223. ciaprb    EQU    PRB
  224. ciaddra    EQU    DDRA
  225. ciaddrb    EQU    DDRB
  226. ciatalo    EQU    TALO
  227. ciatahi    EQU    TAHI
  228. ciatblo    EQU    TBLO
  229. ciatbhi    EQU    TBHI
  230. ciatodlow    EQU    TODLO
  231. ciatodmid    EQU    TODMID
  232. ciatodhi    EQU    TODHI
  233. ciasdr    EQU    SDR
  234. ciaicr    EQU    ICR
  235. ciacra    EQU    CRA
  236. ciacrb    EQU    CRB
  237.     ENDC
  238.     IFND    CIAB
  239. CIAB    EQU    $BFD000
  240.     ENDC
  241.     IFND    AFB_68060
  242. AFB_68060    EQU    7
  243. AFF_68060    EQU    1<<AFB_68060
  244.     ENDC
  245. _LVOAddICRVector EQU    -$6
  246. _LVORemICRVector EQU    -$C
  247. _LVOAbleICR    EQU    -$12
  248. _LVOSetICR    EQU    -$18
  249.  
  250. _LVOFreeNVData    EQU    -$24
  251. _LVOGetNVInfo    EQU    -$36
  252.  
  253. INFINITE    EQU    $7FFFFFFF
  254. MINUS_INFINITE    EQU    $80000000
  255.  
  256. ID_UNIX_DISK    EQU    ('U'<<24)!('N'<<16)!('I'<<8)!(1)
  257.  
  258.  
  259. MC68000    EQU    0
  260. MC68010    EQU    1
  261. MC68EC020    EQU    2    24bit ab
  262. MC68020    EQU    3    32bit ab
  263. MC68EC030     EQU    4    no mmu
  264. MC68030    EQU    5    mmu
  265. MC68EC040     EQU    6    no mmu, no fpu
  266. MC68LC040     EQU    7    mmu, no fpu
  267. MC68040    EQU    8    mmu, fpu
  268. MC68EC060     EQU    9    no mmu, no fpu
  269. MC68LC060     EQU    10    mmu, no fpu
  270. MC68060    EQU    11    mmu, fpu
  271.  
  272. ;;MPC603e    EQU    12    \
  273. ;;MPC604    EQU    13     } not yet implemented, but supported
  274. ;;MPC620    EQU    14    /
  275.  
  276.  
  277. MIN020    EQU    MC68EC020
  278. MAX020    EQU    MC68020
  279. MIN030    EQU    MC68EC030
  280. MAX030    EQU    MC68030
  281. MIN040    EQU    MC68EC040
  282. MAX040    EQU    MC68040
  283. MIN060    EQU    MC68EC060
  284. MAX060    EQU    MC68060
  285. MAXCPU    EQU    INFINITE
  286.  
  287. NOMATH    EQU    0
  288. MC68881    EQU    1
  289. MC68882    EQU    2
  290. MC68040i    EQU    3
  291. MC68060i    EQU    4
  292. MINFPU    EQU    MC68881
  293. MAXFPU    EQU    INFINITE
  294.  
  295. NOMMU    EQU    0
  296. MC68851    EQU    1
  297. MC68030m    EQU    2
  298. MC68040m    EQU    3
  299. MC68060m    EQU    4
  300. MINMMU    EQU    MC68851
  301. MAXMMU    EQU    INFINITE
  302.  
  303. DBG    MACRO    *id
  304.     IFNE    WA_DEBUG
  305.     move.l    #\1,-(sp)
  306.     jsr    _dp
  307.     ENDC
  308.     ENDM
  309.     IFNE    WA_DEBUG
  310. _DBUGMAIN    jmp    __MAIN
  311. _dp    bra.b    .exit
  312.     btst    #INTB_INTEN-8,$DFF000+intenar
  313.     beq.b    .exit
  314.     btst    #INTB_PORTS,$DFF000+intenar+1
  315.     beq.b    .exit
  316.     movem.l    d0-a6,-(sp)
  317.     move.l    (4).w,a6        No need...
  318.     clr.l    -(sp)
  319.     move.l    (8*4+7*4+4+4,sp),-(sp)
  320.     move.l    sp,-(sp)
  321.     lea    (LibList,a6),a0        No need...
  322.     lea    (.dosname,pc),a1
  323.     call    FindName
  324.     move.l    d0,a6
  325.     lea    (.fmt,pc),a0
  326.     move.l    a0,d1
  327.     addq.l    #1,-(a0)
  328.     move.l    (a0),-(sp)
  329.     move.l    sp,d2
  330.     call    VPrintf
  331.     call    Output
  332.     move.l    d0,d1
  333.     call    Flush
  334.     moveq    #10,d1
  335.     call    Delay
  336.     lea    (4*4,sp),sp
  337.     movem.l    (sp)+,d0-a6
  338. .exit    move.l    (sp)+,(sp)
  339.     rts
  340.     CNOP    0,4
  341. .cnt    dc.l    0
  342. .fmt    dc.b    'DEBUG %ld: %4s',10,0
  343. .dosname    dc.b    'dos.library',0
  344.  
  345.     SECTION    DREALMAIN,CODE
  346.     ENDC
  347. __MAIN
  348.  
  349.     IFGT    0
  350.     lea    (.init,pc),a0
  351.     lea    (.rout,pc),a1
  352.     lea    (.cleanup,pc),a2
  353.     jsr    TimeRoutine
  354.     rts
  355.  
  356. .init    move.l    (4).w,a6
  357.     call    Disable
  358.     rts
  359. .rout    move.l    #$1000,d0
  360. .loop    subq.l    #1,d0
  361.     bne.b    .loop
  362.     rts
  363. .cleanup    move.l    (4).w,a6
  364.     call    Enable
  365.     rts
  366.     ENDC
  367.  
  368. ;    include    "Source:WBStartUp.ASM"
  369.  
  370. ; WBStartUp code
  371.  
  372. startupcode    move.l    (4).w,a6
  373.     move.l    d0,d2
  374.     move.l    a0,a2
  375.     sub.l    a1,a1
  376.     jsr    (-$126,a6)    ;FindTask
  377.     move.l    d0,a4
  378.  
  379.     tst.l    ($AC,a4)    ; pr_CLI
  380.     bne.s    .main
  381.  
  382.     lea    ($5C,a4),a0    ; pr_MsgPort
  383.     jsr    (-$180,a6)    ;WaitPort
  384.     lea    ($5C,a4),a0    ; pr_MsgPort
  385.     jsr    (-$174,a6)    ;GetMsg
  386.     move.l    d0,-(sp)
  387.     sub.l    a0,a0
  388.     bsr.b    .main
  389.     move.l    d0,d2
  390.  
  391.     move.l    (4).w,a6
  392.     jsr    (-$84,a6)    ;Forbid
  393.     move.l    (sp)+,a1
  394.     jsr    (-$17A,a6)    ;ReplyMsg
  395.  
  396.     move.l    d2,d0
  397.     rts
  398.  
  399. .main    move.l    d2,d0
  400.     move.l    a2,a0
  401.     ; a6=execbase
  402.     ; a4=thistask (FindTask()'d! :)
  403.  
  404.  
  405. MAINMAIN    clr.b    -1(a0,d0.l)
  406.     move.l    a0,_Args
  407.     move.l    a4,_ThisTask
  408.     lea    (ExecBase00,pc),a0
  409.     move.l    a6,(a0)
  410.     lea    (__MAIN-4,pc),a0
  411. .eloop    move.l    (a0),d0
  412.     beq.b    .edone
  413.     lsl.l    #2,d0
  414.     move.l    d0,a0
  415.     move.l    a6,(4,a0)
  416.     bra.b    .eloop
  417. .edone
  418.     tst.l    (pr_CLI,a4)
  419.     seq    WBMode
  420.     cmp.w    #36,(LIB_VERSION,a6)
  421.     shi    NewKick
  422.  
  423.     IFNE    WA_DEBUG
  424.     cmp.w    #37,(LIB_VERSION,a6)
  425.     blo.b    .db_exit
  426.     tst.b    WBMode
  427.     bne.b    .db_exit
  428.     move.l    _Args,a0
  429.     tst.b    (a0)
  430.     beq.b    .db_exit
  431.     move.w    #$4E71,_dp        Enable debug stuff!
  432.     call    CacheClearU
  433. .db_exit
  434.     ENDC
  435.  
  436.     lea    (DosName,pc),a1
  437.     moveq    #0,d0
  438.     call    OpenLibrary
  439.     move.l    d0,_DosBase
  440.     beq.b    .fail
  441.     move.l    d0,a5
  442.  
  443.     exg    a5,a6
  444.     call    Output
  445.     tst.b    WBMode
  446.     bpl.b    .cli
  447.     lea    (ConsoleName,pc),a0
  448.     tst.b    NewKick
  449.     bpl.b    .is_old
  450.     lea    (NewConsoleName-ConsoleName,a0),a0
  451. .is_old    move.l    a0,d1
  452.     move.l    #MODE_READWRITE,d2
  453.     call    Open
  454. .cli    move.l    d0,OutputFH
  455.     exg    a5,a6
  456.     bne.b    .gotfh
  457. .fail    moveq    #RETURN_FAIL,d0        <- Things are badly wrong!
  458.     rts
  459. .gotfh
  460.  
  461.  IFGT 0
  462.                         Agnus    PCMCIA  Akiko   AT-IDE    NVRAM  Ramsey&Gary
  463.             KS:     Denise    Chip   A690ID  Proc   StockMHz   UNI/01   A26x0
  464. >A1000   1.1-1.3      O Older  ¼/½          01??      7
  465. >A500old 1.2-2.x,3.1  O  Old   ½            01234     7
  466.  A500    1.2-2.x,3.1  O  Fat   ½-2          01234     7
  467.  A500+   2.x,3.1      E Super  1-2          01234     7
  468. >CDTV    1.3,2.x,3.1? O ?Fat?  1   (x) x    01234     7
  469. >A600    2.05,3.1     E Fatter 1/2  x       0  3    x 7
  470. >A1200*  3.0,3.1      A  AGA   1/2  x         2346p x 14
  471. >A1400   3.0,3.1      A  AGA   1/2  x         2??   x 25/28
  472. >CD³²    3.1          A  AGA   2          x   23    x 14     x
  473.  A2000   1.2-2.x,3.1  O  Fat   ½/1          012346p   7
  474.  A2000+  1.2-2.x,3.1  E  Fat   ½/1          012346p   7
  475. >A2500   1.2-2.x,3.1  O  Fat   ½/1            23      25                  x
  476. >A3000   1.3/2.x,3.1  E Ftr/Sp 1/2             346p   16/25/30         x
  477. >A3000UX UNIX         E Ftr/Sp 1/2             346p   25        x      x
  478. >A4000   3.0,3.1      A  AGA   2               346p x '30/25           x
  479.  A4000T* 3.1          A  AGA   2                46p x '40/25           x
  480. XWalker* 3.2          A  AGA   1/2             3  p x 'EC30/40
  481. >DraCo   AmigaOS      -   -     -                6?   50
  482.  
  483. * Amiga 3000 has always MMU and math co-processor. (?)
  484. * Blizzard turbos can have Kickstart ROM ReKicked 100% transparently, so
  485.   any kickstart version goes!
  486. * Amiga 3000 Tower has a HD floppy drive by default?
  487. * Amiga 4000 Tower has 68040 @ 25 MHz or 68060 @ 50 MHz, AmigaOS 3.1 and
  488.   SCSI-II controller (built in, not A4091?)
  489. X Walker has a SuperIO chip.
  490. * Draco has Altais gfx card. (see rs:identify.library.rs)
  491.  
  492.  
  493.  Check PCMCIA: Find 'card.resource'    600/1200/(570?)
  494.  Check CDTV: Find 'cdtv.device'
  495.  Check A690ID: FindResident 'A690ID'   570  (A500 CD-ROM/CDTV expansion)
  496.  Check AT-IDE: Find interrupt 'AT-IDE' 600/1200/4000
  497.  Check Akiko: Test GfxBase.ChunkyToPlanarPtr CD³² [OR HW emul card]
  498.  Check NVRAM: Test Nonvolatile/GetNVInfo() maxstorage
  499.  Check UNIX: Find any bootable UNI/01 partition
  500.  Check A3000: Ramsey-Chip rev < $F  (that is $D)
  501.  Check A4000: Ramsey-Chip rev >= $F
  502.  Check A2500: Match ConfigDev for A2620/A2630 turbo card
  503.  Check DraCo: Find 'draco.resource'
  504.  Check UAE: FindName(execbase.intrlist,'UAE filesystem')
  505.  
  506.  ROM:
  507.                                                       || 256 KB
  508.      30: 1000old with KS1.0                           \/
  509.      31: 1000 with KS 1.1 ntsc
  510.      32: 1000 with KS 1.1 pal
  511.   33 34: All but  1200, 4000, CD³², 500+, 600
  512.      35: Beta, not in chip                            ||
  513.      36: Early 3000                                   \/ 512 KB
  514.      37: All but 1000[old], 1200, 4000, CD³²
  515.      38: Not in chip
  516.      39: A1200, A1400, A4000
  517.      40: All but A1000[old]
  518.      41: Not in chip
  519.      42: Not in chip
  520. X    43: Walker (AmigaOS 3.2)                        || 1024 KB
  521.                                                      \/
  522.  
  523.     - Agnus Hardware Stats -
  524.  
  525.                         MODEL   VIDEO    CHIPRAM         CHIP TYPE
  526.         Agnus           8361    NTSC       512k     A1000 Subsystem DIP
  527.         Agnus           8361    NTSC       512k     A1000 Subsystem DIP
  528.         Fat Agnus       8370    NTSC       512k     DIP
  529.         Fat Agnus       8370    NTSC       512k     PLCC
  530.         Fat Agnus       8371    PAL        512k     DIP
  531.         Fat Agnus       8371    PAL        512k     PLCC
  532.         Fat Agnus       8372    NTSC/PAL   512k     PLCC
  533.         Fatter Agnus    8372a   NTSC/PAL  1024k     PLCC
  534.         Super Agnus     8372b   NTSC/PAL  2048k     PLCC A3000
  535.         Super Agnus     8375    NTSC/PAL  2048k     PLCC A500+
  536.         Alice                   NTSC/PAL  2048k     PLCC A4000/A1200
  537.  
  538.  
  539.   Question: Why doesn't SCSI work on the A4000?
  540.     Answer: It does. But because of a bug in early versions of the Zorro-III
  541.             DMA controller (the "Buster" chip), DMA SCSI controllers didn't
  542.             work properly. This problem can be fixed (by replacing the early
  543.             revision 9 Buster with a revision 11 version) or avoided
  544.             altogether (by using a SCSI controller that doesn't use the
  545.             Zorro-III bus, like the one built into the Warp Engine
  546.             accelerator).
  547.  
  548.  ENDC
  549.  
  550.     movem.l    a4/a5,-(sp)
  551.     bsr.b    __Main
  552.     movem.l    (sp)+,a4/a5
  553.     move.l    d0,-(sp)
  554.  
  555.     lea    (CursorOn,pc),a0
  556.     bsr    Printf
  557.  
  558.     tst.b    WBMode
  559.     bpl.b    .cli_noclose
  560.  
  561.     move.l    a5,a6
  562.  
  563.     tst.b    NewKick
  564.     bmi.b    .close_up
  565.  
  566.     lea    (PressReturn,pc),a0
  567.     bsr    Printf
  568.  
  569.     subq.l    #4,sp
  570.     move.l    OutputFH,d1
  571.     move.l    sp,d2
  572.     moveq    #1,d3
  573.     call    Read
  574.     addq.l    #4,sp
  575.  
  576. .close_up    move.l    OutputFH,d1
  577.     call    Close
  578. .cli_noclose
  579.     move.l    (ExecBase00,pc),a6
  580.     move.l    _DosBase,a1
  581.     call    CloseLibrary
  582.  
  583.     move.l    (sp)+,d0
  584.     rts
  585.  
  586.  
  587. _error    moveq    #RETURN_ERROR,d0
  588.     rts
  589.  
  590. __Main
  591.     DBG    'bgma'
  592.  
  593.     move.l    (4).w,a6        Use (4).w
  594.     bsr    GetDraCo
  595.  
  596.     DBG    'gdra'
  597.  
  598.  
  599.     bsr    ExtAttnFlags
  600.     move.w    d0,_AttnFlags
  601.  
  602.     DBG    'gatf'
  603.  
  604.     jsr    CacheClearU        Clear caches (now ExecBaseXX are valid)
  605.  
  606.     DBG    'cacc'
  607.  
  608.     lea    (_GfxName,pc),a1
  609.     moveq    #0,d0
  610.     call    OpenLibrary
  611.     move.l    d0,_GfxBase
  612.     beq    _error
  613.     move.l    d0,a1
  614.     call    CloseLibrary
  615.     lea    (ExpName,pc),a1
  616.     moveq    #0,d0
  617.     call    OpenLibrary
  618.     move.l    d0,_ExpBase
  619.     beq    _error
  620.     move.l    d0,a1
  621.     call    CloseLibrary
  622.  
  623.     lea    (sStart,pc),a0
  624.     bsr    Printf
  625.  
  626.     DBG    'seva'
  627.  
  628.     st    RamseyRev
  629.     move.w    _AttnFlags,d0
  630.     bsr    GetRamsey
  631.  
  632. ;    move.w    #15,d0            debug
  633.  
  634.     beq.b    .no_ramsey
  635.     move.w    d0,RamseyRev
  636.     cmp.w    #15,d0
  637.     slo    A3000ID
  638.     shs    A4000ID
  639. .no_ramsey
  640.     DBG    'gram'
  641.  
  642.     st    GaryRev
  643.     move.w    _AttnFlags,d0
  644.     bsr    GetGary
  645.  
  646. ;    move.w    #0,d0            debug
  647. ;    moveq    #1,d1
  648.  
  649.     beq.b    .no_gary
  650.     move.w    d0,GaryRev
  651.     call    Disable
  652.     move.b    $00DE0000,_wasDSACK
  653.     bpl.b    .is_DSACK
  654.     bclr    #7,$00DE0000        Set DSACK mode...
  655. .is_DSACK    call    Enable
  656. .no_gary
  657.     tst.b    A3000ID            A3000 must have both!
  658.     beq.b    .no_a30gry
  659.     tst.w    RamseyRev
  660.     bpl.b    .no_a30gry
  661.     clr.b    A3000ID
  662. .no_a30gry
  663.  
  664.     DBG    'ggry'
  665.  
  666.     lea    (sMMUna,pc),a0
  667.     move.l    a0,MMU
  668.     lea    (sNullStr,pc),a0
  669.     move.l    a0,MMUStatus
  670.     btst    #AFB_68030,_AttnFlags+1
  671.     beq.b    .lowpros
  672.     st    _EC
  673. .lowpros    jsr    GetMMU
  674.     move.l    d0,_MMUID
  675.     beq.b    .nommu            is 'EC' model
  676.     lea    (sNotActiveStr,pc),a0
  677.     tst.l    d1
  678.     beq.b    .msetoff
  679.     lea    (sRunningStr,pc),a0
  680. .msetoff    move.l    a0,MMUStatus
  681.     lea    (MMUTable,pc),a0
  682.     lea    MMU,a1
  683.     subq.l    #1,d0
  684.     bsr    PutWStrPtr
  685.     clr.l    EC
  686.     clr.l    _EC
  687. .nommu
  688.     DBG    'gmmu'
  689.  
  690.     bsr    GetGayle
  691.     move.w    d0,GayleRev
  692.     cmp.w    #13,d0
  693.     seq    AGAGayleID
  694.     bsr    GetPaula
  695.     move.w    d0,PaulaRev
  696.  
  697.     DBG    'ggay'
  698.  
  699.     bsr    GetGfxChip
  700.     move.b    d0,GfxChipID+3
  701.     move.w    d1,GfxChipRev
  702.     lea    (GfxChipTable,pc),a0
  703.     lea    GfxChip,a1
  704.     bsr    PutWStrPtr
  705.     lea    GChipRevBuffer,a2
  706.     move.l    a2,GfxChipRev_ptr
  707.     lea    (sRev,pc),a0
  708.     lea    GfxChipRev,a1
  709.     move.w    (a1),d0
  710.     bmi.b    .is_OCS
  711.     bsr    Sprintf
  712. .is_OCS
  713.     DBG    'ggcp'
  714.  
  715.     bsr    GetAnimChip
  716.     move.b    d0,AnimChipID+3
  717.     lea    (AnimChipTable,pc),a0
  718.     lea    AnimChip,a1
  719.     bsr    PutWStrPtr
  720.  
  721.     DBG    'gacp'
  722.  
  723.     bsr    GetGfxLibEmul
  724.     move.l    d0,GfxLibEmul
  725.     move.w    d1,BandWidth
  726.     lea    (GfxLibEmulTable,pc),a0
  727.     lea    GfxLibEmul_ptr,a1
  728.     bsr    PutWStrPtr
  729.     lea    DBWBuffer,a2
  730.     move.l    a2,BandWidth_ptr
  731.     cmp.w    #2,GfxLibEmul+2        AGA?
  732.     bne.b    .not_aga
  733.     lea    (sDBWFmt,pc),a0
  734.     lea    BandWidth,a1
  735.     bsr    Sprintf
  736. .not_aga
  737.     DBG    'ggbe'
  738.  
  739.     jsr    GetCPU
  740.  
  741.     DBG    'gcpu'
  742.  
  743.     jsr    GetProcInfo
  744.  
  745.     DBG    'gpin'
  746.  
  747.     move.l    _100kHz,d0
  748.     divu.w    #10,d0
  749.     swap    d0
  750.     move.l    d0,MHz
  751.     move.l    CPUID,d0
  752.     lea    (CPUTable,pc),a0
  753.     lea    CPU,a1
  754.     bsr    PutWStrPtr
  755.  
  756.  
  757.     bsr    GetMisc
  758.  
  759.     DBG    'gmsc'
  760.  
  761.     tst.b    CardSlotID
  762.     bne.b    .has_slot
  763.     bsr    GetCardSlot
  764.     move.b    d0,CardSlotID
  765.  
  766.     DBG    'gcsl'
  767. .has_slot
  768. ;    clr.l    CardSlotID        debug
  769.  
  770.     lea    (sNullStr,pc),a0
  771.     tst.l    UAEID
  772.     beq.b    .nouae
  773.     lea    (sUAE,pc),a0
  774. .nouae    move.l    a0,AfterMG_ptr
  775.  
  776.     lea    (sNA,pc),a0
  777.     tst.l    HWClockID
  778.     beq.b    .nohwclock
  779.     lea    (sClockFound,pc),a0
  780. .nohwclock    move.l    a0,HWClock_ptr
  781.  
  782.  
  783.     tst.b    ATIDEID
  784.     bne.b    .has_ATIDE
  785.     bsr    GetATIDE
  786.     move.b    d0,ATIDEID
  787.  
  788.     DBG    'gide'
  789. .has_ATIDE
  790.  
  791.     lea    (sFna,pc),a2
  792.     move.w    _AttnFlags,d0
  793.     bsr    GetFPU
  794.     move.b    d0,FPUID+3
  795.     beq.b    .nofpu
  796.  
  797.     IFGT    0
  798.     move.l    FPUCompareTime,-(sp)    dbug
  799.     lsr.l    #8,d0
  800.     lsr.l    #8,d0
  801.     divu.w    #10,d0
  802.     swap    d0
  803.     move.l    d0,-(sp)
  804.     lea    (FPUTable,pc),a0
  805.     move.l    FPUID,d0
  806.     add.l    d0,d0
  807.     add.w    (a0,d0.l),a0
  808.     move.l    a0,-(sp)
  809.     lea    (sFPUFmt,pc),a0
  810.     move.l    sp,a1
  811.     lea    FPUBuffer,a2
  812.     bsr    Sprintf
  813. ;;    addq.l    #8,sp
  814.     lea    (3*4,sp),sp        dbug
  815. .nofpu    move.l    a2,FPU_ptr
  816.     ELSE
  817.  
  818.     lea    (FPUTable,pc),a0
  819.     move.l    FPUID,d0
  820.     add.l    d0,d0
  821.     add.w    (a0,d0.l),a0
  822.     move.l    a0,-(sp)
  823.     lea    (sFPUFmt,pc),a0
  824.     move.l    sp,a1
  825.     lea    FPUBuffer,a2
  826.     bsr    Sprintf
  827.     addq.l    #4,sp
  828. .nofpu    move.l    a2,FPU_ptr
  829.     ENDC
  830.  
  831.     DBG    'gfpu'
  832.  
  833.  
  834.     tst.l    A4000ID
  835.     beq.b    .not_a4000t
  836.     move.b    A4091ID,A4000TID    A4091 is checked in GetMisc subr
  837. .not_a4000t
  838.     bsr    GetGfxBoards
  839.     DBG    'ggbo'
  840.  
  841.     bsr    GetSndCards
  842.     DBG    'gsca'
  843.  
  844.     bsr    GetExpBoards
  845.     DBG    'gebo'
  846.  
  847.     bsr    GetChipMem
  848.     move.l    d0,ChipMemd
  849.     move.l    (ExecBase00,pc),a6
  850.     move.l    (MaxLocMem,a6),d0
  851.     lsr.l    #8,d0            /10
  852.     lsr.l    #2,d0
  853.     move.l    d0,ChipMem
  854.  
  855.     DBG    'gcme'
  856.  
  857.     bsr    GetFastMem
  858.     move.l    d0,FastMem
  859.  
  860.     DBG    'gfme'
  861.  
  862.     lea    (sNullStr,pc),a0
  863.     move.l    a0,VirtMem_ptr
  864.     bsr    GetVirtMem
  865.     move.l    d0,VirtMem
  866.     beq.b    .novirtmem
  867.     lea    sVirtMemBuf,a2
  868.     move.l    a2,VirtMem_ptr
  869.     lea    (sVirtMemFmt,pc),a0
  870.     lea    VirtMem,a1
  871.     bsr    Sprintf
  872. .novirtmem
  873.     DBG    'gvme'
  874.  
  875.     move.w    _AttnFlags,d0
  876.     bsr    GetChipRomVer
  877.     move.l    d0,RomVer
  878.     move.l    d1,RomChkSum
  879.     bsr    GetKickStr
  880.     move.l    d0,RomVerS
  881.  
  882.     DBG    'gcro'
  883.  
  884.     bsr    GetCRomVer
  885.     move.l    d0,CRomVer
  886.     move.l    d1,CRomChkSum
  887.     bsr    GetKickStr
  888.     move.l    d0,CRomVerS
  889.  
  890.     DBG    'grom'
  891.  
  892.     lea    (sNullStr,pc),a2
  893.     move.l    RomVer,d0
  894.     cmp.l    CRomVer,d0
  895.     bne.b    .rekickrom
  896.     move.l    RomChkSum,d0
  897.     cmp.l    CRomChkSum,d0
  898.     beq.b    .rom_is_same
  899. .rekickrom    lea    sROMBuf,a2
  900.     lea    (sReKickROM,pc),a0
  901.     lea    CRomVer,a1
  902.     bsr    Sprintf
  903. .rom_is_same    move.l    a2,ReKickROM_ptr
  904.  
  905.  
  906.     bsr    GetWBVersion
  907.     move.l    d0,WBVer
  908.     bsr    GetWBStr
  909.     move.l    d0,WBVerS
  910.  
  911.     DBG    'gwbv'
  912.  
  913.     lea    (sNoSetPatch,pc),a0
  914.     move.l    a0,SetPatchVerPtr
  915.     bsr    GetSetPatchVersion
  916.     tst.l    d0
  917.     beq.b    .nosetpatch
  918.     move.l    d0,-(sp)
  919.     lea    sSetPatchBuf,a2
  920.     lea    (sSetPatchVerFmt,pc),a0
  921.     move.l    sp,a1
  922.     bsr    Sprintf
  923.     move.l    a2,SetPatchVerPtr
  924.     addq.l    #4,sp
  925. .nosetpatch
  926.     DBG    'gspv'
  927.  
  928.     lea    ExpBoardsBuffer,a0
  929.     move.l    a0,ExpBoards_ptr
  930.     bsr    GetBoards
  931.  
  932.     DBG    'gboa'
  933.  
  934.     bsr    GetOtherChips
  935.  
  936.     DBG    'goth'
  937.  
  938.     bsr    EvaluateFormulas
  939.     move.l    d0,MachineGuess
  940.  
  941.     DBG    'deva'
  942.  
  943.     lea    (sRaport,pc),a0
  944.     lea    Params,a1
  945.     bsr    Printf
  946.  
  947.     DBG    'prnt'
  948.  
  949.     tst.w    GaryRev
  950.     bmi.b    .nogary
  951.     call    Disable
  952.     tst.b    _wasDSACK
  953.     bpl.b    .was_DSACK
  954.     bset    #7,$00DE0000        Set BERR if it was on originally!
  955. .was_DSACK    call    Enable
  956. .nogary
  957.     moveq    #RETURN_OK,d0
  958.     rts
  959.  
  960.  
  961. PutWStrPtr    add.w    d0,d0
  962.     add.w    (a0,d0.w),a0
  963.     move.l    a0,(a1)
  964.     rts
  965.  
  966.  
  967. ;  IN: a0=buffer
  968. GetBoards    movem.l    d0-a6,-(sp)
  969.     move.l    a0,a4
  970.     move.l    (ExecBase00,pc),a6
  971.     lea    (.boardsname,pc),a1
  972.     moveq    #2,d0
  973.     call    OpenLibrary
  974.     move.l    d0,d7
  975.     beq    .exit
  976.  
  977.     move.l    d7,a6
  978.     moveq    #0,d0
  979.     jsr    (-36,a6)        call    AllocBoardInfo
  980.     move.l    d0,d6
  981.     beq    .closeboards
  982.  
  983.     moveq    #-1,d0            Any boards available?
  984.     bsr    FindConfigDev
  985.     beq    .noboards
  986.     lea    (.expansion,pc),a0
  987. .copy    move.b    (a0)+,(a4)+
  988.     bne.b    .copy
  989.     subq.l    #1,a4
  990.     sub.l    a1,a1
  991.  
  992. .next    move.l    d6,a0
  993.     jsr    (-42,a6)        call    NextBoardInfo
  994.     tst.l    d0
  995.     beq.b    .done
  996.  
  997.     move.l    d0,-(sp)
  998.     move.l    (16,a0),-(sp)        bi_ExSize
  999.     move.l    (12,a0),-(sp)        bi_ExAddress
  1000.     move.l    (32,a0),-(sp)        bi_ProdName
  1001.     move.l    (28,a0),-(sp)        bi_ManuName
  1002.     move.l    (24,a0),-(sp)        bi_ProdID
  1003.     move.l    (20,a0),-(sp)        bi_ManuID
  1004.     move.l    sp,a1
  1005.     lea    (.boardsfmt,pc),a0
  1006.     move.l    a4,a2
  1007.     bsr    Sprintf
  1008.     lea    (6*4,sp),sp
  1009. .findend    tst.b    (a4)+
  1010.     bne.b    .findend
  1011.     subq.l    #1,a4
  1012.  
  1013.     move.l    (sp),a0
  1014.     cmp.w    #$2140,(cd_Rom+er_Manufacturer,a0)    Blizzard PPC?
  1015.     bne.b    .not_blizppc
  1016.     cmp.b    #110,(cd_Rom+er_Product,a0)
  1017.     bne.b    .not_blizppc
  1018.     cmp.w    #$00F0,(cd_BoardAddr,a0)
  1019.     bne.b    .not_blizppc
  1020.     lea    (.blizzppc,pc),a0
  1021.     pea    $F00010
  1022.     move.l    sp,a1
  1023.     move.l    a4,a2
  1024.     bsr    Sprintf
  1025.     addq.l    #4,sp
  1026. .blfindend    tst.b    (a4)+
  1027.     bne.b    .blfindend
  1028.     subq.l    #1,a4
  1029.  
  1030. .not_blizppc
  1031.     move.l    (sp)+,a1
  1032.     bra.b    .next
  1033. .done
  1034. .noboards
  1035. .freebi    move.l    d6,a0
  1036.     jsr    (-48,a6)        call    FreeBoardInfo
  1037. .closeboards    move.l    d7,a1
  1038.     move.l    (ExecBase00,pc),a6
  1039.     call    CloseLibrary
  1040. .exit    movem.l    (sp)+,d0-a6
  1041.     rts
  1042.  
  1043. .boardsname    dc.b    'boards.library',0    BOARDSNAME
  1044. .expansion    dc.b    '     Expansion board(s):',10,0
  1045. .boardsfmt    dc.b    '%s/%s: %s %s (@%s %s)',10,0
  1046. .blizzppc    dc.b    '          Blizzard PPC serial number: %7s',10,0
  1047.     CNOP    0,4
  1048.  
  1049.  
  1050. GetExpBoards    movem.l    d0-d1/a0-a1,-(sp)
  1051.     lea    (ExpBoardTable1,pc),a0    If you have A2000 you propably
  1052. .loop1    move.l    (a0)+,d0        have some expansion stuff in it!!
  1053.     beq.b    .done1
  1054.     bsr    FindConfigDev
  1055.     sne    A2000EID
  1056.     bne.b    .done1
  1057.     bra.b    .loop1
  1058. .done1
  1059.     lea    (ExpBoardTable2,pc),a0    If any A500 expansion is found
  1060. .loop2    move.l    (a0)+,d0        A2000ID is cleared.
  1061.     beq.b    .done2
  1062.     bsr    FindConfigDev
  1063.     beq.b    .loop2
  1064.     st    A500EID
  1065.     clr.b    A2000EID
  1066. .done2
  1067.  
  1068.     tst.l    A690ID
  1069.     beq.b    .no_A500_CDROM
  1070.     st    A500EID
  1071.     clr.b    A2000EID
  1072. .no_A500_CDROM
  1073.     movem.l    (sp)+,d0-d1/a0-a1
  1074.     rts
  1075.  
  1076. ;;; ExpBoardTables
  1077.  
  1078. EXPBRD    MACRO
  1079.     dc.l    ($\1<<16)!\2
  1080.     ENDM
  1081.  
  1082.     CNOP    0,4
  1083. ExpBoardTable2
  1084.     EXPBRD    202,32    A560 Memory Module
  1085.     EXPBRD    3F2,68    MicroBotics VXL RAM*32
  1086.     EXPBRD    3F2,69    MicroBotics VXL 68030 turbo
  1087.     EXPBRD    420,5    Supra 500 HD/RAM interface
  1088.     EXPBRD    420,9    Supra 500XP
  1089.     EXPBRD    420,12    Supra 500XP/Wordsync
  1090.     EXPBRD    420,13    Supra 500XP/Wordsync
  1091. ;500/2000!!!    EXPBRD    7E1,10    GVP Series II (A500) memory board
  1092. ;500/2000!!!    EXPBRD    7E1,11    GVP Series II (A500) SCSI ctrl
  1093.     EXPBRD    801,4    BSC Oktagon 500
  1094.     EXPBRD    82C,4    BSC Oktagon 500
  1095.     EXPBRD    2062,1    Expansion Systems DataFlyer 500 HD Ctrl
  1096.     dc.l    0
  1097.  
  1098.     CNOP    0,4
  1099. ExpBoardTable1
  1100.     ;Harlequin
  1101.     EXPBRD    851,1    Resolver
  1102.     EXPBRD    0851,2    Vivid 24
  1103.     EXPBRD    07E1,68    Rembrandt
  1104.     EXPBRD    0845,2    Visiona
  1105.     ;OpalVision
  1106.     EXPBRD    838,0    FireCracker
  1107.     EXPBRD    838,1    FireCracker
  1108.     EXPBRD    406,0    Lowell A2410
  1109.     EXPBRD    3EC,245    Kronos/C Ltd A2410
  1110.  
  1111.     EXPBRD    0891,1    EGS
  1112.     EXPBRD    07E1,32    IV24
  1113.     ;Video Toaster
  1114.     EXPBRD    2140,34    CyberVision 64/4MB
  1115.     EXPBRD    2140,50    CyberVision 64/3D
  1116.     EXPBRD    2140,67    CyberVision 64/3D
  1117.     EXPBRD    85E,1    GDA-1
  1118.     EXPBRD    86A,1    Horizon
  1119.     EXPBRD    86A,2    Blackbox 
  1120.     EXPBRD    86A,3    Voyager
  1121.     EXPBRD    877,12    Picasso II
  1122.     EXPBRD    877,13    Picasso II
  1123.     EXPBRD    877,24    Picasso IV
  1124.     EXPBRD    4754,16    RetinaZ3
  1125.     EXPBRD    4754,19,sAltais
  1126.     ;RetinaZ2? Domino? Piccolo? PiccoloSD64? RainBowIII? 1600GX?
  1127.  
  1128.     EXPBRD    201,1    A2088/A2288
  1129.     EXPBRD    201,2    A2286
  1130.     EXPBRD    201,103 A2386SX
  1131.     EXPBRD    866,1    D. Salamon Golden Gate II BridgeCard
  1132.  
  1133.     EXPBRD    2017,7    GoldenGate 80386
  1134.     EXPBRD    2017,9    GoldenGate 80486
  1135.     ;EMC 486SLC
  1136.  
  1137.     EXPBRD    200,2    3-State Megamix 2000
  1138.     EXPBRD    202,1    A2090(A)
  1139.     EXPBRD    202,4    A2090B
  1140.     EXPBRD    202,9    A2060
  1141.     EXPBRD    202,69    A2232 (prototype)
  1142.     EXPBRD    202,70    A2232
  1143.     EXPBRD    202,80    A2620 68020 turbo
  1144.     EXPBRD    202,81    A2640 68030 turbo
  1145.     EXPBRD    202,84    A4091 SCSI/SCSI-II         ???
  1146.     EXPBRD    202,112    A2065
  1147.     EXPBRD    2F4,105    A2000 68040 turbo
  1148.     EXPBRD    2F4,150  ???  68040 turbo
  1149.     EXPBRD    3EC,4    Kronos 2000            ???
  1150.     EXPBRD    3ED,1    A-Squared LIVE!
  1151.     EXPBRD    3F2,68    MicroBotics 68030 turbo???
  1152.     EXPBRD    3F2,150    MB HardFrame/2000?
  1153.     EXPBRD    3F2,158    MB HardFrame/2000?
  1154.     EXPBRD    3FF,255    Dual serial port
  1155.     EXPBRD    404,57    A2000 68030 turbo
  1156.     EXPBRD    404,87    A2000 68030 turbo
  1157.     EXPBRD    41D,1    Amerisar Ethernet
  1158.     EXPBRD    420,1    Supra 4x4
  1159.     EXPBRD    420,3    Supra 2000 DMA
  1160.     EXPBRD    420,11    Supra 2400zi internal modem
  1161.     EXPBRD    420,16    Supra 2400zi internal modem
  1162.     EXPBRD    422,17    Mag40 68040 Turbo
  1163.     EXPBRD    6E1,8    GVP Series I HD Ctrl
  1164.     EXPBRD    7E1,3    GVP Hard Card 0
  1165.     EXPBRD    7E1,8    GVP A3001 Expansion board
  1166. ;;    EXPBRD    7E1,9    GVP A3001 RAM            500/2000!!!
  1167.     EXPBRD    7E1,255    GVP GForce 68040 Turbo
  1168.     EXPBRD    7EA,105    68040 turbo???
  1169. ;;wasina500?    EXPBRD    801,6    BSC Oktagon 2008
  1170. ;;wasina500?    EXPBRD    801,8    BSC Oktagon 2008
  1171.     EXPBRD    801,16    BSC Parallel/Serial
  1172.     EXPBRD    801,32    BSC Frame Buffer
  1173.     EXPBRD    801,64    BSC ISDN Master
  1174.     EXPBRD    802,4    Kronos 2000            ???
  1175.     EXPBRD    817,1    ICD 2000 SCSI
  1176.     EXPBRD    817,4    ICD 2080 Board
  1177.     EXPBRD    81D,9    GVP A2000-Ram8/2
  1178.     EXPBRD    828,16    Applied LD2000 Modem???
  1179.     EXPBRD    82C,5    BSC Memory Master Card
  1180. ;;wasina500?    EXPBRD    82C,6    BSC Oktagon 2008        ???
  1181. ;;wasina500?    EXPBRD    82C,8    BSC Oktagon 2008
  1182.     EXPBRD    82C,18    ?
  1183.     EXPBRD    82C,64    BSC ISDN Master
  1184.     EXPBRD    87B,21    Emplant MAC emu
  1185.     EXPBRD    1028,87    Imtromix hurricane 2800
  1186.     EXPBRD    2017,7    ?
  1187.     EXPBRD    2100,1    ReadySoft Amax II+ Mac emu
  1188.     EXPBRD    2132,27    ?
  1189.     EXPBRD    4754,4    Macrosystems Framegrabber?
  1190.     EXPBRD    A9AD,17    Reis-ware Scan King
  1191.     EXPBRD    819,2    Kupke Golem SCSI II
  1192.     dc.l    0
  1193. ;;;
  1194.  
  1195.  
  1196. GetGfxBoards    movem.l    d0-d1/a0-a6,-(sp)
  1197.     lea    GfxBoardI,a4
  1198.     lea    (sNullStr,pc),a0
  1199.     move.l    a0,(a4)
  1200.     lea    GfxBoardBuffer+2,a3
  1201.     move.l    a3,(GfxBoard-GfxBoardI,a4)
  1202.     subq.l    #2,a3
  1203.  
  1204.     move.l    (4).w,a6
  1205.     cmp.w    #39,(LIB_VERSION,a6)
  1206.     blo    .nocgfx
  1207.     lea    (.cgfxname,pc),a1
  1208.     moveq    #41,d0
  1209.     call    OpenLibrary
  1210.     tst.l    d0
  1211.     beq.b    .nocgfx
  1212.     move.l    d0,a6
  1213.  
  1214.     clr.l    -(sp)
  1215.     pea    (12).w        ; Cybervision PPC
  1216.     pea    CYBRBIDTG_MONITORID
  1217.     move.l    sp,a0
  1218.     call    BestCModeIDTagList
  1219.     addq.l    #1,d0
  1220.     beq.b    .no_b1
  1221.  
  1222.     lea    (.cvppc,pc),a0
  1223.     bsr    .copy1
  1224.  
  1225. .no_b1    move.w    #14,(4+2,sp)    ; Inferno
  1226.     move.l    sp,a0
  1227.     call    BestCModeIDTagList
  1228.     addq.l    #1,d0
  1229.     beq.b    .no_b2
  1230.  
  1231.     lea    (.inferno,pc),a0
  1232.     bsr    .copy1
  1233.  
  1234. .no_b2    lea    (3*4,sp),sp
  1235.     move.l    a6,a1
  1236.     move.l    (4).w,a6
  1237.     call    CloseLibrary
  1238. .nocgfx
  1239.     lea    (GfxBoardTable,pc),a2
  1240.  
  1241. .loop    movem.l    (a2)+,d0/a0
  1242.     tst.l    d0
  1243.     beq.b    .done
  1244.     bsr    FindConfigDev
  1245.     beq.b    .loop
  1246.     bsr.b    .copy1
  1247.     bra.b    .loop
  1248.  
  1249. .done    move.b    #10,(a3)
  1250.     movem.l    (sp)+,d0-d1/a0-a6
  1251.     rts
  1252.  
  1253. .copy1    lea    (sGfxBoards,pc),a1
  1254.     move.l    a1,(a4)            Set introducer
  1255.     move.b    #'/',(a3)+
  1256.     move.b    #' ',(a3)+
  1257. .copy    move.b    (a0)+,(a3)+
  1258.     bne.b    .copy
  1259.     subq.l    #1,a3
  1260.     rts
  1261.  
  1262. .cgfxname    dc.b    'cybergraphics.library',0
  1263. .cvppc    dc.b    'CyberVision PPC',0
  1264. .inferno    dc.b    'Inferno',0
  1265.     CNOP    0,2
  1266.  
  1267.  
  1268. GetSndCards    movem.l    d0-d1/a0-a4,-(sp)
  1269.     lea    SndCardI,a4
  1270.     lea    (sNullStr,pc),a0
  1271.     move.l    a0,(a4)
  1272.     lea    SndCardBuffer+1,a3
  1273.     move.l    a3,(SndCard-SndCardI,a4)
  1274.     lea    (SndCardTable,pc),a2
  1275.     lea    (sSndCards,pc),a1
  1276.     subq.l    #1,a3
  1277.  
  1278. .loop    movem.l    (a2)+,d0/a0
  1279.     tst.l    d0
  1280.     beq.b    .done
  1281.     bsr.b    FindConfigDev
  1282.     beq.b    .loop
  1283.     move.l    a1,(a4)            Set introducer
  1284.     move.b    #'/',(a3)+
  1285. .copy    move.b    (a0)+,(a3)+
  1286.     bne.b    .copy
  1287.     subq.l    #1,a3
  1288.     bra.b    .loop
  1289.  
  1290. .done    move.b    #10,(a3)
  1291.     movem.l    (sp)+,d0-d1/a0-a4
  1292.     rts
  1293.  
  1294.  
  1295.  
  1296. ;  IN: d0=manu<<16+prod
  1297. ; OUT: d0=ConfigDev if found, else zero, ccs set!
  1298. FindConfigDev    movem.l    d1-d2/a0-a1/a6,-(sp)
  1299.     move.l    _ExpBase,a6
  1300.     sub.l    a0,a0
  1301.     moveq    #0,d1
  1302.     move.w    d0,d1
  1303.     clr.w    d0
  1304.     swap    d0
  1305.     moveq    #-1,d2
  1306.     cmp.w    d2,d0
  1307.     bne.b    .ok1
  1308.     move.l    d2,d0
  1309. .ok1    cmp.w    d2,d1
  1310.     bne.b    .ok2
  1311.     move.l    d2,d1
  1312. .ok2    call    FindConfigDev
  1313.     tst.l    d0
  1314.     movem.l    (sp)+,d1-d2/a0-a1/a6
  1315.     rts
  1316.  
  1317.  
  1318. GetOtherChips    movem.l    d0-a6,-(sp)
  1319.     lea    ChipsBuffer+2,a2
  1320.     move.l    a2,CustomChips
  1321.  
  1322.     subq.l    #2,a2
  1323.     lea    (sPaula,pc),a0
  1324.     lea    PaulaRev,a1
  1325.     move.w    (a1),d0
  1326.     bmi.b    .nopaula
  1327.     bsr.b    .print
  1328. .nopaula
  1329.     lea    (sRamsey,pc),a0
  1330.     lea    RamseyRev,a1
  1331.     tst.w    (a1)
  1332.     bmi.b    .noramsey
  1333.     bsr.b    .print
  1334. .noramsey
  1335.     lea    (sGary,pc),a0
  1336.     lea    GaryRev,a1
  1337.     tst.w    (a1)
  1338.     bmi.b    .nogary
  1339.     bsr.b    .print
  1340. .nogary
  1341.     lea    (sGayle,pc),a0
  1342.     lea    GayleRev,a1
  1343.     move.w    (a1),d0
  1344.     bmi.b    .nogayle
  1345.     bsr.b    .print
  1346. .nogayle
  1347.     tst.l    AkikoID
  1348.     beq.b    .noakiko
  1349.     lea    (sAkiko,pc),a0
  1350.     bsr.b    .print
  1351. .noakiko
  1352.     movem.l    (sp)+,d0-a6
  1353.     rts
  1354.  
  1355. .print    tst.b    (a2)+
  1356.     bne.b    .print
  1357.     move.b    #',',(-1,a2)
  1358.     move.b    #' ',(a2)+
  1359.     bra    Sprintf
  1360.  
  1361.  
  1362. ;  IN: d0=AttnFlags ('030 info available)
  1363. ; OUT: d0=ramseyrev, if z clear
  1364. GetRamsey    movem.l    d6-d7/a5-a6,-(sp)
  1365.     moveq    #0,d6
  1366.     moveq    #0,d7
  1367.     tst.l    NoHW
  1368.     bne.b    .no_chip2
  1369.     btst    #AFB_68020,d0
  1370.     beq.b    .no_chip2
  1371.  
  1372.     lea    (.supramsey,pc),a5
  1373.     move.l    (ExecBase00,pc),a6
  1374.     call    Disable
  1375.     call    Supervisor        Ramsey revision:
  1376.  
  1377.     cmp.w    #$D,d6
  1378.     blo.b    .no_chip        Minimum!
  1379.     cmp.w    #$F+5,d6        Maximum! ???
  1380.     bhi.b    .no_chip
  1381.  
  1382.     moveq    #-1,d7
  1383.  
  1384. .no_chip    call    Enable
  1385. .no_chip2    move.l    d6,d0
  1386.     tst.l    d7            <- Does set ccs
  1387.     movem.l    (sp)+,d6-d7/a5-a6    <- Doesn't set ccs!!!
  1388.     rts
  1389.  
  1390. .supramsey    move.b    $DE0043,d6
  1391. ;    move.b    #$F,d6            debug
  1392.     rte
  1393.  
  1394.  
  1395. ;  IN: d0=AttnFlags ('030 info available)
  1396. ; OUT: d0=garyrev, if z clear
  1397. GetGary    movem.l    d1-d2/d6-d7/a0/a6,-(sp)
  1398.     moveq    #0,d6
  1399.     moveq    #0,d7
  1400.     tst.l    NoHW
  1401.     bne.b    .no_chip2
  1402.     btst    #AFB_68020,d0
  1403.     beq.b    .no_chip2
  1404.  
  1405.     move.l    (ExecBase00,pc),a6
  1406.     call    Disable
  1407.  
  1408. ;    Gary revision:
  1409.     lea    $DE1002,a0
  1410.     clr.b    (a0)
  1411.     jsr    CacheClearU
  1412.     cmp.b    #$7F,(a0)
  1413.     nop
  1414.     bne.b    .no_chip
  1415.  
  1416.     clr.b    (a0)
  1417.     nop
  1418.     moveq    #7,d0
  1419. .loop    tst.b    (a0)
  1420.     nop
  1421.     bpl.b    .skip
  1422.     bset    d0,d6
  1423. .skip    dbf    d0,.loop
  1424.  
  1425.     cmp.w    #$FF,d6
  1426.     beq.b    .no_chip        All bits 1 -> No chip!
  1427.     cmp.w    #209,d6            Test for Gaylething... :)
  1428.     beq.b    .no_chip        (not really needed tho)
  1429.  
  1430.     moveq    #-1,d7
  1431.  
  1432. .no_chip    call    Enable
  1433. .no_chip2    move.l    d6,d0
  1434.     tst.l    d7            <- Does set ccs
  1435.     movem.l    (sp)+,d1-d2/d6-d7/a0/a6    <- Doesn't set ccs!!!
  1436.     rts
  1437.  
  1438.  
  1439. ;NAME   rev ADDR type chip Description
  1440. ;---------------------------------------------------------------------------
  1441. ;POTINP     016   R    P   Pot pin data read
  1442. ;
  1443. ;     Bit
  1444. ;    Number  Name              Function
  1445. ;
  1446. ;    07-01   X       Paula 8364 chip revision identification number
  1447. ;                    (presently all zeroes)
  1448.  
  1449. ; OUT: d0=paula revision or -1
  1450. GetPaula    tst.l    NoHW
  1451.     bne.b    .nohw
  1452.     IFND    potgor
  1453.     move.w    $DFF000+potinp,d0    potgor
  1454.     ELSE
  1455.     move.w    $DFF000+potgor,d0
  1456.     ENDC
  1457.  
  1458.     and.w    #%11111110,d0
  1459.     lsr.w    #1,d0
  1460.     rts
  1461.  
  1462. .nohw    moveq    #-1,d0
  1463.     rts
  1464.  
  1465.  
  1466. ; OUT: d0=Gayle revision or -1
  1467. GetGayle    movem.l    d1-a6,-(sp)
  1468.     tst.l    NoHW
  1469.     bne    .no_gayle
  1470.  
  1471.     move.l    (ExecBase00,pc),a6
  1472.  
  1473.     lea    $DFF000,a0
  1474.     lea    $DE1000,a1        Gayle port
  1475.     moveq    #0,d1
  1476.     call    Disable
  1477.     move.w    (intenar,a0),d0
  1478.     move.w    #$BFFF,(intena,a1)
  1479.     move.w    #$3FFF,d2
  1480.     cmp.w    (intenar,a0),d2
  1481.     bne.b    .skip1
  1482.     move.w    d2,(intena,a1)
  1483.     tst.w    (intenar,a0)
  1484.     bne.b    .skip1
  1485.     moveq    #1,d1
  1486. .skip1    move.w    d2,(intena,a0)
  1487.     or.w    #$8000,d0
  1488.     move.w    d0,(intena,a0)
  1489.  
  1490.     call    Enable
  1491.     tst.w    d1
  1492.     bne.b    .no_gayle
  1493.  
  1494.     moveq    #3,d2            Get revision:
  1495.     move.b    d1,(a1)
  1496. .loop    move.b    (a1),d0
  1497.     lsl.b    #1,d0
  1498.     addx.b    d1,d1
  1499.     dbra    d2,.loop
  1500.     moveq    #0,d0
  1501.     move.b    d1,d0
  1502. .exit    tst.b    d0
  1503.     bne.b    .exit2
  1504. .no_gayle    moveq    #-1,d0
  1505. .exit2    movem.l    (sp)+,d1-a6
  1506.     rts
  1507.  
  1508.  
  1509. ;  IN: d0=version<<16+revision
  1510. ; OUT: d0=ptr to null terminated kick version string (eg. '2.05',0)
  1511. GetKickStr    move.l    d1,-(sp)
  1512.     move.w    d0,d1
  1513.     swap    d0
  1514.     tst.w    d0
  1515.     beq.b    .no_rom
  1516.     sub.w    #30,d0
  1517.     cmp.w    #13,d0
  1518.     bls.b    .ok
  1519.     moveq    #14,d0
  1520. .ok    add.w    d0,d0
  1521.     lea    (_ks,pc),a0
  1522.     add.w    (a0,d0.w),a0
  1523.     cmp.w    #(37-30)*2,d0
  1524.     bne.b    .skip
  1525.     cmp.w    #175,d1            >37.175<
  1526.     bls.b    .skip
  1527.     addq.l    #(_sKS_05-_sKS7),a0
  1528. .skip    move.l    a0,d0
  1529.     move.l    (sp)+,d1
  1530.     rts
  1531. .no_rom    lea    (_sKNoROM,pc),a0
  1532.     bra.b    .skip
  1533. _wb    dc.w    _sKS0-_wb,_sKS1-_wb,_sKS2-_wb,_sKS3-_wb,_sKS4-_wb
  1534.     dc.w    _sKS5-_wb,_sKS6-_wb,_sKS7_2-_wb,_sKSWB-_wb,_sKS8-_wb
  1535.     dc.w    _sKS9-_wb,_sKSA-_wb,_sKSX-_wb
  1536. _ks    dc.w    _sKS0-_ks,_sKS1-_ks,_sKS2-_ks,_sKS3-_ks,_sKS4-_ks
  1537.     dc.w    _sKS5-_ks,_sKS6-_ks,_sKS7-_ks,_sKSH-_ks,_sKS8-_ks
  1538.     dc.w    _sKS9-_ks,_sKSH-_ks,_sKSH-_ks,_sKSA-_ks,_sKSX-_ks
  1539. _sKS0    dc.b    '1.0',0
  1540. _sKS1    dc.b    '1.1 ntsc',0
  1541. _sKS2    dc.b    '1.1 pal',0
  1542. _sKS3    dc.b    '1.2',0
  1543. _sKS4    dc.b    '1.3',0
  1544. _sKS5    dc.b    '1.4 beta',0
  1545. _sKS6    dc.b    '2.0 beta',0
  1546. _sKS8    dc.b    '3.0',0
  1547. _sKS9    dc.b    '3.1',0
  1548. _sKSA    dc.b    '3.2',0
  1549. _sKSX    dc.b    'unknown',0
  1550. _sKS7    dc.b    '2.04',0
  1551. _sKS_05    dc.b    '2.05',0
  1552. _sKSH    dc.b    'hack',0
  1553. _sKS7_2    dc.b    '2.0',0
  1554. _sKSWB    dc.b    '2.1',0
  1555. _sKNoROM
  1556. sNoSetPatch    dc.b    'version information not available',0
  1557.     CNOP    0,4
  1558.  
  1559.  
  1560. ;  IN: d0=version<<16+revision
  1561. ; OUT: d0=ptr to null terminated WB version string (eg. '2.1',0)
  1562. GetWBStr    move.l    d1,-(sp)
  1563.     move.w    d0,d1
  1564.     swap    d0
  1565.     tst.w    d0
  1566.     beq.b    .no_wb
  1567.     sub.w    #30,d0
  1568.     cmp.w    #11,d0
  1569.     bls.b    .ok
  1570.     moveq    #12,d0
  1571. .ok    add.w    d0,d0
  1572.     lea    (_wb,pc),a0
  1573.     add.w    (a0,d0.w),a0
  1574. .done    move.l    a0,d0
  1575.     move.l    (sp)+,d1
  1576.     rts
  1577. .no_wb    lea    (_sKNoROM,pc),a0
  1578.     bra.b    .done
  1579.  
  1580.  
  1581. ExtAttnFlags    movem.l    d1/d2/a0-a1/a6,-(sp)
  1582.     move.l    (4).w,a6        Use (4).w
  1583.     move.w    (AttnFlags,a6),d2
  1584.     tst.l    NoHW
  1585.     bne.b    .nohw
  1586.     cmp.w    #37,(LIB_VERSION,a6)
  1587.     bhs.b    .test060
  1588.  
  1589.     jsr    Test030_040_882
  1590.     or.w    d0,d2
  1591. ;;    bra.b    .xit
  1592.  
  1593. .test060    btst    #AFB_68040,d2        You must have 68040 flag
  1594.     beq.b    .no060            set to have 68060.
  1595.     tst.b    d2            Test #AFB_68060
  1596.     bmi.b    .is060            Is already valid!
  1597.  
  1598.     jsr    Test060            Test for 68060.
  1599. .is060
  1600. .no060
  1601. .nohw
  1602. .xit    move.w    d2,d0
  1603.     movem.l    (sp)+,d1/d2/a0-a1/a6
  1604.     rts
  1605.  
  1606.  
  1607. GetCardSlot    moveq    #0,d0
  1608.     move.w    GayleRev,d1
  1609.     cmp.w    #13,d1
  1610.     bne.b    .no_cardslot
  1611.     moveq    #-1,d0
  1612. .no_cardslot    rts
  1613.  
  1614.  
  1615.  
  1616. GetATIDE    movem.l    d1-a6,-(sp)
  1617.     lea    $00DA2000,a4        IDE port
  1618.     bsr.b    .TestIDEHW
  1619.     movem.l    (sp)+,d1-a6
  1620.     tst.l    d0
  1621.     rts
  1622.  
  1623. .TestIDEHW    move.l    d0,-(sp)
  1624.     move.w    GayleRev,d1
  1625.     cmp.w    #13,d1
  1626.     bne.b    .nohw
  1627.  
  1628.     moveq    #9,d0            Try 10 times:
  1629.     move.b    d0,(sp)
  1630. .try_again    move.b    (3,sp),($0018,a4)
  1631.     move.b    ($0010,a4),d1
  1632.     move.b    ($001C,a4),d0
  1633.     move.l    d0,a0
  1634.     and.b    #$C0,d0
  1635.     beq.b    .has2
  1636.     cmp.b    #$C0,d0
  1637.     beq.b    .nohw
  1638.     tst.b    d0
  1639.     bpl.b    .has
  1640.     move.l    a0,d0
  1641.     eor.b    d1,d0
  1642.     and.b    #$FD,d0
  1643.     bne.b    .nohw
  1644.     moveq    #2,d0
  1645.     bra.b    .exit
  1646.  
  1647. .has2    btst    #4,(3,sp)
  1648.     bne.b    .nohw
  1649.     subq.b    #1,(sp)
  1650.     bmi.b    .nohw
  1651.     bsr.b    WaitVBL
  1652.     bra.b    .try_again
  1653.  
  1654. .valid    moveq    #1,d0
  1655.     bra.b    .exit
  1656.  
  1657. .has    moveq    #$12,d0
  1658.     move.b    d0,($0010,a4)
  1659.     cmp.b    ($0010,a4),d0
  1660.     bne.b    .nohw
  1661.     moveq    #$34,d0
  1662.     move.b    d0,($0010,a4)
  1663.     cmp.b    ($0010,a4),d0
  1664.     beq.b    .valid
  1665. .nohw    moveq    #0,d0
  1666. .exit    addq.w    #4,sp
  1667.     rts
  1668.  
  1669.  
  1670. WaitVBL    moveq    #1,d0
  1671. WaitBlanks    movem.l    d2/a2/a3/a6,-(sp)
  1672.     move.l    d0,d2
  1673.     lea    (-$0022,sp),sp
  1674.     move.l    sp,a2
  1675.     move.b    #4,(8,a2)
  1676.     clr.b    (9,a2)
  1677.     clr.l    (10,a2)
  1678.     clr.b    (14,a2)
  1679.     move.b    #4,(15,a2)
  1680.     suba.l    a1,a1
  1681.     call    FindTask
  1682.     move.l    d0,($0010,a2)
  1683.     lea    ($0014,a2),a0
  1684.     move.l    a0,(8,a0)
  1685.     addq.l    #4,a0
  1686.     clr.l    (a0)
  1687.     move.l    a0,-(a0)
  1688.     lea    (-$0028,sp),sp
  1689.     move.l    sp,a3
  1690.     lea    (TimerDevName,pc),a0
  1691.     move.l    a3,a1
  1692.     moveq    #UNIT_VBLANK,d0
  1693.     moveq    #0,d1
  1694.     call    OpenDevice
  1695.     tst.l    d0
  1696.     bne.b    .exit
  1697.     move.l    a2,(IO+MN_REPLYPORT,a3)
  1698.     move.l    a3,a1
  1699.     move.w    #TR_ADDREQUEST,(IO_COMMAND,a1)
  1700.     clr.l    (IOTV_TIME+EV_HI,a1)
  1701.     move.l    d2,(IOTV_TIME+EV_LO,a1)
  1702.     call    DoIO
  1703.     move.l    a3,a1
  1704.     call    CloseDevice
  1705. .exit    lea    ($004A,sp),sp
  1706.     movem.l    (sp)+,d2/a2/a3/a6
  1707.     rts
  1708.  
  1709.  
  1710. GetDraCo    movem.l    d0-a6,-(sp)
  1711.     move.l    (4).w,a6        Use (4).w
  1712.     lea    (.DraCoName,pc),a1
  1713.     call    OpenResource
  1714.     tst.l    d0
  1715. ;;DEBUG
  1716.     beq.b    .nodraco
  1717.     st    DraCoID
  1718.     st    NoHW
  1719. .nodraco    movem.l    (sp)+,d0-a6
  1720.     rts
  1721.  
  1722. .DraCoName    dc.b    'draco.resource',0
  1723.     CNOP    0,4
  1724.  
  1725.  
  1726. GetUAE    movem.l    d0-a6,-(sp)
  1727.     move.l    (4).w,a6        Use (4).w
  1728.     call    Forbid
  1729.     move.l    (IVEXTER+IV_DATA,a6),d0
  1730.     beq.b    .nouae
  1731.     move.l    d0,a0            a0=lh
  1732.     lea    (.UAEName,pc),a1
  1733.     call    FindName
  1734.     tst.l    d0
  1735.     beq.b    .nouae
  1736.     st    UAEID
  1737. .nouae    call    Permit
  1738.     movem.l    (sp)+,d0-a6
  1739.     rts
  1740.  
  1741. .UAEName    dc.b    'UAE filesystem',0
  1742.     CNOP    0,4
  1743.  
  1744.  
  1745. GetPowerUP    movem.l    d0-a6,-(sp)
  1746.     lea    sPowerUPBuf,a0
  1747.     move.l    a0,PowerUP_ptr
  1748.     clr.b    (a0)
  1749.  
  1750.     move.l    (4).w,a6        Use (4).w
  1751.     cmp.w    #36,(LIB_VERSION,a6)
  1752.     blo    .oldkick
  1753.  
  1754.     moveq    #3*4,d0
  1755.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1
  1756.     call    AllocVec
  1757.     tst.l    d0
  1758.     beq    .nomem
  1759.     move.l    d0,a5
  1760.  
  1761.     lea    (.ppcName,pc),a1
  1762.     moveq    #44,d0
  1763.     call    OpenLibrary
  1764.     tst.l    d0
  1765.     beq    .noppc
  1766.     move.l    d0,a6
  1767.  
  1768.     move.l    #PPCINFOTAG_CPUCOUNT,(a5) Get CPU count
  1769.     move.l    a5,a0
  1770.     call    PPCGetInfo
  1771.     move.l    d0,d7
  1772.     beq    .nocpus
  1773.  
  1774.     st    PowerUPID
  1775.  
  1776.     lea    (sPowerUPFmt0,pc),a0
  1777.     move.l    d7,-(sp)
  1778.     move.l    sp,a1
  1779.     lea    sPowerUPBuf,a2
  1780.     bsr    Sprintf
  1781.     addq.l    #4,sp
  1782. .findend1    tst.b    (a2)+
  1783.     bne.b    .findend1
  1784.     subq.l    #1,a2
  1785.  
  1786.     moveq    #0,d6
  1787. .cpu_loop
  1788.     moveq    #-1,d5
  1789.     move.l    #PPCINFOTAG_CPU,(a5)    Version of the CPU
  1790.     move.l    d6,(4,a5)
  1791.     move.l    a5,a0
  1792.     call    PPCGetInfo
  1793.     moveq    #CPU_603,d1        3
  1794.     moveq    #CPU_604e,d2        9
  1795.     cmp.l    d1,d0
  1796.     blo.b    .unknown1
  1797.     cmp.l    d2,d0
  1798.     bhi.b    .unknown1
  1799.     move.l    d0,d5
  1800. .unknown1
  1801.     moveq    #10,d0
  1802.     cmp.w    #45,(LIB_VERSION,a6)
  1803.     blo.b    .noppldiv
  1804.     move.l    #PPCINFOTAG_CPUPLL,(a5)    PLL Divider of the CPU
  1805.     move.l    d6,(4,a5)
  1806.     move.l    a5,a0
  1807.     call    PPCGetInfo
  1808.     move.l    d0,d1
  1809.     and.l    #$FFFFFFF0,d1
  1810.     bne.b    .noppldiv
  1811.     moveq    #10,d0
  1812. .noppldiv    move.l    d0,-(sp)
  1813.  
  1814.     move.l    #PPCINFOTAG_CPUREV,(a5)    Get CPU revision
  1815.     move.l    d6,(4,a5)
  1816.     move.l    a5,a0
  1817.     call    PPCGetInfo
  1818.     lsl.l    #8,d0        ; ddccbbaa -> ccbbaa00
  1819.     lsr.w    #8,d0        ; ccbbaa00 -> ccbb00aa
  1820.     move.l    d0,-(sp)
  1821.  
  1822.     move.l    #PPCINFOTAG_CPUCLOCK,(a5) Clock of the CPU (Get CPU MHz)
  1823.     move.l    d6,(4,a5)
  1824.     move.l    a5,a0
  1825.     call    PPCGetInfo
  1826.     move.l    d0,-(sp)
  1827.  
  1828.     pea    (sPPCxx,pc)
  1829.     move.l    d5,d0
  1830.     bmi.b    .unknown2
  1831.     lea    (PowerPCTable,pc),a0
  1832.     move.l    sp,a1
  1833.     bsr    PutWStrPtr
  1834.  
  1835.     move.l    d5,d0
  1836.     lea    (PowerPCPLLTable,pc),a0
  1837.     add.w    d0,d0
  1838.     lea    (12,sp),a1
  1839.     add.w    (a0,d0.w),a0
  1840.     move.l    (4,sp),d0
  1841.     move.l    (a1),d1
  1842.     mulu.w    #10,d0
  1843.     add.w    d1,d1
  1844.     divu.w    0(a0,d1.w),d0
  1845.     move.l    d0,(a1)
  1846. .unknown2
  1847.     lea    (sPowerUPFmt1,pc),a0
  1848.     move.l    sp,a1
  1849.     ;a2=buffer
  1850.     bsr    Sprintf
  1851.     lea    (4*4,sp),sp
  1852. .findend2    tst.b    (a2)+
  1853.     bne.b    .findend2
  1854.     subq.l    #1,a2
  1855.  
  1856.     addq.l    #1,d6
  1857.     subq.l    #1,d7
  1858.     bne    .cpu_loop
  1859.  
  1860.     move.b    #10,(a2)+        LF
  1861.     clr.b    (a2)
  1862.  
  1863. .nocpus    move.l    a6,a1
  1864.     move.l    (4).w,a6        Use (4).w
  1865.     call    CloseLibrary
  1866. .noppc    move.l    a5,a1
  1867.     call    FreeVec
  1868. .nomem
  1869. .oldkick    movem.l    (sp)+,d0-a6
  1870.     rts
  1871.  
  1872. .ppcName    dc.b    'ppc.library',0
  1873.     CNOP    0,4
  1874.  
  1875.  
  1876. GetMisc    movem.l    d0-d7/a0-a6,-(sp)
  1877.     move.l    (ExecBase00,pc),a6
  1878.     lea    (.CardName,pc),a1
  1879.     call    OpenResource
  1880.     tst.l    d0
  1881.     sne    CardSlotID
  1882.  
  1883.     move.l    (IVPORTS,a6),a0
  1884.     lea    (.ATIDEName,pc),a1
  1885.     bsr    .findnametest
  1886.     sne    ATIDEID
  1887.  
  1888.     lea    (DeviceList,a6),a0
  1889.     lea    (.CDTVDevName,pc),a1
  1890.     bsr    .findnametest
  1891.     sne    CDTVID
  1892.  
  1893.     lea    (.A690IDName,pc),a1
  1894.     call    FindResident
  1895.     tst.l    d0
  1896.     beq.b    .no_A690
  1897.     st    A690ID
  1898.     clr.b    CDTVID
  1899. .no_A690
  1900.     lea    (sNullStr,pc),a0
  1901.     move.l    a0,C2P
  1902.     move.l    _GfxBase,a0
  1903.     cmp.w    #40,(LIB_VERSION,a0)
  1904.     blo.b    .no40
  1905.     tst.l    (gb_ChunkyToPlanarPtr,a0)
  1906.     beq.b    .noC2P
  1907.     lea    (sHWC2P,pc),a0
  1908.     move.l    a0,C2P
  1909.     st    C2PID
  1910.  
  1911.     lea    (.NonvolName,pc),a1
  1912.     moveq    #40,d0
  1913.     call    OpenLibrary
  1914.     tst.l    d0
  1915.     beq.b    .nononvol
  1916.     move.l    d0,a6
  1917.  
  1918.     moveq    #1,d1            Kill requesters
  1919.     call    GetNVInfo
  1920.     tst.l    d0
  1921.     beq.b    .caseoffailure
  1922.     move.l    d0,a0
  1923.  
  1924.     move.l    (a0),d0            nvi_MaxStorage
  1925.     beq.b    .noNV
  1926.     cmp.l    #128*1024,d0        Estimated...
  1927.     slo    CD32NVRAMID        It's not an emulator!
  1928. .noNV    call    FreeNVData
  1929.  
  1930. .caseoffailure    move.l    a6,a1
  1931.     move.l    (ExecBase00,pc),a6
  1932.     call    CloseLibrary
  1933. .nononvol
  1934. .noC2P
  1935. .no40
  1936.     move.l    _DosBase,a1        Find UNI/01 partitions:
  1937.     move.l    (dl_Root,a1),a2
  1938.     moveq    #DLT_VOLUME,d1
  1939.  
  1940.     move.l    (ExecBase00,pc),a6
  1941.     call    Forbid
  1942.  
  1943.     move.l    (rn_Info,a2),a0
  1944.     add.l    a0,a0
  1945.     add.l    a0,a0
  1946.     move.l    (di_DevInfo,a0),d0
  1947. .nextdev    beq.b    .devs_scanned
  1948.     lsl.l    #2,d0
  1949.     move.l    d0,a0
  1950.     cmp.l    (dl_Type,a0),d1        (d1=DLT_VOLUME)
  1951.     bne.b    .gnd
  1952.     cmp.l    #ID_UNIX_DISK,(dl_DiskType,a0)
  1953.     seq    UNIXID
  1954.     beq.b    .devs_scanned
  1955. .gnd    move.l    (a0),d0            dl_Next
  1956.     bra.b    .nextdev
  1957.  
  1958. .devs_scanned    call    Permit
  1959.  
  1960.     move.l    #$202<<16+80,d0        Try to find 'A2620 68020 Accelerator / RAM Board'
  1961.     bsr    FindConfigDev
  1962.     sne    A2500ID
  1963.     bne.b    .is2500
  1964.     move.l    #$202<<16+81,d0        Try to find 'A2630 68030 Accelerator / RAM Board'
  1965.     bsr    FindConfigDev
  1966.     sne    A2500ID
  1967. .is2500
  1968.  
  1969.     move.l    #$202<<16+84,d0        Try to find 'CBM A4091 SCSI/SCSI-II HD Controller'
  1970.     bsr    FindConfigDev
  1971.     sne    A4091ID
  1972.  
  1973.     move.l    #$2140<<16!$FFFF,d0    Try to find any 'Phase 5 Digital Products'
  1974.     bsr    FindConfigDev
  1975.     sne    Phase5ID
  1976.  
  1977.  
  1978.  
  1979.     bsr    GetPowerUP
  1980.     DBG    'gpup'
  1981.  
  1982.     bsr    GetUAE
  1983.     DBG    'guae'
  1984.  
  1985.     bsr    GetClock
  1986.     move.l    d0,HWClockID
  1987.     DBG    'gclk'
  1988.  
  1989.     movem.l    (sp)+,d0-d7/a0-a6
  1990.     rts
  1991.  
  1992. .findnametest    call    Disable
  1993.     call    FindName
  1994.     call    Enable
  1995.     tst.l    d0
  1996.     rts
  1997.  
  1998. .CardName    dc.b    'card.resource',0
  1999. .CDTVDevName    dc.b    'cdtv.device',0
  2000. .A690IDName    dc.b    'A690ID',0
  2001. .ATIDEName    dc.b    'AT-IDE',0
  2002. .NonvolName    dc.b    'nonvolatile.library',0
  2003.     CNOP    0,4
  2004.  
  2005.  
  2006. ;  IN: -
  2007. ; OUT: d0=zero if no clock, nonzero if clock found
  2008. GetClock    movem.l    d1-a6,-(sp)
  2009.     moveq    #0,d7
  2010.     move.l    (ExecBase00,pc),a6
  2011.     call    Forbid
  2012.     lea    (.battclockres,pc),a1
  2013.     call    OpenResource
  2014.     tst.l    d0
  2015.     beq.b    .nores
  2016.     move.l    d0,a6
  2017.     jsr    (-12,a6)
  2018.     move.l    (ExecBase00,pc),a6
  2019.     tst.l    d0
  2020.     beq.b    .exit
  2021.     bra.b    .found
  2022.  
  2023. .nores    lea    $DC0001,a0
  2024.     moveq    #0,d2
  2025.     moveq    #0,d1
  2026. .loop    moveq    #15,d2
  2027.     and.b    (a0),d2
  2028.     cmp.b    #9,d2
  2029.     beq.b    .loop
  2030.     addq.b    #1,d2
  2031.     bsr.b    .wait
  2032.     moveq    #$F,d1
  2033.     and.b    (a0),d1
  2034.     sub.b    d2,d1
  2035.     beq.b    .found
  2036.     cmp.b    #1,d1
  2037.     bne.b    .exit
  2038. .found    moveq    #1,d7
  2039. .exit    call    Permit
  2040.     move.l    d7,d0
  2041.     movem.l    (sp)+,d1-a6
  2042.     rts
  2043.  
  2044. .wait    bsr.b    .wait2
  2045.     move.l    d0,d1
  2046. .wloop    bsr.b    .wait2
  2047.     sub.l    d1,d0
  2048.     cmp.l    #60,d0
  2049.     bne.b    .wloop
  2050.     rts
  2051. .wait2    moveq    #0,d0
  2052.     move.b    $BFEA01,d0
  2053.     lsl.w    #8,d0
  2054.     move.b    $BFE901,d0
  2055.     lsl.l    #8,d0
  2056.     move.b    $BFE801,d0
  2057.     rts
  2058.  
  2059. .battclockres    dc.b    'battclock.resource',0
  2060.     CNOP    0,2
  2061.  
  2062.  
  2063. GetProcInfo    movem.l    d0-a6,-(sp)
  2064.     lea    (sNullStr,pc),a2
  2065.     tst.b    _AttnFlags+1
  2066.     bpl.b    .no060
  2067.  
  2068.     lea    (.getpcr,pc),a5
  2069.     call    Supervisor
  2070.     lsr.w    #8,d0
  2071.     swap    d0            d0.l=rev<<16!id
  2072.     move.l    d0,-(sp)
  2073.  
  2074.     lea    (sProcInfo060Fmt,pc),a0
  2075.     move.l    sp,a1
  2076.     lea    sPI060Buffer,a2
  2077.     bsr    Sprintf
  2078.     move.l    (sp)+,d0
  2079.  
  2080.     cmp.w    #%0000010000110000,d0    fix CPUID according to CPU internal info
  2081.     bne.b    .not68060
  2082.  
  2083.     move.l    #MC68060,CPUID
  2084.  
  2085. .not68060    cmp.w    #%0000010000110001,d0
  2086.     bne.b    .not68xx060
  2087.  
  2088.     move.l    #MC68EC060,CPUID    no FPU, no MMU -> EC060
  2089.  
  2090.     tst.l    _MMUID
  2091.     beq.b    .nommu
  2092.     move.l    #MC68LC060,CPUID    no FPU, MMU -> LC060
  2093. .nommu
  2094. .not68xx060
  2095.  
  2096. .no060    move.l    a2,procinfo_ptr
  2097.     movem.l    (sp)+,d0-a6
  2098.     rts
  2099.  
  2100. .getpcr    or.w    #$700,sr
  2101.     dc.w    $4E7A,$0808    movec    pcr,d0
  2102.     nop
  2103.     rte
  2104.  
  2105.  
  2106.  
  2107. GetCPU    jsr    GetAddressBits
  2108.     move.l    d0,AddrBits
  2109.  
  2110.     DBG    'gabi'
  2111.  
  2112.     move.w    _AttnFlags,d0
  2113.     bsr    GetMinCPUnum
  2114.     move.l    d0,d7
  2115.  
  2116.     cmp.b    #MIN020,d7
  2117.     bne.b    .not_020
  2118.     cmp.w    #32,AddrBits+2
  2119.     bne.b    .is_EC020
  2120.     st    _EC
  2121.     addq.l    #MC68020-MC68EC020,d7
  2122. .is_EC020    bra.b    .proc_ok
  2123. .not_020
  2124.     cmp.b    #MIN030,d7
  2125.     bne.b    .not_030
  2126.     tst.l    _MMUID
  2127.     beq.b    .is_EC030
  2128.     addq.l    #MC68030-MC68EC030,d7
  2129. .is_EC030    bra.b    .proc_ok
  2130. .not_030
  2131.     cmp.b    #MIN040,d7
  2132.     beq.b    .test_040
  2133.     cmp.b    #MIN060,d7
  2134.     bne.b    .not_040
  2135.  
  2136. .test_040    btst    #AFB_FPU40,_AttnFlags+1
  2137.     bne.b    .is_full
  2138.     tst.l    _MMUID
  2139.     beq.b    .proc_ok
  2140.     addq.l    #1,d7
  2141.     bra.b    .proc_ok
  2142. .is_full    addq.l    #2,d7
  2143. ;;    bra.b    .proc_ok
  2144. .not_040
  2145. .proc_ok
  2146.     move.l    d7,CPUID
  2147.  
  2148.     IFGT    0
  2149.     move.l    (4).w,a6
  2150.     move.w    _AttnFlags,d0
  2151.     btst    #AFB_68030,d0        If 68000, 68010 or 68020 use old one.
  2152.     beq.b    .getmhz_old
  2153.     cmp.w    #37,(LIB_VERSION,a6)    If V37+ and 68030+ use new one.
  2154.     blo.b    .getmhz_old
  2155.     bsr    GetMHz
  2156.     bra.b    .getmhz_new
  2157.     ENDC
  2158.  
  2159. .getmhz_old    bsr    GetMHz_old
  2160. .getmhz_new    move.l    d0,_100kHz
  2161.  
  2162.  
  2163.     lea    (s68000,pc),a0
  2164.     moveq    #7,d1
  2165.     move.l    CPUCompareTime,d0
  2166.     divu.w    #180356/4,d0        68000 @ 7 MHz
  2167.     addq.w    #4/2,d0            Add 0.5 for correct rounding!
  2168.     lsr.w    #2,d0            /4
  2169.     cmp.w    #16,d0
  2170.     bls.b    .cmpbaseok
  2171.  
  2172.     lea    (s68030,pc),a0
  2173.     moveq    #25,d1
  2174.     move.l    CPUCompareTime,d0
  2175.     divu.w    #1442744/32,d0        68030 @ 25 MHz
  2176.     add.w    #32/2,d0        Add 0.5 for correct rounding!
  2177.     lsr.w    #5,d0            /32
  2178.  
  2179. .cmpbaseok    move.w    d0,Multiplier
  2180.     move.l    a0,CmpCPU_ptr
  2181.     move.w    d1,CmpCPUMHz
  2182.  
  2183.     rts
  2184.  
  2185.  
  2186. ;  IN: D0.w=attnflags
  2187. ; OUT: D0.l=procnum
  2188. GetMinCPUnum    move.l    d1,-(sp)
  2189.     move.l    d0,d1
  2190.     moveq    #0,d0
  2191.     btst    #AFB_68010,d1
  2192.     beq.b    .exit
  2193.     moveq    #MC68010,d0
  2194.     btst    #AFB_68020,d1
  2195.     beq.b    .exit
  2196.     moveq    #MIN020,d0
  2197.     btst    #AFB_68030,d1
  2198.     beq.b    .exit
  2199.     moveq    #MIN030,d0
  2200.     btst    #AFB_68040,d1
  2201.     beq.b    .exit
  2202.     moveq    #MIN040,d0
  2203.     tst.b    d1            Test #AFB_68060
  2204.     bpl.b    .exit
  2205.     moveq    #MIN060,d0
  2206.  
  2207. .exit    move.l    (sp)+,d1
  2208.     rts
  2209.  
  2210.  
  2211.     ; New MHz calculator
  2212.  
  2213.     IFND    _LVOSubTime
  2214. _LVOSubTime    EQU    -$30
  2215.     ENDC
  2216.  
  2217. ; OUT: D0=100kHz
  2218. GetMHz    movem.l    d1-d7/a0-a6,-(sp)
  2219.     moveq    #0,d7    
  2220.     move.l    (4).w,a6
  2221.  
  2222.     lea    (.utilname,pc),a1
  2223.     moveq    #37,d0
  2224.     call    OpenLibrary
  2225.     move.l    d0,_gcUtilBase
  2226.     beq.b    .noutil
  2227.  
  2228.     lea    (DeviceList,a6),a0
  2229.     lea    (.timername,pc),a1
  2230.     call    Forbid
  2231.     call    FindName
  2232.     call    Permit
  2233.     move.l    d0,_gcTimerBase
  2234.     beq.b    .notimer
  2235.  
  2236.     move.w    _AttnFlags,d0
  2237.     bsr    .get
  2238.     move.l    d0,d7
  2239.  
  2240. .notimer    move.l    _gcUtilBase,a1
  2241.     move.l    (4).w,a6
  2242.     call    CloseLibrary
  2243.  
  2244. .noutil    move.l    d7,d0
  2245.     movem.l    (sp)+,d1-d7/a0-a6
  2246.     rts
  2247.  
  2248. .gfxname    dc.b    'graphics.library',0
  2249. .utilname    dc.b    'utility.library',0
  2250. .timername    dc.b    'timer.device',0
  2251.     CNOP    0,2
  2252.  
  2253.  
  2254. ;  IN: D0.w=attnflags
  2255. ; OUT: D0=100kHz<<16+procnum
  2256. .get    movem.l    d1-d3/d6-d7,-(sp)
  2257.     move.l    d0,d6
  2258.     moveq    #0,d7
  2259.  
  2260.     bsr    .DoTimer
  2261.     move.l    d0,WAIndex
  2262.     tst.l    d0
  2263.     beq    .gcerror
  2264.     tst.l    _gcETicker
  2265.     beq    .gcerror
  2266.     move.l    CPUID,d1
  2267.     add.l    d1,d1
  2268.     add.l    d1,d1
  2269.     move.l    .gcSpeedTable(pc,d1.l),d2
  2270.  
  2271.     move.l    _gcUtilBase,a6
  2272.     move.l    #100,d1
  2273.     call    UMult32
  2274.     move.l    _gcETicker,d1
  2275.     call    UDivMod32
  2276.     move.l    d0,d1
  2277.     beq    .gcerror
  2278.     move.l    d2,d0
  2279.     call    UDivMod32
  2280.  
  2281.     move.l    d0,d7
  2282. .gcerror
  2283.     move.l    d7,d0
  2284.     movem.l    (sp)+,d1-d3/d6-d7
  2285.     rts
  2286.  
  2287. .gcSpeedTable
  2288.     dc.l    ($1016BF*100/70938)*5000+5000    000  7.09379 MHz
  2289.     dc.l    ($1016BF*100/70938)*5000+5000    010  7.09379 MHz
  2290.     dc.l    ($ADDBB*100/70938)*4000+4000    020 14.18758 MHz
  2291.     dc.l    ($ADDBB*100/70938)*4000+4000
  2292.     dc.l    ($ADDBB*100/70938)*4000+4000    030 40.00000 MHz
  2293.     dc.l    ($ADDBB*100/70938)*4000+4000
  2294.     dc.l    ($341BF*100/70938)*4000+4000    040 40.00000 MHz
  2295.     dc.l    ($341BF*100/70938)*4000+4000
  2296.     dc.l    ($341BF*100/70938)*4000+4000
  2297.     dc.l    ($116BF*100/70938)*5000+5000    060 50.00000 MHz
  2298.     dc.l    ($116BF*100/70938)*5000+5000
  2299.     dc.l    ($116BF*100/70938)*5000+5000
  2300.  
  2301.  
  2302. ;  IN: d6.w=attnflags
  2303. ; OUT: D0.l=compare time
  2304. .DoTimer    movem.l    d1-d7/a0-a6,-(sp)
  2305.     move.l    (4).w,a6
  2306.  
  2307.     move.l    _ThisTask,a1
  2308.     moveq    #127,d0
  2309.     call    SetTaskPri
  2310.     move.l    d0,-(sp)
  2311.  
  2312.     cmp.w    #4,BandWidth
  2313.     beq.b    .is_aga4x
  2314.     move.l    _GfxBase,a6
  2315.     move.l    (gb_ActiView,a6),-(sp)    save view
  2316.     sub.l    a1,a1
  2317.     call    LoadView
  2318.     call    WaitTOF
  2319.     call    WaitTOF
  2320. .is_aga4x
  2321.     move.l    _GfxBase,a6
  2322.     call    WaitBlit        Wait possible blit to finish.
  2323.  
  2324.     bsr    .timing2
  2325.     move.l    d0,d7
  2326.  
  2327.     cmp.w    #4,BandWidth        Restore view, if needed
  2328.     beq.b    .is_aga4x2
  2329.     move.l    _GfxBase,a6
  2330.     move.l    (sp)+,a1
  2331.     call    LoadView
  2332.     call    WaitTOF
  2333.     call    WaitTOF
  2334. .is_aga4x2
  2335.     move.l    (4).w,a6
  2336.     move.l    _ThisTask,a1
  2337.     move.l    (sp)+,d0
  2338.     call    SetTaskPri
  2339.  
  2340.     move.l    d7,d0
  2341.     movem.l    (sp)+,d1-d7/a0-a6
  2342.     rts
  2343.  
  2344.  
  2345. ;  IN: d6.w=attnflags
  2346. .timing2    move.l    (4).w,a6
  2347.     moveq    #MEMF_CHIP,d1            chipmem for 000 and 010
  2348.     btst    #AFB_68020,d6
  2349.     beq.b    .tgoalloc
  2350.     move.l    #MEMF_ANY!MEMF_PUBLIC,d1    any mem for 020
  2351.     btst    #AFB_68030,d6
  2352.     beq.b    .tgoalloc
  2353.     move.l    #MEMF_FAST!MEMF_PUBLIC,d1    fastmem for 030, 040 and 060
  2354. .tgoalloc
  2355.     move.l    #CODE020SIZE,d0
  2356.     call    AllocVec
  2357.     tst.l    d0
  2358.     beq    .nomem
  2359.     move.l    d0,a5
  2360.     lea    (.code020,pc),a0
  2361.     move.l    a5,a1
  2362.     move.l    #CODE020SIZE,d0
  2363.     call    CopyMemQuick
  2364.  
  2365.     call    Forbid
  2366.  
  2367.     move.l    #CACRF_EnableI,d0    Disable all but inst cache for test
  2368.     move.l    #~CACRF_WriteAllocate,d1
  2369.     call    CacheControl
  2370.     move.l    d0,-(sp)        Save prev cache state
  2371.  
  2372.     bsr    turnon060caches
  2373.  
  2374.     jsr    (a5)
  2375.  
  2376.     bsr    restore060caches
  2377.  
  2378.     move.l    (4).w,a6        Restore cache state
  2379.     move.l    (sp)+,d0
  2380.     move.l    #~CACRF_WriteAllocate,d1
  2381.     call    CacheControl
  2382.  
  2383.     call    Permit
  2384.  
  2385.     move.l    a5,a1
  2386.     call    FreeVec
  2387.  
  2388.     move.l    _gcTimerBase,a6
  2389.     move.l    a3,a0
  2390.     move.l    a2,a1
  2391.     call    SubTime
  2392.     move.l    (EV_LO,a3),d0
  2393.     rts
  2394.  
  2395. .nomem    moveq    #0,d0
  2396.     rts
  2397.  
  2398.     CNOP    0,8
  2399. .code020    tst.l    NoHW            ** NO PC REL!
  2400.     bne.b    .skiphw1
  2401.     lea    $DFF000,a4
  2402.     move.w    (intenar,a4),d0
  2403.     move.w    #$7FFF,(intena,a4)
  2404.     swap    d0
  2405.     move.w    (dmaconr,a4),d0
  2406.     move.w    #$000F,(dmacon,a4)    Disable audio
  2407.     move.w    #$C008,(intena,a4)    Enable INT2 & CIAA int
  2408.     or.l    #$80008000,d0
  2409.     move.l    d0,-(sp)
  2410. .skiphw1
  2411.     move.l    _gcTimerBase,a6        ** NO PC REL!
  2412.     lea    _gcStartE,a2        ** NO PC REL!
  2413.     lea    _gcEndE,a3        ** NO PC REL!
  2414.     move.l    #5000000,d4
  2415.  
  2416.     move.l    a2,a0
  2417.     call    ReadEClock
  2418.     bra.b    .loop020
  2419.     CNOP    0,8
  2420. .loop020    subq.l    #1,d4
  2421.     bne.b    .loop020
  2422.  
  2423.     move.l    a3,a0
  2424.     call    ReadEClock
  2425.     add.w    #50,d0
  2426.     divu.w    #100,d0
  2427.     and.l    #$0FFFF,d0
  2428.     move.l    d0,_gcETicker        ** NO PC REL!
  2429.  
  2430.     tst.l    NoHW            ** NO PC REL!
  2431.     bne.b    .skiphw2
  2432.     move.l    (sp)+,d0
  2433.     move.w    #$7FFF,(intena,a4)
  2434.     move.w    d0,(dmacon,a4)
  2435.     swap    d0
  2436.     move.w    d0,(intena,a4)
  2437. .skiphw2    rts
  2438. CODE020SIZE    EQU    (*-.code020+7)&-8
  2439.  
  2440.  
  2441.  
  2442. turnon060caches
  2443.     tst.b    _AttnFlags+1        Test #AFB_68060
  2444.     bpl.b    .exit
  2445.     movem.l    d0-d1/a5-a6,-(sp)
  2446.     move.l    (4).w,a6
  2447.     lea    (.turnon,pc),a5
  2448.     call    Supervisor
  2449.     movem.l    (sp)+,d0-d1/a5-a6
  2450. .exit    rts    
  2451.  
  2452. .turnon    or.w    #$700,sr
  2453.     dc.w    $4E7A,$0002    movec    cacr,d0
  2454.     dc.w    $4E7A,$1808    movec    pcr,d1
  2455.     and.l    #$F8E0E000,d0    mask all 060 used bits
  2456.     and.l    #$00000083,d1    ditto
  2457.     move.l    d0,_gcoldcacr    store old values
  2458.     move.l    d1,_gcoldpcr    for restore
  2459.     and.l    #~$D8006000,d0    EDC off, NAD off, DPI off, FOC off, NAI off, FIC off
  2460.     or.l    #$20808000,d0    enable store buffer, enable instruction cache, enable branch cache
  2461.     or.w    #$1,d1        enable superscalar dispatch
  2462. _restorego    or.w    #$700,sr
  2463.     dc.w    $4E7B,$0002    movec    d0,cacr
  2464.     dc.w    $4E7B,$1808    movec    d1,pcr
  2465.     dc.w    $F518,$F4F8,$F4D8
  2466.     nop
  2467.     rte
  2468.  
  2469.  
  2470. restore060caches
  2471.     tst.b    _AttnFlags+1        Test #AFB_68060
  2472.     bpl.b    .exit
  2473.     movem.l    d0-d1/a5-a6,-(sp)
  2474.     move.l    (4).w,a6
  2475.     lea    (_restorego,pc),a5
  2476.     move.l    _gcoldcacr,d0
  2477.     move.l    _gcoldpcr,d1
  2478.     call    Supervisor
  2479.     movem.l    (sp)+,d0-d1/a5-a6
  2480. .exit    rts    
  2481.  
  2482.     CNOP    0,4
  2483. _gcUtilBase    dc.l    0
  2484. _gcTimerBase    dc.l    0
  2485. _gcStartE    dc.l    0,0
  2486. _gcEndE    dc.l    0,0
  2487. _gcETicker    dc.l    0
  2488. _gcoldcacr    dc.l    0
  2489. _gcoldpcr    dc.l    0
  2490.  
  2491.  
  2492.  
  2493. ; OUT: D0.l=100kHz
  2494. GetMHz_old    movem.l    d1-d3/d7/a5-a6,-(sp)
  2495.     move.l    (4).w,a6
  2496.     moveq    #0,d7
  2497.  
  2498.     tst.l    DraCoID
  2499.     bne    .draco
  2500.  
  2501.     lea    (sNoHW,pc),a0
  2502.     tst.l    NoHW
  2503.     bne    .printerr
  2504.  
  2505.     moveq    #MEMF_CHIP,d1            chipmem for 000, 010, 020 and 030
  2506.     btst    #AFB_68040,_AttnFlags+1
  2507.     beq.b    .tgoalloc
  2508.     move.l    #MEMF_FAST!MEMF_PUBLIC,d1    fastmem for 040 and 060
  2509. .tgoalloc
  2510.     moveq    #CPUTIMER_SIZEOF,d0
  2511.     call    AllocMem
  2512.     tst.l    d0
  2513.     beq    .exit
  2514.     move.l    d0,a5
  2515.     move.l    d0,a1
  2516.     lea    CPU_chiptiming,a0
  2517.     moveq    #CPUTIMER_SIZEOF,d0
  2518.     call    CopyMem    
  2519.  
  2520.     bsr    InitTimer
  2521.     lea    (sNotimer,pc),a0
  2522.     move.l    d0,TimerBit
  2523.     bmi.b    .printerr
  2524.     moveq    #1,d1
  2525.     lsl.l    d0,d1
  2526.     move.l    d1,TimerMask
  2527.  
  2528.     DBG    'itim'
  2529.  
  2530.     move.l    a5,a0
  2531.     bsr    DoTimer
  2532.     move.l    d0,CPUCompareTime
  2533.     move.l    d0,WAIndex
  2534.     move.l    TimerBit,d0
  2535.     bsr    RemTimer
  2536.  
  2537.     DBG    'dtim'
  2538.  
  2539.     move.l    CPUID,d1
  2540.     add.l    d1,d1
  2541.     move.w    .SpeedCompareTable(pc,d1.l),d2
  2542.     move.w    d2,d3
  2543.     lsr.w    #1,d3            \
  2544.     ext.l    d3             > add 0.5 for rounding
  2545.     add.l    CPUCompareTime,d3    /
  2546.     divu.w    d2,d3
  2547.     move.w    d3,d7
  2548.  
  2549.     move.l    (4).w,a6
  2550.     move.l    a5,a1
  2551.     moveq    #CPUTIMER_SIZEOF,d0
  2552.     call    FreeMem
  2553.  
  2554. .exit    move.l    d7,d0
  2555.     movem.l    (sp)+,d1-d3/d7/a5-a6
  2556.     rts
  2557.  
  2558. .draco    move.l    #500,d7            50.0 MHz
  2559.     bra.b    .exit
  2560.  
  2561. .printerr    pea    (sCPU,pc)
  2562.     move.l    a0,-(sp)
  2563.     lea    (sMhzxxxErr,pc),a0
  2564.     move.l    sp,a1
  2565.     bsr    Printf
  2566.     addq.l    #8,sp
  2567.     bra.b    .exit
  2568.  
  2569. .SpeedCompareTable
  2570.     dc.w    2542    000  7.09379 MHz  180355.75 !
  2571.     dc.w    2542    010  7.09379 MHz  180355.75 !
  2572.     dc.w    5771    020 14.18758 MHz  818761.57 !
  2573.     dc.w    5771
  2574.     dc.w    5771    030 50.00000 MHz 2885487.07 ! 25.00000 MHz 1443364!
  2575.     dc.w    5771
  2576.     dc.w    15396    040 40.00000 MHz 6158519.00 !
  2577.     dc.w    15396
  2578.     dc.w    15396
  2579.     dc.w    46187    060 50.00000 MHz 23093284.5 !
  2580.     dc.w    46187
  2581.     dc.w    46187
  2582.  
  2583.  
  2584. ;  IN: D0.w=attnflags
  2585. ; OUT: D0.l=FPUID, 0=n/a, 1=68881, 2=68882, 3=68040, 4=68060
  2586. GetMinFPUnum    move.l    d1,-(sp)
  2587.     move.w    d0,d1
  2588.     moveq    #NOMATH,d0
  2589.     btst    #AFB_68040,d1
  2590.     beq.b    .no_040FPU
  2591.     btst    #AFB_FPU40,d1
  2592.     beq.b    .exit
  2593.     moveq    #MC68040i,d0
  2594.     tst.b    d1            Test #AFB_68060
  2595.     bpl.b    .exit
  2596.     moveq    #MC68060i,d0
  2597.     bra.b    .exit
  2598.  
  2599. .no_040FPU    moveq    #0,d0
  2600.     btst    #AFB_68882,d1
  2601.     beq.b    .no882
  2602.     moveq    #MC68882,d0
  2603.     bra.b    .exit
  2604. .no882    btst    #AFB_68881,d1
  2605.     beq.b    .no881
  2606.     moveq    #MC68881,d0
  2607.     ;bra.b    .exit
  2608. .no881
  2609. .exit    move.l    (sp)+,d1
  2610.     rts
  2611.  
  2612. ;  IN: D0.w=attnflags
  2613. ; OUT: D0.l=100kHz<<16+FPUID, 0=n/a, 1=68881, 2=68882, 3=68040, 4=68060
  2614. GetFPU    movem.l    d1-a6,-(sp)
  2615.     bsr    GetMinFPUnum
  2616.     move.l    d0,d7
  2617.     beq.b    .exit
  2618.  
  2619.     tst.l    DraCoID
  2620.     bne.b    .draco
  2621.  
  2622.     lea    (sNoHW,pc),a0
  2623.     tst.l    NoHW
  2624.     bne.b    .printerr
  2625.  
  2626.     bsr    InitTimer
  2627.     lea    (sNotimer,pc),a0
  2628.     move.l    d0,TimerBit
  2629.     bmi.b    .printerr
  2630.     moveq    #1,d1
  2631.     lsl.l    d0,d1
  2632.     move.l    d1,TimerMask
  2633.  
  2634.     DBG    'fiti'
  2635.  
  2636.     lea    FPU_chiptiming,a0
  2637. ;;    bsr    DoTimer
  2638.     move.l    d0,FPUCompareTime
  2639.     move.l    TimerBit,d0
  2640.     bsr    RemTimer
  2641.  
  2642.     DBG    'fdti'
  2643.  
  2644.     ; on 881 8 fadd/fsub take 8*51 cycles
  2645.     ; on 882 8 fadd fsub (8*56)-(8*17) cycles
  2646.  
  2647.     move.l    d7,d1
  2648.     add.l    d1,d1
  2649.     move.w    .SpeedCompareTable-2(pc,d1.l),d2
  2650.     ;move.w    d2,d3
  2651.     ;lsr.w    #1,d3            \
  2652.     ;ext.l    d3             > add 0.5 for rounding
  2653.     ;add.l    FPUCompareTime,d3    /
  2654.     move.l    FPUCompareTime,d3
  2655.     divu.w    d2,d3
  2656.     swap    d7
  2657.     move.w    d3,d7
  2658.     swap    d7
  2659.  
  2660. .exit    move.l    d7,d0
  2661.     movem.l    (sp)+,d1-a6
  2662.     rts
  2663.  
  2664.     ; Should use CPU MHz as default instead :)
  2665. .draco    or.l    #500<<16,d7        50.0 MHz
  2666.     bra.b    .exit
  2667.  
  2668. .printerr    pea    (sFPU,pc)
  2669.     move.l    a0,-(sp)
  2670.     lea    (sMhzxxxErr,pc),a0
  2671.     move.l    sp,a1
  2672.     bsr    Printf
  2673.     addq.l    #8,sp
  2674.     bra.b    .exit
  2675.  
  2676. .SpeedCompareTable
  2677.     dc.w    1126680/16/500    881
  2678.     dc.w    173203/500    882 50.00000 MHz  112669
  2679.     dc.w    225*8        040 40.00000 MHz  
  2680.     dc.w    225*16        060 50.00000 MHz  
  2681.  
  2682.  
  2683.  
  2684.  
  2685. ;  IN: GfxBase in _GfxBase
  2686. ; OUT: d0=0=OCS, 1=ECS, 2=AGA, 3=CyberGfx, 4=Picasso96, 5=Probench, 6=EGS, 7=Retina,
  2687. ;         8=Graffiti, 9=TIGA, 10=Altais
  2688. ;      d1=bandwidth (1, 2 or 4)
  2689. GetGfxLibEmul    move.l    d2,-(sp)
  2690.  
  2691.     moveq    #0,d0
  2692.     move.w    AnimChipID+2,d1
  2693.     subq.w    #5,d1
  2694.     bmi.b    .oldtestdone
  2695.     moveq    #1,d0
  2696. ;;    subq.w    #8-4,d1
  2697. ;;    bmi.b    .oldtestdone
  2698. .oldtestdone
  2699.     moveq    #1,d1
  2700.     move.l    _GfxBase,a0
  2701.     cmp.w    #37,(LIB_VERSION,a0)
  2702.     blo.b    .xit
  2703.     move.b    (gb_ChipRevBits0,a0),d2
  2704.     move.b    d2,d1
  2705.     moveq    #0,d0             OCS %10001
  2706.     and.b    #GFXF_HR_DENISE|GFXF_AA_LISA|GFXF_AA_ALICE,d1 %0xxx0
  2707.     beq.b    .done
  2708.     moveq    #2,d0              AGA %11111
  2709.     cmp.b    #GFXF_HR_DENISE|GFXF_AA_LISA|GFXF_AA_ALICE,d1
  2710.     beq.b    .done
  2711.     moveq    #1,d0            ECS %10011
  2712. ;;    cmp.b    #GFXF_HR_DENISE,d1
  2713. ;;    beq.b    .done
  2714. .done
  2715.     moveq    #0,d1
  2716.     move.b    (gb_MemType,a0),d1
  2717.     and.b    #3,d1
  2718.     addq.l    #1,d1
  2719.     cmp.b    #3,d1
  2720.     bne.b    .xit
  2721.     subq.l    #1,d1
  2722. .xit
  2723.     bsr.b    .getgfxg
  2724.  
  2725.     move.l    (sp)+,d2
  2726.     tst.l    d0
  2727.     rts
  2728.  
  2729.  
  2730. ; OUT: d0=0=OCS, 1=ECS, 2=AGA, 3=CyberGfx, 4=Picasso96, 5=Probench, 6=EGS, 7=Retina,
  2731. ;         8=Graffiti, 9=TIGA, 10=Altais
  2732.  
  2733. ; DosBase in _DosBase, ThisTask in _ThisTask
  2734.  
  2735. .getgfxg    tst.b    DraCoID
  2736.     beq.b    .not_altais
  2737.     moveq    #10,d0
  2738.     rts
  2739. .not_altais    movem.l    d0-a6,-(sp)
  2740.     move.l    (ExecBase00,pc),a6
  2741.  
  2742.     lea    (.picassortg,pc),a1
  2743.     lea    (LibList,a6),a0
  2744.     call    FindName
  2745.     tst.l    d0
  2746.     beq.b    .notp96
  2747.     move.l    _DosBase,a6
  2748.     lea    (.pic962,pc),a0
  2749.     move.l    a0,d1
  2750.     moveq    #ACCESS_READ,d2
  2751.     call    Lock
  2752.     move.l    d0,d1
  2753.     beq.b    .notp96
  2754.     call    UnLock
  2755.  
  2756.     lea    (.picasso96api,pc),a1
  2757.     moveq    #0,d0
  2758.     call    OpenLibrary
  2759.     tst.l    d0
  2760.     beq.b    .notp96
  2761.     move.l    d0,a1
  2762.     call    CloseLibrary
  2763.  
  2764.     moveq    #4,d7
  2765.     bra    .exit
  2766. .notp96
  2767.     lea    (.cybergfx,pc),a1
  2768.     lea    (LibList,a6),a0
  2769.     call    FindName
  2770. ;    moveq    #0,d0
  2771. ;    call    OpenLibrary
  2772.     tst.l    d0
  2773.     beq.b    .notgg
  2774. ;    move.l    d0,a1
  2775. ;    call    CloseLibrary
  2776.     move.l    _ThisTask,a3
  2777.     lea    (pr_WindowPtr,a3),a3
  2778.     move.l    (a3),d3
  2779.     moveq    #-1,d0
  2780.     move.l    d0,(a3)
  2781.     move.l    _DosBase,a6
  2782.     lea    (.cybergfx3,pc),a0
  2783.     move.l    a0,d1
  2784.     moveq    #ACCESS_READ,d2
  2785.     call    Lock
  2786.     move.l    d0,d1
  2787.     bne.b    .isgg
  2788.     lea    (.cybergfx2,pc),a0
  2789.     move.l    a0,d1
  2790.     call    Lock
  2791.     move.l    d0,d1
  2792.     beq.b    .notgg2
  2793. .isgg    call    UnLock
  2794.     move.l    d3,(a3)
  2795.     moveq    #3,d7
  2796.     bra.b    .exit
  2797. .notgg2    move.l    d3,(a3)
  2798. .notgg
  2799.     move.l    (ExecBase00,pc),a6
  2800.  
  2801.     lea    (.retina,pc),a1
  2802.     lea    (LibList,a6),a0
  2803.     call    FindName
  2804.     tst.l    d0
  2805.     beq.b    .not_retina
  2806.     moveq    #7,d7
  2807.     move.l    #$4754<<16+6,d0        Try to find Retina Z2
  2808.     bsr    FindConfigDev
  2809.     bne.b    .exit
  2810.     move.l    #$4754<<16+16,d0    Try to find Retina Z3
  2811.     bsr    FindConfigDev
  2812.     bne.b    .exit
  2813. .not_retina
  2814.     lea    (.egs,pc),a1
  2815.     moveq    #6,d7
  2816.     bsr.b    .test
  2817.     lea    (.graffiti,pc),a1
  2818.     moveq    #8,d7
  2819.     bsr.b    .test
  2820.     lea    (.tiga,pc),a1
  2821.     moveq    #9,d7
  2822.     bsr.b    .test
  2823.     lea    (.probench,pc),a1
  2824.     moveq    #5,d7
  2825.     bsr.b    .test
  2826.  
  2827.     moveq    #0,d7
  2828. .exit    tst.l    d7
  2829.     beq.b    .none
  2830.     move.l    d7,(sp)
  2831. .none    movem.l    (sp)+,d0-a6
  2832.     rts
  2833.  
  2834. .test
  2835. ;    moveq    #0,d0
  2836. ;    call    OpenLibrary
  2837.     lea    (LibList,a6),a0
  2838.     call    FindName
  2839.     tst.l    d0
  2840.     beq.b    .texit
  2841. ;    move.l    d0,a1
  2842. ;    call    CloseLibrary
  2843.     move.l    #.exit,(sp)
  2844. .texit    rts
  2845.  
  2846. .picassortg    dc.b    'rtg.library',0
  2847. .pic962    dc.b    'DEVS:Picasso96Settings',0
  2848. .picasso96api    dc.b    'Picasso96API.library',0
  2849. .cybergfx    dc.b    'cybergraphics.library',0
  2850. .cybergfx2    dc.b    'ENVARC:CyberGraphics',0
  2851. .cybergfx3    dc.b    'ENVARC:CyberGraphX',0
  2852. .egs    dc.b    'egs.library',0
  2853. .retina    dc.b    'retina.library',0
  2854. .graffiti    dc.b    'graffiti.library',0
  2855. .tiga    dc.b    'gfx.library',0
  2856. .probench    dc.b    'hrgblitter.library',0
  2857.     CNOP    0,4
  2858.  
  2859.  
  2860. ; OUT: D0.l=size of virtual memory in KB
  2861. GetVirtMem    movem.l    d1/a0-a1/a6,-(sp)
  2862.     move.l    (ExecBase00,pc),a6
  2863.     lea    (.vmemname,pc),a1
  2864.     moveq    #1,d0
  2865.     call    OpenLibrary
  2866.     tst.l    d0
  2867.     beq.b    .novmem
  2868.     move.l    d0,a6
  2869.     moveq    #1,d0            VMEMF_VIRTUAL
  2870.     move.l    #MEMF_TOTAL,d1
  2871.     jsr    (-$2A,a6)        VMAvailMem
  2872.     move.l    d0,-(sp)
  2873.     move.l    a6,a1
  2874.     move.l    (ExecBase00,pc),a6
  2875.     call    CloseLibrary
  2876.     move.l    (sp)+,d0
  2877. .novmem    movem.l    (sp)+,d1/a0-a1/a6
  2878.     beq.b    .getit
  2879.     movem.l    d1-d2,-(sp)
  2880.     move.l    d0,d1
  2881.     swap    d1
  2882.     and.l    #$0FFFF,d1
  2883.     divu.w    #1024,d1
  2884.     swap    d1
  2885.     clr.w    d1
  2886.     move.l    d1,d2
  2887.     lsl.l    #8,d2
  2888.     lsl.l    #2,d2
  2889.     sub.l    d2,d0
  2890.     divu.w    #1024,d0
  2891.     and.l    #$0FFFF,d0
  2892.     add.l    d1,d0
  2893.     movem.l    (sp)+,d1-d2
  2894.     rts
  2895.  
  2896. .getit    move.l    #(MEMF_PUBLIC!MEMF_CHIP!MEMF_LOCAL!MEMF_24BITDMA!MEMF_KICK)<<16+(MEMF_ANY),d0
  2897.     bra.b    GetMem
  2898.  
  2899. .vmemname    dc.b    'vmem.library',0
  2900.     CNOP    0,4
  2901.  
  2902. ; OUT: D0.l=size of fast memory in KB
  2903. GetFastMem    move.l    #(MEMF_PUBLIC!MEMF_CHIP!MEMF_FAST)<<16+(MEMF_PUBLIC!MEMF_FAST),d0
  2904.     bra.b    GetMem
  2905.  
  2906. ; OUT: D0.l=size of chip memory in KB
  2907. GetChipMem    move.l    #(MEMF_PUBLIC!MEMF_CHIP!MEMF_FAST)<<16+(MEMF_PUBLIC!MEMF_CHIP),d0
  2908. ;    bra.b    GetMem
  2909.  
  2910. ;  IN: d0=mask, d1=req
  2911. ; OUT: D0.l=total size of memory with matching 'req' after masking req with 'mask'
  2912. GetMem    movem.l    d1-d3/a0/a6,-(sp)
  2913.     move.w    d0,d3
  2914.     swap    d0
  2915.     move.w    d0,d2
  2916.     and.w    d2,d3
  2917.     move.l    (ExecBase00,pc),a6
  2918.     call    Forbid
  2919.  
  2920.     move.l    (MemList,a6),a0
  2921.     moveq    #0,d0
  2922. .loop    move.l    (a0),d1
  2923.     beq.b    .done
  2924.     move.w    (MH_ATTRIBUTES,a0),d1
  2925.     and.w    d2,d1
  2926.     cmp.w    d3,d1
  2927.     bne.b    .nomatch
  2928.     move.l    (MH_UPPER,a0),d1
  2929.     sub.l    (MH_LOWER,a0),d1
  2930.     subq.l    #1,d1
  2931.     lsr.l    #8,d1
  2932.     lsr.l    #6,d1
  2933.     addq.l    #1,d1
  2934.     lsl.l    #4,d1
  2935.     add.l    d1,d0
  2936. .nomatch    move.l    (a0),a0
  2937.     bra.b    .loop
  2938. .done
  2939.     call    Permit
  2940.     movem.l    (sp)+,d1-d3/a0/a6
  2941.     rts
  2942.  
  2943.  
  2944. ; OUT: D0=version<<16+revision, or null if wblib
  2945. GetWBVersion    movem.l    d1-a6,-(sp)
  2946.     moveq    #0,d7
  2947.     move.l    (ExecBase00,pc),a6
  2948.     lea    (.versionname,pc),a1
  2949.     moveq    #0,d0
  2950.     call    OpenLibrary
  2951.     tst.l    d0
  2952.     beq.b    .exit
  2953.     move.l    d0,a1
  2954.     move.l    (LIB_VERSION,a1),d7
  2955.     call    CloseLibrary
  2956. .exit    move.l    d7,d0
  2957.     movem.l    (sp)+,d1-a6
  2958.     rts
  2959. .versionname    dc.b    'version.library',0
  2960.     CNOP    0,4
  2961.  
  2962.  
  2963.     STRUCTURE prvSetPatchSemaphore,0
  2964.     STRUCT    prvsps_Sem,SS_SIZE
  2965.     STRUCT    prvsps_Private,MLH_SIZE
  2966.     UWORD    prvsps_Version
  2967.     UWORD    prvsps_Revision
  2968.     ; Don't touch
  2969. GetSetPatchVersion
  2970.     movem.l    d1-a6,-(sp)
  2971.     moveq    #0,d7
  2972.     move.l    (ExecBase00,pc),a6
  2973.     cmp.w    #36,(LIB_VERSION,a6)
  2974.     blo.b    .exit
  2975.     lea    (.semaname,pc),a1
  2976.     call    Forbid
  2977.     call    FindSemaphore
  2978.     call    Permit
  2979.     tst.l    d0
  2980.     beq.b    .exit
  2981.     move.l    d0,a0
  2982.     move.l    (prvsps_Version,a0),d7
  2983. .exit    move.l    d7,d0
  2984.     movem.l    (sp)+,d1-a6
  2985.     rts
  2986. .semaname    dc.b    '« SetPatch »',0
  2987.     CNOP    0,4
  2988.  
  2989. ; OUT: D0=version<<16+revision
  2990. ;      d1=chksum
  2991. GetCRomVer    movem.l    d2-d3/a0-a1/a6,-(sp)
  2992.     move.l    (ExecBase00,pc),a6
  2993.  
  2994.     move.l    (LIB_IDSTRING,a6),d0
  2995.     and.w    #~3,d0
  2996.     move.l    d0,a0
  2997.     move.l    #$11104EF9,d0
  2998.     move.l    #$FFF8FFFF,d1
  2999.     moveq    #-1,d3
  3000.  
  3001.     move.l    a0,a1
  3002. .find    move.l    -(a0),d2
  3003.     and.l    d1,d2
  3004.     cmp.l    d2,d0
  3005.     dbeq    d3,.find
  3006.     addq.w    #1,d3
  3007.     bne.b    .addrok
  3008.     move.l    a1,d0
  3009.     clr.w    d0               Commodore does it this way...
  3010.     move.l    d0,a0
  3011. .addrok
  3012. ;;    lea    ($1000).w,a1
  3013. ;;    move.l    (a1),(a1)        <- Fake access (NOT enforcer hit, though)
  3014.     move.l    (12,a0),d3
  3015.  
  3016.     move.l    #256*1024,d0
  3017.     cmp.w    #$1111,(a0)
  3018.     beq.b    .rom256k
  3019.     add.l    d0,d0
  3020. .rom256k    jsr    ROMReSum
  3021.     move.l    d0,d1
  3022.  
  3023.     move.l    d3,d0
  3024.     movem.l    (sp)+,d2-d3/a0-a1/a6
  3025.     rts
  3026.  
  3027.  
  3028. ;  IN: D0.w=attnflags
  3029. ; OUT: D0=version<<16+revision, zero if no "real" KS rom available
  3030. ;      d1=chksum, zero if no "real" KS rom available
  3031. GetChipRomVer    movem.l    d2-d7/a0-a6,-(sp)
  3032.     move.l    (ExecBase00,pc),a6
  3033.  
  3034.     jsr    getromver_novmem
  3035.  
  3036.     move.l    d6,d1
  3037.     move.l    d7,d0
  3038.     movem.l    (sp)+,d2-d7/a0-a6
  3039.     rts
  3040.  
  3041.  
  3042. ; OUT: D0=chipid, -1=unknown
  3043. GetAnimChip    movem.l    d1-d7/a0-a6,-(sp)
  3044.     moveq    #-1,d7
  3045.     tst.l    NoHW
  3046.     bne.b    .xit
  3047.  
  3048.     moveq    #1,d7
  3049.     move.w    $DFF004,d0
  3050.     and.w    #$7F00,d0
  3051.     lsr.w    #8,d0
  3052.     bclr    #4,d0
  3053.     beq.b    .skip
  3054.     moveq    #0,d7
  3055. .skip
  3056.     cmp.b    #$20,d0
  3057.     beq.b    .sa4
  3058.     cmp.b    #$21,d0
  3059.     beq.b    .sa6
  3060.     cmp.b    #$22,d0
  3061.     beq.b    .sa8
  3062.     cmp.b    #$23,d0
  3063.     beq.b    .saA
  3064.  
  3065.     tst.b    d0
  3066.     bne.b    .unknown
  3067.     bsr.b    .subr
  3068.     bra.b    .xit
  3069.  
  3070. .saA    addq.b    #2,d7
  3071. .sa8    addq.b    #2,d7
  3072. .sa6    addq.b    #2,d7
  3073. .sa4    addq.b    #4,d7
  3074.  
  3075. .xit    move.l    d7,d0
  3076.     movem.l    (sp)+,d1-d7/a0-a6
  3077.     rts
  3078.  
  3079. .unknown    moveq    #-1,d7
  3080.     bra.b    .xit
  3081.  
  3082. .subr    move.l    (ExecBase00,pc),a6    Test for 8361/8367 Agnus:
  3083.     call    Disable
  3084.     moveq    #32-1,d6        Multicheck: 32 times
  3085.     move.l    _GfxBase,a6
  3086.     lea    $DFF000,a5        Loads of preloads:
  3087.     lea    (bltsize,a5),a4
  3088.     lea    (dmaconr,a5),a3
  3089.     moveq    #$41,d4            Shortest possible blit
  3090.     call    OwnBlitter
  3091.     move.w    (a3),d5            Save dmacon
  3092.     move.w    #DMAF_BLITHOG,(dmacon,a5) <- No nasty blitter, please!
  3093. .blitloop    call    WaitBlit        Do it right, but only here! :-O
  3094.     move.w    #$0E00,(bltcon0,a5)    Dummy blit, no dest
  3095.     bra.b    .blitcnop
  3096.     CNOP    0,4            Align to longword
  3097. .blitcnop    move.w    d4,(a4)            / Fetched in   \
  3098.     move.w    (a3),d0            \ one longword /
  3099.     btst    #DMAB_BLTDONE,d0    <- _Very_ old agnus
  3100.     beq.b    .old_agnus           get this wrong!!!
  3101.     dbf    d6,.blitloop
  3102.     addq.b    #2,d7
  3103. .old_agnus    or.w    #$8000,d5        Restore dmacon
  3104.     move.w    d5,(dmacon,a5)
  3105.     call    WaitBlit        Wait blit to finish, if any
  3106.     call    DisownBlitter
  3107.     move.l    (ExecBase00,pc),a6
  3108.     call    Enable
  3109.     rts
  3110.  
  3111.  
  3112. ;  \/  Now this should work with OCS *much* better!?  \/
  3113.  
  3114. ; OUT: D0=chipid, 0=OCS denise, 1=ECS denise, 2=AGA Lisa, 3=AAA Lisa, 4=Unknown
  3115. ;      d1.w=revision number, or -1 if OCS
  3116. GetGfxChip    movem.l    d2-d3/d7/a0/a5/a6,-(sp)
  3117.     moveq    #-1,d1
  3118.     moveq    #4,d0
  3119.     tst.l    NoHW
  3120.     bne.b    .exit
  3121.     lea    $DFF000,a5
  3122.     move.l    (ExecBase00,pc),a6
  3123.     call    Disable
  3124.     moveq    #0,d7
  3125.     lea    ($7C,a5),a0        Preload denise/lisa ID hw addr
  3126.     move.w    #$FF,d3            Preload 'and' value
  3127.  
  3128.     moveq    #1-1,d0            !! These two just disable the
  3129.     bsr    HWWait            !! annoying flick effect...
  3130.     move.w    (dmaconr,a5),d1        Save old dmacon
  3131.     or.w    #DMAF_SETCLR,d1
  3132.     move.w    #$3FF,(dmacon,a5)    Disable all dma
  3133.     move.w    (a0),d0            !! OCS denise gives value $FFFF 
  3134.                     ;! when all dma is off (hmm?)
  3135.     move.w    d1,(dmacon,a5)        Enable dma again
  3136.     not.w    d0            !! Well, my old trusty A500 does!!
  3137.     beq.b    .OCS            !! (CAN'T BE SURE ABOUT THIS)
  3138.  
  3139.     move.w    (a0),d0             Get ID
  3140.     and.w    d3,d0
  3141.     moveq    #128-1,d2        Check 128 times (try to notice old denise random)
  3142. .loop    move.w    (a0),d1            Get ID again
  3143.     and.w    d3,d1
  3144.     cmp.b    d0,d1            Same value?
  3145.     bne.b    .OCS            Not the same value, then OCS Denise
  3146.     dbf    d2,.loop
  3147.     cmp.b    #$FC,d0
  3148.     beq.b    .ECS
  3149.     or.b    #%11110000,d0        Mask AGA revision
  3150.     cmp.b    #%11111000,d0        Bit 3=AGA
  3151.     beq.b    .AGA
  3152.     cmp.b    #%11110000,d0        Bit 3=0 => AAA
  3153.     beq.b    .AAA
  3154.     addq.l    #1,d7            4 is Unknown
  3155. .AAA    addq.l    #1,d7            3 is AAA
  3156. .AGA    addq.l    #1,d7            2 is AGA
  3157. .ECS    addq.l    #1,d7            1 is ECS
  3158. .OCS    move.l    d7,d0            0 is OCS
  3159.  
  3160.     call    Enable
  3161.  
  3162.     tst.b    d0
  3163.     beq.b    .skip_OCS
  3164.     and.w    #%11110000,d1
  3165.     lsr.b    #4,d1
  3166.     neg.b    d1
  3167.     add.b    #$F,d1
  3168.  
  3169. .exit    movem.l    (sp)+,d2-d3/d7/a0/a5/a6
  3170.     rts
  3171.  
  3172. .skip_OCS    moveq    #-1,d1
  3173.     bra.b    .exit
  3174.  
  3175.  
  3176. ;  IN: A0=FmtString, A1=Array, a2=Buffer
  3177. ; OUT: Formatted text
  3178. Sprintf    movem.l    a0-a3/a6/d0-d1,-(sp)
  3179.     move.l    a2,a3
  3180.     lea    (.putchar,pc),a2
  3181.     move.l    (ExecBase00,pc),a6
  3182.     call    RawDoFmt
  3183.     movem.l    (sp)+,a0-a3/a6/d0-d1
  3184.     rts
  3185. .putchar    move.b    d0,(a3)+
  3186.     rts
  3187.  
  3188.  
  3189. ;  IN: A0=FmtString, A1=Array (may be 0)
  3190. ; OUT: Printed text
  3191. Printf    movem.l    a0-a3/a6/d0-d3,-(sp)
  3192.     lea    pf_Data,a3
  3193.     move.l    a5,(a3)+
  3194.     clr.l    (a3)+
  3195.     lea    (.newchar,pc),a2
  3196.     move.l    (ExecBase00,pc),a6
  3197.     call    RawDoFmt
  3198.     move.l    a5,a6
  3199.     move.l    OutputFH,d1
  3200.     move.l    a3,d2
  3201.     move.l    (-4,a3),d3
  3202.     call    Write
  3203.     movem.l    (sp)+,a0-a3/a6/d0-d3
  3204.     rts
  3205. .newchar    movem.l    d0-d3/a0-a1/a3/a6,-(sp)
  3206.     move.l    a3,d2                for Write()
  3207.     move.l    -(a3),d1
  3208.     move.b    d0,4(a3,d1.l)
  3209.     addq.b    #1,d1
  3210.     move.l    d1,(a3)
  3211.     bne.b    .dont_print
  3212.     move.l    -(a3),a6
  3213.     move.l    OutputFH,d1
  3214.     moveq    #64,d3
  3215.     lsl.w    #2,d3
  3216.     call    Write
  3217. .dont_print    movem.l    (sp)+,d0-d3/a0-a1/a3/a6
  3218.     rts
  3219.  
  3220.  
  3221. ; a0=timer routine (should be in chipmem)
  3222. ; OUT: D0.l=compare time
  3223. DoTimer    movem.l    d1-a6,-(sp)
  3224.     move.l    a0,a5
  3225.     lea    $DFF000,a4
  3226.     move.l    (ExecBase00,pc),a6
  3227.  
  3228.     move.l    _ThisTask,a1
  3229.     moveq    #127,d0
  3230.     call    SetTaskPri
  3231.     move.l    d0,-(sp)
  3232.  
  3233.     cmp.w    #4,BandWidth
  3234.     beq.b    .is_aga4x
  3235.     move.l    a6,-(sp)
  3236.     move.l    _GfxBase,a6
  3237.     move.l    (gb_ActiView,a6),d6    save view
  3238.     sub.l    a1,a1
  3239.     call    LoadView
  3240.     moveq    #3-1,d0
  3241.     bsr    HWWait
  3242.     move.l    (sp)+,a6
  3243. .is_aga4x
  3244.     move.l    a6,-(sp)
  3245.     move.l    _GfxBase,a6
  3246.     call    WaitBlit        Wait possible blit to finish.
  3247.     move.l    (sp)+,a6
  3248.  
  3249.     jsr    ChipTiming2
  3250.     move.l    d0,d7
  3251.  
  3252.     cmp.w    #4,BandWidth        Restore view, if needed
  3253.     beq.b    .is_aga4x2
  3254.     move.l    a6,-(sp)
  3255.     move.l    _GfxBase,a6
  3256.     move.l    d6,a1
  3257.     call    LoadView
  3258.     moveq    #3-1,d0
  3259.     bsr    HWWait
  3260. ;;    move.l    (gb_copinit,a6),(cop1lc,a4)    Kick copper into life
  3261.     move.l    (sp)+,a6
  3262. .is_aga4x2
  3263.     move.l    _ThisTask,a1
  3264.     move.l    (sp)+,d0
  3265.     call    SetTaskPri
  3266.  
  3267.     move.l    d7,d0
  3268.     movem.l    (sp)+,d1-a6
  3269.     rts
  3270.  
  3271.  
  3272.  
  3273. HWWait    movem.l    d0-d2/a0,-(sp)
  3274.     tst.l    NoHW
  3275.     bne.b    .nohw
  3276.     lea    $DFF006,a0
  3277.     moveq    #-1,d2
  3278. .wait1    move.b    (a0),d1
  3279.     cmp.b    d2,d1
  3280.     bne.b    .wait1
  3281. .wait2    move.b    (a0),d1
  3282.     cmp.b    d2,d1
  3283.     beq.b    .wait2
  3284.     dbf    d0,.wait1
  3285. .exit    movem.l    (sp)+,d0-d2/a0
  3286.     rts
  3287.  
  3288. .nohw    addq.l    #1,d0
  3289.     bsr    WaitBlanks        Will break Forbid() or Disable()
  3290.     bra.b    .exit
  3291.  
  3292.  
  3293. ; OUT: d0=iCRBit (now result is LONG negative if failed to get cia)
  3294. InitTimer    movem.l    d1/d7/a0-a1/a5-a6,-(sp)
  3295.     move.l    (ExecBase00,pc),a6
  3296.     moveq    #-1,d7            for .noresource
  3297.     lea    (_CiabName,pc),a1
  3298.     call    OpenResource
  3299.     move.l    d0,CiabResource
  3300.     beq.b    .noresource
  3301.     move.l    d0,a5
  3302.  
  3303.     moveq    #IS_SIZE,d0
  3304.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1    No virtmem please!
  3305.     call    AllocMem
  3306.     move.l    d0,_CiaInterrupt
  3307.     beq.b    .nomem
  3308.  
  3309.     move.l    d0,a1
  3310.     addq.l    #LN_TYPE,a1
  3311.     move.w    #NT_INTERRUPT<<8+127,(a1)+
  3312.     lea    (CiaIntName,pc),a0
  3313.     move.l    a0,(a1)+
  3314.     lea    CiaIntData,a0
  3315.     move.l    a0,(a1)+
  3316.     lea    CiaIntCode,a0
  3317.     move.l    a0,(a1)+
  3318.  
  3319.     moveq    #1,d7
  3320. .allocloop    move.l    d7,d0
  3321.      move.l    _CiaInterrupt,a1
  3322.     exg    a5,a6
  3323.     call    AddICRVector
  3324.     exg    a5,a6
  3325.     tst.l    d0
  3326.     beq.b    .ciaok
  3327.     dbf    d7,.allocloop
  3328. .ciaok
  3329.     tst.w    d7
  3330.     bpl.b    .gottimer
  3331.     move.l    _CiaInterrupt,a1
  3332.     clr.l    _CiaInterrupt
  3333.     moveq    #IS_SIZE,d0
  3334.     call    FreeMem
  3335. .gottimer
  3336. .nomem
  3337. .noresource    move.w    d7,d0
  3338.     ext.l    d0
  3339.     movem.l    (sp)+,d1/d7/a0-a1/a5-a6
  3340.     rts
  3341.  
  3342. ;  IN: d0=iCRBit
  3343. RemTimer    movem.l    d0-d1/a0-a1/a6,-(sp)
  3344.     tst.l    d0
  3345.     bmi.b    .exit
  3346.     move.l    CiabResource,d1
  3347.     beq.b    .xit
  3348.     move.l    d1,a6
  3349.     move.l    _CiaInterrupt,a1
  3350.     call    RemICRVector
  3351.     move.l    (ExecBase00,pc),a6
  3352.     move.l    _CiaInterrupt,a1
  3353.     clr.l    _CiaInterrupt
  3354.     moveq    #IS_SIZE,d0
  3355.     call    FreeMem    
  3356. .exit    clr.l    CiabResource
  3357. .xit    movem.l    (sp)+,d0-d1/a0-a1/a6
  3358.     rts
  3359.  
  3360. EvaluateFormulas
  3361. ;    move.l    #MC68060,CPUID        debug
  3362. ;    clr.l    CardSlotID
  3363. ;    st    A4000ID
  3364.  
  3365.     movem.l    d1-d7/a0-a6,-(sp)
  3366.     move.l    sp,EvalSpSave
  3367.     moveq.l    #0,d6            param array
  3368.     lea    (Formulas,pc),a1
  3369. .get_next    move.l    (a1)+,a0
  3370. ;    beq.b    _eval_error        <- n_e_v_e_r happens!!
  3371. ;    move.l    d0,a0
  3372.     move.l    a1,-(sp)
  3373.     bsr.b    _EvaluateFormula
  3374.     move.l    (sp)+,a1
  3375.     tst.l    d0
  3376.     beq.b    .get_next
  3377.     move.l    (a0),d0
  3378.     cmp.l    #32,d0
  3379.     bhs.b    _eval_exit
  3380.     bset    d0,d6
  3381.     bra.b    .get_next
  3382. _eval_exit
  3383. _eval_error
  3384. ;;    move.l    d6,WAIndex        db
  3385.     move.l    EvalSpSave,sp
  3386. ;    tst.l    d0            disabled - zero not possible!
  3387. ;    bne.b    .ok
  3388. ;    lea    (sNullStr,pc),a0
  3389. ;    move.l    a0,d0
  3390. ;.ok
  3391.     movem.l    (sp)+,d1-d7/a0-a6
  3392.     rts
  3393. _eval_error2    lea    (sEvalErr,pc),a0
  3394.     move.l    a0,d0
  3395.     bra.b    _eval_error
  3396.  
  3397. ; A1=parameter array
  3398. _EvaluateFormula2
  3399.     move.l    a0,-(sp)
  3400.     move.l    a1,a0
  3401.     bsr.b    _EvaluateFormula
  3402.     move.l    (sp)+,a0
  3403.     rts
  3404.  
  3405. ; A0=parameter array
  3406. _EvaluateFormula
  3407.     moveq    #0,d0            orig result=0
  3408.     moveq    #0,d4            op-mode (AND)
  3409.     moveq    #0,d7            skipmode=OFF
  3410. .get_next_com    move.l    (a0)+,d1
  3411.     lea    (OperatorTable-8,pc),a1
  3412. .get_next_op    addq.l    #8,a1
  3413.     move.l    (a1)+,d2
  3414.     beq.b    _eval_error2
  3415.     cmp.l    d1,d2
  3416.     bne.b    .get_next_op
  3417.     move.l    (4,a1),a2
  3418.     movem.l    (a0),d1-d3
  3419.     add.l    (a1),a0
  3420.     cmpa.w    #0,a2
  3421.     beq.b    .evaluated
  3422.     tst.b    d7            handle skip-mode
  3423.     bne.b    .get_next_com        << fixed!
  3424.     tst.l    (a1)            handle first parameter
  3425.     beq.b    .not_addr_arg
  3426.     move.l    d1,a1
  3427.     cmp.l    #_EvaluateFormula2,a2    special handle for jump command
  3428.     beq.b    .not_addr_arg    
  3429.     cmpa.w    #32,a1
  3430.     bhs.b    .std_addr_arg
  3431.     btst    d1,d6            test entry in param array
  3432.     sne    d1
  3433.     ext.w    d1
  3434.     ext.l    d1            d1.l=0/-1
  3435.     bra.b    .not_addr_arg
  3436. .std_addr_arg    move.l    (a1),d1
  3437. .not_addr_arg    moveq    #0,d0
  3438.     movem.l    d4-d7/a1-a6,-(sp)
  3439.     jsr    (a2)
  3440.     movem.l    (sp)+,d4-d7/a1-a6
  3441.     tst.l    d0
  3442.     beq.b    .d0zero
  3443.     moveq    #-1,d0            ensure d0=-1 on true-condition    
  3444. .d0zero    cmp.b    d4,d0
  3445.     bne.b    .no_cond_satisfied
  3446.     moveq    #-1,d7
  3447. .no_cond_satisfied
  3448.     bra    .get_next_com
  3449. .evaluated    rts
  3450.  
  3451. _EqualTo0    tst.l    d1
  3452.     seq    d0
  3453.     rts
  3454.  
  3455. _NotEqualTo0    tst.l    d1
  3456.     sne    d0
  3457.     rts
  3458.  
  3459. _Equal    cmp.l    d1,d2
  3460.     seq    d0
  3461.     rts
  3462.  
  3463. _InsideBorders    cmp.l    d2,d1
  3464.     blt.b    .no_inside
  3465.     cmp.l    d3,d1
  3466.     sle    d0
  3467. .no_inside    rts
  3468.  
  3469. _OutsideBorders    cmp.l    d2,d1
  3470.     blt.b    .is_outside
  3471.     cmp.l    d3,d1
  3472.     sle    d0
  3473. .is_outside    not.b    d0
  3474.     rts
  3475.  
  3476. _NotEqual    cmp.l    d1,d2
  3477.     sne    d0
  3478.     rts
  3479.  
  3480. _SetAndMode    moveq    #0,d4            AND-mode
  3481.     moveq    #-1,d0            result
  3482.     rts
  3483.  
  3484. _SetOrMode    moveq    #-1,d4            OR-mode
  3485.     moveq    #0,d0            result
  3486.     rts
  3487.  
  3488. OperatorTable    dc.l    '&',0,_SetAndMode
  3489.     dc.l    '!',0,_SetOrMode
  3490.     dc.l    '(',0,_EvaluateFormula
  3491.     dc.l    '->',4,_EvaluateFormula2
  3492.     dc.l    '=0',4,_EqualTo0
  3493.     dc.l    '<>0',4,_NotEqualTo0
  3494.     dc.l    '=',8,_Equal
  3495.     dc.l    '<>',8,_NotEqual
  3496.     dc.l    '<x<',12,_InsideBorders        the edges are included
  3497.     dc.l    'out',12,_OutsideBorders    the edges aren't included
  3498.     dc.l    ')',0,0
  3499.     dc.l    '|',0,0
  3500.     dc.l    0
  3501.  
  3502. _bitn    SET    0
  3503. BIT    MACRO
  3504. \1    EQU    _bitn
  3505. _bitn    SET    _bitn+1
  3506.     ENDM
  3507.  
  3508. ; Define toggle-array bits
  3509.     BIT    _ISAGA
  3510.  
  3511. Formulas    dc.l    calculateAGA
  3512.  
  3513.     dc.l    calculateDraCo
  3514.     dc.l    calculateCD32
  3515.     dc.l    calculateCDTV
  3516.     dc.l    calculateA1400
  3517.     dc.l    calculateA1200
  3518. ;X    dc.l    calculateWalker
  3519.     dc.l    calculateA4000T
  3520.     dc.l    calculateA4000
  3521.     dc.l    calculateA600
  3522.     dc.l    calculateA1000
  3523.     dc.l    calculateA3000
  3524.     dc.l    calculateA30UX
  3525.     dc.l    calculateA3000T
  3526.     dc.l    calculate2500
  3527.     dc.l    calculate500o
  3528.     dc.l    calculateA500e
  3529.     dc.l    calculateA2000e
  3530.     dc.l    calculateA500pe
  3531.     dc.l    calculateA2000pe
  3532.     dc.l    calculateA500p
  3533.     dc.l    calculateA2000p
  3534.     dc.l    calculateA500
  3535.     dc.l    calculateA2000
  3536.     dc.l    calculateAAA
  3537.  
  3538. ;    dc.l    calculateA1200        debug move! (ought to be before Walker)
  3539.  
  3540.     dc.l    calc_default        <- ALWAYS exits
  3541. ;    dc.l    0            <- Not needed!!
  3542.  
  3543. calculateAGA    dc.l    '&','=',GfxChipID,2,'<x<',AnimChipID,8,$B,'|',_ISAGA
  3544. calculateDraCo    dc.l    '&','<>0',DraCoID,'|',sDraCo
  3545. calculateCD32    dc.l    '&','<>0',C2PID,'<>0',_ISAGA,'<>0',CD32NVRAMID
  3546.     dc.l    '<x<',RomVer,40<<16,INFINITE,'<x<',CPUID,MIN020,MAXCPU,'|',sCD32
  3547. calculateCDTV    dc.l    '&','<x<',ChipMem,1024,2048,'<>0',CDTVID,'<x<',CPUID,0,MAX040,'|',sCDTV
  3548. calculateA1400    dc.l    '&','<x<',CPUID,MIN020,MAX020,'<x<',_100kHz,240,260,'=',ChipMem,2048
  3549.     dc.l    '<>0',_ISAGA,'<>0',CardSlotID
  3550.     dc.l    '<x<',RomVer,39<<16,INFINITE,'|',sAmiga1400
  3551. calculateA1200    dc.l    '&','<>0',_ISAGA,'<>0',CardSlotID,'<x<',CPUID,MIN020,MAXCPU
  3552.     dc.l    '<x<',RomVer,30<<16,INFINITE,'<x<',ChipMem,1024,2048,'|',sAmiga1200
  3553. ;??                 ^^
  3554. ;XcalculateWalker    dc.l    '&','<>0',_ISAGA,'<x<',RomVer,41<<16,INFINITE,'=0',CardSlotID
  3555. ;??                          ^^
  3556. ;X    dc.l    '=',CPUID,MC68EC030,'=',_100kHz,400,'<x<',ChipMem,1024,2048,'|',sWalker
  3557. calculateA4000T    dc.l    '&','<>0',_ISAGA,'<x<',RomVer,40<<16,INFINITE,'=0',CardSlotID
  3558. ;??                          ^^
  3559.     dc.l    '<x<',CPUID,MAX040,MAXCPU,'=',ChipMem,2048,'<>0',A4000TID,'|',sAmiga4000T
  3560. calculateA4000    dc.l    '&','<>0',_ISAGA,'<x<',RomVer,39<<16,INFINITE,'=0',CardSlotID
  3561.     dc.l    '<x<',CPUID,MIN030,MAXCPU,'=',ChipMem,2048,'<>0',A4000ID,'|',sAmiga4000
  3562. calculateA600    dc.l    '&','=',GfxChipID,1,'<x<',AnimChipID,6,7
  3563.     dc.l    '<x<',RomVer,37<<16+175+1,INFINITE,'<x<',ChipMem,1024,2048
  3564.     dc.l    '<>0',CardSlotID,'|',sAmiga600
  3565. calculateA1000    dc.l    '&','=',GfxChipID,0,'<x<',AnimChipID,0,1
  3566.     dc.l    '<x<',RomVer,30<<16,INFINITE,'<x<',ChipMem,256,512,'|',sAmiga1000
  3567. calculateA3000    dc.l    '&','<x<',RomVer,35<<16,INFINITE,'=',GfxChipID,1
  3568.     dc.l    '<x<',AnimChipID,4,7,'<x<',ChipMem,1024,2048
  3569.     dc.l    '<x<',CPUID,MIN030,MAXCPU,'<>0',A3000ID,'|',sAmiga3000
  3570. calculateA30UX    dc.l    '&','<>0',UNIXID,'<x<',RomVer,35<<16,INFINITE,'=',GfxChipID,1
  3571.     dc.l    '<x<',AnimChipID,4,7,'<x<',ChipMem,1024,2048
  3572.     dc.l    '<x<',CPUID,MIN030,MAXCPU,'<>0',A3000ID,'|',sAmiga3000UX
  3573. calculateA3000T    dc.l    '&','<x<',RomVer,35<<16,INFINITE,'=',GfxChipID,1
  3574.     dc.l    '<x<',AnimChipID,4,7,'<x<',ChipMem,1024,2048
  3575.     dc.l    '<x<',CPUID,MIN030,MAXCPU,'<>0',A4000ID,'|',sAmiga3000T
  3576. calculate2500    dc.l    '&','<>0',A2500ID,'<x<',RomVer,33<<16,INFINITE,'=',GfxChipID,0
  3577.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,512,1024,'<x<',CPUID,MIN020,MAX030
  3578.     dc.l    '<x<',_100kHz,240,260,'|',sAmiga2500
  3579. calculate500o    dc.l    '&','<x<',RomVer,33<<16,INFINITE,'=',GfxChipID,0
  3580.     dc.l    '<x<',AnimChipID,2,3,'=',ChipMem,512,'|',sAmiga500old
  3581.  
  3582. calculateA500e    dc.l    '&','<>0',A500EID,'<x<',RomVer,33<<16,INFINITE,'=',GfxChipID,0
  3583.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,512,2048,'<x<',CPUID,0,MAX040
  3584.     dc.l    '|',sAmiga500e
  3585. calculateA2000e    dc.l    '&','<>0',A2000EID,'<x<',RomVer,33<<16,INFINITE,'=',GfxChipID,0
  3586.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,512,1024,'<x<',CPUID,0,MAXCPU
  3587.     dc.l    '|',sAmiga2000e
  3588. calculateA500pe    dc.l    '&','<>0',A500EID,'<x<',RomVer,37<<16,INFINITE,'=',GfxChipID,1
  3589.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,1024,2048,'<x<',CPUID,0,MAX040
  3590.     dc.l    '|',sAmiga500Pluse
  3591. calculateA2000pe
  3592.     dc.l    '&','<>0',A2000EID,'<x<',RomVer,37<<16,INFINITE,'=',GfxChipID,1
  3593.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,1024,2048,'<x<',CPUID,0,MAXCPU
  3594.     dc.l    '|',sAmiga2000Pluse
  3595. calculateA500p    dc.l    '&','=0',A500EID,'<x<',RomVer,37<<16,INFINITE,'=',GfxChipID,1
  3596.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,1024,2048,'<x<',CPUID,0,MAX040
  3597.     dc.l    '|',sAmiga500Plus
  3598. calculateA2000p    dc.l    '&','=0',A2000EID,'<x<',RomVer,37<<16,INFINITE,'=',GfxChipID,1
  3599.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,1024,2048,'<x<',CPUID,0,MAXCPU
  3600.     dc.l    '|',sAmiga2000Plus
  3601. calculateA500    dc.l    '&','=0',A500EID,'<x<',RomVer,33<<16,INFINITE,'=',GfxChipID,0
  3602.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,512,2048,'<x<',CPUID,0,MAX040
  3603.     dc.l    '|',sAmiga500
  3604. calculateA2000    dc.l    '&','=0',A2000EID,'<x<',RomVer,33<<16,INFINITE,'=',GfxChipID,0
  3605.     dc.l    '<x<',AnimChipID,4,5,'<x<',ChipMem,512,1024,'<x<',CPUID,0,MAXCPU
  3606.     dc.l    '|',sAmiga2000
  3607.  
  3608. calculateAAA    dc.l    '=',GfxChipID,3,'|',sAmigaAAA
  3609. calc_default    dc.l    '<>0',calc_default,'|',sDefault
  3610.  
  3611.  
  3612. GfxChipTable
  3613. .s    dc.w    sDenise-.s,sECSDenise-.s,sAGALisa-.s,sAAALisa-.s,sUnknown-.s
  3614.  
  3615.     dc.w    sUnknown-AnimChipTable
  3616. AnimChipTable
  3617. .s    dc.w    sA0-.s,sA1-.s,sA2-.s,sA3-.s,sA4-.s,sA5-.s,sA6-.s,sA7-.s
  3618.     dc.w    sA8-.s,sA9-.s,sAA-.s,sAB-.s
  3619.  
  3620. CPUTable
  3621. .s    dc.w    s68000-.s,s68010-.s,s68EC020-.s,s68020-.s,s68EC030-.s
  3622.     dc.w    s68030-.s,s68EC040-.s,s68LC040-.s,s68040-.s
  3623.     dc.w    s68EC060-.s,s68LC060-.s,s68060-.s
  3624. ;;    dc.w    sMPC603e-.s,sMPC604-.s,sMPC620-.s
  3625.  
  3626. FPUTable
  3627. .s    dc.w    sFna-.s,s68881-.s,s68882-.s,s68040f-.s,s68060f-.s
  3628.  
  3629. MMUTable
  3630. .s    dc.w    s68851-.s,s68030m-.s,s68040m-.s,s68060m-.s
  3631.  
  3632. GfxLibEmulTable
  3633. .s    dc.w    sOCS-.s,sECS-.s,sAGA-.s,sCyberGfxg-.s,sPicasso96g-.s,sProBenchg-.s
  3634.     dc.w    sEGSg-.s,sRetinag-.s,sGraffitig-.s,sTIGAg-.s,sAltaisg-.s
  3635.  
  3636. PowerPCTable
  3637. .s    dc.w    sPPCxx-.s,sPPCxx-.s,sPPCxx-.s
  3638.     dc.w    sPPC603-.s,sPPC604-.s,sPPC602-.s,sPPC603e-.s,sPPC603p-.s
  3639.     dc.w    sPPCxx-.s
  3640.     dc.w    sPPC604e-.s
  3641.  
  3642. PowerPCPLLTable
  3643. .s    dc.w    pllxx-.s,pllxx-.s,pllxx-.s
  3644.     dc.w    pll603-.s,pll604-.s,pll602-.s,pll603e-.s,pll603p-.s
  3645.     dc.w    pllxx-.s
  3646.     dc.w    pll604e-.s
  3647.  
  3648. pllxx
  3649. pll603
  3650. pll604
  3651. pll602
  3652. pll603e
  3653. pll603p
  3654. pll604e
  3655.     dc.w    10    ; 0000
  3656.     dc.w    10    ; 0001
  3657.     dc.w    70    ; 0010
  3658.     dc.w    10    ; 0011 PLL bypass
  3659.     dc.w    20    ; 0100
  3660.     dc.w    65    ; 0101
  3661.     dc.w    25    ; 0110
  3662.     dc.w    45    ; 0111
  3663.     dc.w    30    ; 1000
  3664.     dc.w    55    ; 1001
  3665.     dc.w    40    ; 1010
  3666.     dc.w    50    ; 1011
  3667.     dc.w    15    ; 1100
  3668.     dc.w    60    ; 1101
  3669.     dc.w    35    ; 1110
  3670.     dc.w    10    ; 1111
  3671.  
  3672.  
  3673. DosName    dc.b    'dos.library',0
  3674. ExpName    dc.b    'expansion.library',0
  3675. _GfxName    dc.b    'graphics.library',0
  3676. _CiabName    dc.b    'ciab.resource',0
  3677. CiaIntName    dc.b    'WhichAmiga CIA interrupt',0
  3678. TimerDevName    dc.b    'timer.device',0
  3679. ConsoleName    dc.b    'CON:10/10/620/246/ WhichAmiga  Copyright © 1995-1999 PitPlane Productions',0
  3680. NewConsoleName    dc.b    'CON:10/10/620/246/WhichAmiga  Copyright © 1995-1999 PitPlane Productions/CLOSE/AUTO/WAIT',0
  3681. PressReturn    dc.b    10,$9B,'0 pPress <RETURN> to close window.',$9B,'30;40m',0
  3682. sNoHW    dc.b    'No Amiga custom hardware available',0
  3683. sNotimer    dc.b    'Severe trouble! No free CIA timer available',10
  3684. sMhzxxxErr    dc.b    '%s!',10
  3685.     dc.b    'Unable to calculate %s clock frequency.',10,0
  3686. sCPU    dc.b    'CPU',0
  3687. sFPU    dc.b    'FPU',0
  3688. CursorOn    dc.b    $9B,' p',0
  3689.  
  3690.     dc.b    '$VER:'
  3691. sStart    dc.b    'WhichAmiga 1.3.3 (2.5.99)',10
  3692.     dc.b    $9B,'0 p'
  3693.     dc.b    'Written by Harry "Piru" Sintonen. Copyright © 1995-1999 PitPlane Productions.',10,10
  3694.     dc.b    'Evaluating system...',10,0
  3695.  
  3696. ;;sRaport    dc.b    'Central Processing Unit: %s %d.%d MHz  (%dx %s %dMHz WAIndex: %ld)',10
  3697. sRaport    dc.b    'Central Processing Unit: %s %d.%d MHz%s',10
  3698.     dc.b    '%s'
  3699.     dc.b    '    Floating Point Unit: %s',10
  3700.     dc.b    ' Memory Management Unit: %s %s',10
  3701.     dc.b    '   Custom graphics chip: %s%s',10
  3702.     dc.b    '  Custom animation chip: %s',10
  3703.     dc.b    '   Other custom chip(s): %s',10
  3704.     dc.b    '        Graphics system: %s%s',10
  3705.     dc.b    '%s%s'
  3706.     dc.b    '%s'
  3707.     dc.b    '%s%s'
  3708.     dc.b    '         Hardware Clock: %s',10
  3709.     dc.b    ' Max. Chipmem available: %ld K',10
  3710.     dc.b    ' Max. Fastmem available: %ld K',10
  3711.     dc.b    '%s'
  3712.     dc.b    '       ROM chip version: %d.%d (Kickstart %s)',10
  3713.     dc.b    '%s'
  3714.     dc.b    '      Workbench version: %d.%d (Workbench %s)',10
  3715.     dc.b    '       SetPatch version: %s',10
  3716.     dc.b    '%s'
  3717.     dc.b    10
  3718.     dc.b    ' Your computer %s%s.',10
  3719.     dc.b    0
  3720.  
  3721. sRev    dc.b    ' (rev %d)',0
  3722. sReKickROM    dc.b    '  ReKicked ROM, version: %d.%d (Kickstart %s)',10,0
  3723. sHWC2P    dc.b    '  Chunky-to-planar conv: available',10,0
  3724. sGfxBoards    dc.b    '      Graphics board(s): ',0
  3725. sSndCards    dc.b    '           Soundcard(s): ',0
  3726.  
  3727. ;sFPUFmt    dc.b    '%s %d.%d MHz  (%ld)',0
  3728. sFPUFmt    dc.b    '%s',0
  3729.  
  3730. sVirtMemFmt    dc.b    ' Max. Virtmem available: %ld K',10,0
  3731.  
  3732. sDBWFmt    dc.b    '  display bandwidth: %dx',0
  3733.  
  3734. sPowerUPFmt0    dc.b    '%2ld PowerUP Processor(s):',0
  3735. sPowerUPFmt1    dc.b    ' PPC %s %ld MHz (rev %d.%d), %ld MHz busclock',0
  3736.  
  3737. sProcInfo060Fmt    dc.b    ' (rev %d)',0
  3738.  
  3739. sSetPatchVerFmt    dc.b    '%d.%d',0
  3740.  
  3741. sOCS    dc.b    'Amiga OCS',0
  3742. sECS    dc.b    'Amiga ECS',0
  3743. sAGA    dc.b    'Amiga AGA',0
  3744. sCyberGfxg    dc.b    'CyberGraphX',0
  3745. sPicasso96g    dc.b    'Picasso96',0
  3746. sProBenchg    dc.b    'ProBench',0
  3747. sEGSg    dc.b    'EGS',0
  3748. sRetinag    dc.b    'Retina',0
  3749. sGraffitig    dc.b    'Graffiti',0
  3750. sTIGAg    dc.b    'TIGA',0
  3751. sAltaisg    dc.b    'Altais',0
  3752.  
  3753. sDenise    dc.b    'OCS Denise 8362',0
  3754. sECSDenise    dc.b    'ECS Denise 8373',0
  3755. sAGALisa    dc.b    'AGA Lisa 4203',0
  3756. sAAALisa    dc.b    'AAA Lisa?',0
  3757.  
  3758. sA0    dc.b    'OCS NTSC Agnus 8361',0            10
  3759. sA1    dc.b    'OCS PAL Agnus 8367',0            00
  3760. sA2    dc.b    'OCS NTSC Fat Agnus 8370',0        10
  3761. sA3    dc.b    'OCS PAL Fat Agnus 8371',0        00
  3762. sA4    dc.b    'ECS NTSC Fatter Agnus 8372a, 1MB',0    30
  3763. sA5    dc.b    'ECS PAL Fatter Agnus 8372a, 1MB',0    20
  3764. sA6    dc.b    'ECS NTSC Super Agnus 8372b, 2MB',0    31
  3765. sA7    dc.b    'ECS PAL Super Agnus 8372b, 2MB',0    21
  3766. sA8    dc.b    'AGA NTSC Alice 8374, thru rev 2',0    32
  3767. sA9    dc.b    'AGA PAL Alice 8374, thru rev 2',0    22
  3768. sAA    dc.b    'AGA NTSC Alice 8374, rev 3-4',0    33
  3769. sAB    dc.b    'AGA PAL Alice 8374, rev 3-4',0        23
  3770. sAxx    dc.b    'ECS Super Agnus 8375, 2MB',0        ??
  3771. sUnknown    dc.b    'Unknown',0
  3772.  
  3773. s68000    dc.b    'MC68000',0
  3774. s68010    dc.b    'MC68010',0
  3775. s68EC020    dc.b    'MC68EC020',0
  3776. s68020    dc.b    'MC68020',0
  3777. s68EC030    dc.b    'MC68EC030',0
  3778. s68030    dc.b    'MC68030',0
  3779. s68EC040    dc.b    'MC68EC040',0
  3780. s68LC040    dc.b    'MC68LC040',0
  3781. s68040    dc.b    'MC68040',0
  3782. s68EC060    dc.b    'MC68EC060',0
  3783. s68LC060    dc.b    'MC68LC060',0
  3784. s68060    dc.b    'MC68060',0
  3785. ;;sMPC603e    dc.b    'MPC603e',0
  3786. ;;sMPC604    dc.b    'MPC604',0
  3787. ;;sMPC620    dc.b    'MPC620',0
  3788.  
  3789. s68881    dc.b    'MC68881',0
  3790. s68882    dc.b    'MC68882',0
  3791. s68040f    dc.b    '68040fpu',0
  3792. s68060f    dc.b    '68060fpu',0
  3793.  
  3794. s68851    dc.b    'MC68851',0
  3795. s68030m    dc.b    '68030mmu',0
  3796. s68040m    dc.b    '68040mmu',0
  3797. s68060m    dc.b    '68060mmu',0
  3798.  
  3799. sPaula    dc.b    'Paula 8364 (rev %d)',0
  3800. sRamsey    dc.b    'Ramsey (rev %d)',0
  3801. sGary    dc.b    'Gary (rev %d)',0
  3802. sGayle    dc.b    'Gayle (rev %d)',0
  3803. sAkiko    dc.b    'Akiko C2P',0
  3804. sSuperIO    dc.b    'SuperIO (rev %d)',0
  3805. sBuster    dc.b    'Buster (rev %d)',0
  3806.  
  3807. sRunningStr    dc.b    'running',0
  3808. sNotActiveStr    dc.b    'not active',0
  3809.  
  3810. sPPC603    dc.b    '603',0
  3811. sPPC604    dc.b    '604',0
  3812. sPPC602    dc.b    '602',0
  3813. sPPC603e    dc.b    '603e',0
  3814. sPPC603p    dc.b    '603p',0
  3815. sPPC604e    dc.b    '604e',0
  3816. sPPCxx    dc.b    '???',0
  3817.  
  3818. sFna
  3819. sMMUna
  3820. sNA
  3821. sGfxEmulna    dc.b    'not available',0
  3822. sNullStr    EQU    *-1
  3823. sClockFound    dc.b    'clock found',0
  3824.  
  3825. sEvalErr    dc.b    'ok, but evaluating code didn''t work! ;)',0
  3826.  
  3827. sUAE    dc.b    ', run by UAE Amiga Emulator',0
  3828. sAmiga1000    dc.b    'is an Amiga 1000',0
  3829. sAmiga500old    dc.b    'is an old Amiga 500',0
  3830. sAmiga500    dc.b    'probably is an Amiga 500',0
  3831. sAmiga500e    dc.b    'is an expanded Amiga 500',0
  3832. sAmiga500Plus    dc.b    'probably is an Amiga 500+',0
  3833. sAmiga500Pluse    dc.b    'is an expanded Amiga 500+',0
  3834. sAmiga600    dc.b    'is an Amiga 600',0
  3835. sAmiga1200    dc.b    'is an Amiga 1200',0
  3836. sAmiga1400    dc.b    'is an Amiga 1400',0
  3837. sAmiga2000    dc.b    'probably is an Amiga 2000',0
  3838. sAmiga2000e    dc.b    'is an expanded Amiga 2000',0
  3839. sAmiga2000Plus    dc.b    'probably is an Amiga 2000+',0
  3840. sAmiga2000Pluse    dc.b    'is an expanded Amiga 2000+',0
  3841. sAmiga2500    dc.b    'is an Amiga 2500',0
  3842. sAmiga3000    dc.b    'is an Amiga 3000',0
  3843. sAmiga3000UX    dc.b    'is an Amiga 3000UX',0
  3844. sAmiga3000T    dc.b    'is an Amiga 3000 Tower',0
  3845. sAmiga4000    dc.b    'is an Amiga 4000',0
  3846. sAmiga4000T    dc.b    'probably is an Amiga 4000 Tower',0
  3847. sCD32    dc.b    'is an Amiga CD³²',0
  3848. sCDTV    dc.b    'is an Amiga CDTV',0
  3849. ;XsWalker    dc.b    'is Amiga Techologies'' Walker',0
  3850. sDraCo    dc.b    'is MacroSystems'' DraCo (Amiga-clone)',0
  3851. sAmigaAAA    dc.b    'probably is a new AAA Amiga (portable? PowerAmiga?)',0
  3852. sDefault    dc.b    'is some Amiga or compatible',0
  3853.  
  3854.  
  3855. GFXBRD    MACRO
  3856.     dc.l    (($\1)<<16)!\2,\3
  3857.     ENDM
  3858.  
  3859. ;    $140C    2    'US Interface Ltd. Magic graphics',0
  3860. ;    $140C    130    'US Interface Ltd. Magic graphics (Prototype)',0
  3861.  
  3862.     CNOP    0,4
  3863. GfxBoardTable
  3864.     GFXBRD    07E1,32,sIV24
  3865.     GFXBRD    06E1,32,sIV24
  3866.     GFXBRD    0891,2,sEGS
  3867.     GFXBRD    0838,0,sIF24        NTSC
  3868.     GFXBRD    0838,1,sIF24        PAL
  3869.     GFXBRD    0851,1,sResolver
  3870.     GFXBRD    0851,2,sVivid24
  3871.     GFXBRD    086A,3,sVoyager
  3872.     GFXBRD    086A,2,sBlackbox
  3873.     GFXBRD    086A,1,sHorizon
  3874.     GFXBRD    085E,1,sGDA
  3875.     GFXBRD    0406,0,sA2410
  3876.     GFXBRD    03EC,245,sA2410kronos
  3877.     GFXBRD    0845,2,sVisiona
  3878.     GFXBRD    0845,4,sMerlin
  3879.     GFXBRD    2140,34,sCyberVision
  3880.     GFXBRD    07E1,68,sRembrandt
  3881.     GFXBRD    0872,2,sDomino
  3882.     GFXBRD    0893,5,sPiccolo        (actually Piccolo Memory)
  3883.     GFXBRD    0893,11,sPiccoloSD64
  3884.     GFXBRD    0877,12,sPicassoII
  3885.     GFXBRD    0877,13,sPicassoII
  3886.     GFXBRD    4754,6,sRetinaZ2
  3887.     GFXBRD    4754,16,sRetinaZ3
  3888.     GFXBRD    0861,33,sRainbowIII
  3889.     GFXBRD    0877,24,sPicassoIV
  3890.     GFXBRD    2140,50,sCyberVision3D
  3891.     GFXBRD    2140,67,sCyberVision3D
  3892.     GFXBRD    4754,19,sAltais
  3893.     GFXBRD    041D,20,s1600GX
  3894.  
  3895. ;    GFXBRD    2140,13,sIV24        db
  3896. ;    GFXBRD    2140,13,sEGS
  3897. ;    GFXBRD    2140,13,sResolver    Testing 1.2.3...
  3898. ;    GFXBRD    2140,13,sA2410
  3899.     dc.l    0
  3900.  
  3901. sA2410    dc.b    'Lowell A2410',0
  3902. sA2410kronos    dc.b    'Kronos/C Ltd A2410',0
  3903. sIV24    dc.b    'Impact Vision 24',0
  3904. sEGS    dc.b    'EGS Spectrum',0
  3905. sIF24    dc.b    'FireCracker 24',0
  3906. sResolver    dc.b    'Resolver',0
  3907. sVivid24    dc.b    'Vivid 24',0
  3908. sGDA    dc.b    'GDA-1',0
  3909. sHorizon    dc.b    'Horizon',0
  3910. sBlackbox    dc.b    'Blackbox',0
  3911. sVoyager    dc.b    'Voyager',0
  3912. sVisiona    dc.b    'Visiona',0
  3913. sMerlin    dc.b    'Merlin',0
  3914. sCyberVision    dc.b    'CyberVision 64',0
  3915. sRembrandt    dc.b    'Rembrandt',0
  3916. sDomino    dc.b    'Domino',0
  3917. sPiccolo    dc.b    'Piccolo',0
  3918. sPiccoloSD64    dc.b    'PiccoloSD-64',0
  3919. sPicassoII    dc.b    'Picasso II',0
  3920. sRetinaZ2    dc.b    'Retina Z2',0
  3921. sRetinaZ3    dc.b    'Retina Z3',0
  3922. sRainbowIII    dc.b    'Rainbow III',0
  3923. sAltais    dc.b    'Altais Card',0
  3924. s1600GX    dc.b    '1600-GX',0
  3925. sCyberVision3D    dc.b    'CyberVision 64/3D',0
  3926. sPicassoIV    dc.b    'Picasso IV',0
  3927.     CNOP    0,4
  3928.  
  3929.  
  3930. SNDCRD    MACRO
  3931.     dc.l    (($\1)<<16)!\2,\3
  3932.     ENDM
  3933.  
  3934.     CNOP    0,4
  3935. SndCardTable
  3936.     SNDCRD    0840,191,sWavetools
  3937.     SNDCRD    38A5,0,sDelfina
  3938.     SNDCRD    4231,1,sPrelude
  3939.     SNDCRD    4754,3,sMaestro
  3940.     SNDCRD    4754,5,sMaestroPro
  3941.     SNDCRD    4754,12,sToccata
  3942.     SNDCRD    4754,13,sToccataPro
  3943.     SNDCRD    38A5,1,sDelfinaLITE
  3944.  
  3945. ;    SNDCRD    2140,13,sDelfina    db
  3946. ;    SNDCRD    2140,13,sMaestroPro
  3947.     dc.l    0
  3948.  
  3949. sWavetools    dc.b    'Wavetools',0
  3950. sDelfina    dc.b    'Delfina DSP',0
  3951. sPrelude    dc.b    'Prelude',0
  3952. sMaestro    dc.b    'Maestro',0
  3953. sMaestroPro    dc.b    'MaestroPro',0
  3954. sToccata    dc.b    'Toccata',0
  3955. sToccataPro    dc.b    'ToccataPro',0
  3956. sDelfinaLITE    dc.b    'Delfina LITE',0
  3957.  
  3958.     CNOP    0,4
  3959. ExecBase00    dc.l    'EXEC'
  3960.  
  3961.  
  3962.     CNOP    0,4
  3963. ;;    SECTION    BSS,BSS
  3964.  
  3965. ;;ExecBase01    ds.l    1
  3966.  
  3967. Params
  3968. CPU    ds.l    1
  3969. MHz    ds.l    1
  3970. procinfo_ptr    ds.l    1
  3971. ;Multiplier    ds.w    1
  3972. ;CmpCPU_ptr    ds.l    1
  3973. ;CmpCPUMHz    ds.w    1
  3974. ;WAIndex    ds.l    1
  3975. PowerUP_ptr    ds.l    1
  3976. FPU_ptr    ds.l    1
  3977. MMU    ds.l    1
  3978. MMUStatus    ds.l    1
  3979. GfxChip    ds.l    1
  3980. GfxChipRev_ptr    ds.l    1
  3981. AnimChip    ds.l    1
  3982. CustomChips    ds.l    1
  3983. GfxLibEmul_ptr    ds.l    1
  3984. BandWidth_ptr    ds.l    1
  3985. GfxBoardI    ds.l    1
  3986. GfxBoard    ds.l    1
  3987. C2P    ds.l    1
  3988. SndCardI    ds.l    1
  3989. SndCard    ds.l    1
  3990. HWClock_ptr    ds.l    1
  3991. ChipMemd    ds.l    1
  3992. FastMem    ds.l    1
  3993. VirtMem_ptr    ds.l    1
  3994. RomVer    ds.l    1
  3995. RomVerS    ds.l    1
  3996. ReKickROM_ptr    ds.l    1
  3997. WBVer    ds.l    1
  3998. WBVerS    ds.l    1
  3999. SetPatchVerPtr    ds.l    1
  4000. ExpBoards_ptr    ds.l    1
  4001. MachineGuess    ds.l    1
  4002. AfterMG_ptr    ds.l    1
  4003.  
  4004. CPUCompareTime    ds.l    1
  4005. FPUCompareTime    ds.l    1
  4006. CPUID    ds.l    1
  4007. EC    ds.l    1
  4008. _EC    ds.l    1
  4009. GfxLibEmul    ds.l    1
  4010. CRomVer    ds.l    1            \
  4011. CRomVerS    ds.l    1            /
  4012. CRomChkSum    ds.l    1
  4013. RomChkSum    ds.l    1
  4014. ;RamseyGaryRev
  4015. RamseyRev    ds.w    1
  4016. GaryRev    ds.w    1
  4017. GfxChipRev    ds.w    1
  4018.     ds.w    1
  4019. GfxChipID    ds.l    1
  4020. AnimChipID    ds.l    1
  4021. FPUID    ds.l    1
  4022. CardSlotID    ds.l    1
  4023. DraCoID    ds.l    1
  4024. PowerUPID    ds.l    1
  4025. UAEID    ds.l    1
  4026. GayleRev    ds.w    1
  4027. PaulaRev    ds.w    1
  4028. AGAGayleID    ds.l    1
  4029. A690ID    ds.l    1
  4030. CDTVID    ds.l    1
  4031. ATIDEID    ds.l    1
  4032. C2PID
  4033. AkikoID    ds.l    1
  4034. CD32NVRAMID    ds.l    1
  4035. UNIXID    ds.l    1
  4036. A500EID    ds.l    1
  4037. A2000EID    ds.l    1
  4038. A3000ID    ds.l    1
  4039. A4000ID    ds.l    1
  4040. A4091ID    ds.l    1
  4041. Phase5ID    ds.l    1
  4042. A4000TID    ds.l    1
  4043. A2500ID    ds.l    1
  4044. _100kHz    ds.l    1
  4045. HWClockID    ds.l    1
  4046. VirtMem    ds.l    1
  4047. AddrBits    ds.l    1
  4048. BandWidth    ds.w    1
  4049.     ds.w    1    Align
  4050.  
  4051. _ThisTask    ds.l    1
  4052. _Args    ds.l    1
  4053. _DosBase    ds.l    1
  4054. _ExpBase    ds.l    1
  4055. _wasDSACK    ds.l    1
  4056. _CiaInterrupt    ds.l    1
  4057. NewKick    ds.l    1
  4058. WBMode    ds.l    1
  4059. OutputFH    ds.l    1
  4060. EvalSpSave    ds.l    1
  4061. ChipMem    ds.l    1
  4062. ; disabled this x thing:
  4063. Multiplier    ds.w    1
  4064. CmpCPU_ptr    ds.l    1
  4065. CmpCPUMHz    ds.w    1
  4066. WAIndex    ds.l    1
  4067.  
  4068. pf_Data    ds.l    1    dosbase
  4069.     ds.l    1    cnt
  4070.     ds.b    256    text-buffer
  4071.  
  4072. FPUBuffer    ds.b    32
  4073. GfxBoardBuffer    ds.b    256
  4074. SndCardBuffer    ds.b    256
  4075. sVirtMemBuf    ds.b    80
  4076. sROMBuf    ds.b    80
  4077. ChipsBuffer    ds.b    80+2
  4078. GChipRevBuffer    ds.b    20
  4079. DBWBuffer    ds.b    32
  4080. ExpBoardsBuffer    ds.b    (10+10+6+4+48+48)*20
  4081. sPowerUPBuf    ds.b    80*8
  4082. sSetPatchBuf    ds.b    16
  4083. sPI060Buffer    ds.b    32
  4084.  
  4085.  
  4086.     SECTION    CODE_C,CODE_C        Virtmem sensitive parts:
  4087.  
  4088. ExecBase02    dc.l    'EXEC'
  4089.  
  4090.  
  4091.     include    "utility/utility_lib.i"
  4092.     IFND    _LVOReadEClock
  4093. _LVOReadEClock    EQU    -$3C
  4094.     ENDC
  4095.     CNOP    0,4
  4096. ;  IN: a0=init_routine, a1=time_routine, a2=cleanup_routine
  4097. ; OUT: d0=microseconds time_routine took to execute, -1 for error
  4098. ;NOTE: init_time_routine may change cache settings, loadview(0) etc.
  4099. ;      do NOT change a5!
  4100. TimeRoutine
  4101.     STRUCTURE mytimerstuff,0
  4102.     APTR    mts_execbase
  4103.     APTR    mts_timerbase
  4104.     APTR    mts_utilitybase
  4105.     STRUCT    mts_beg_eclockval,EV_SIZE
  4106.     STRUCT    mts_end_eclockval,EV_SIZE
  4107.     ;
  4108.     APTR    mts_init_routine
  4109.     APTR    mts_time_routine
  4110.     APTR    mts_cleanup_routine
  4111.     ULONG    mts_eclockfreq
  4112.     ;
  4113.     APTR    mts_ciabbase
  4114.     ULONG    mts_timerbit
  4115.     ULONG    mts_timermask
  4116.     UWORD    mts_oldAbleICRmask
  4117.     UWORD    mts_oldSetICRmask
  4118.     APTR    mts_ciabcrx
  4119.     APTR    mts_ciabtxlo
  4120.     STRUCT    mts_IS,IS_SIZE
  4121.     ALIGNLONG
  4122.     STRUCT    mts_icode,8
  4123.     LABEL    mts_fullrounds
  4124.     ULONG    mts_idata
  4125.     ULONG    mts_idata_add
  4126.     LABEL    mts_SIZEOF
  4127.  
  4128.  
  4129.     movem.l    d1-a6,-(sp)
  4130.     moveq    #-1,d7
  4131.     move.l    (4).w,a6
  4132.     cmp.w    #36,(LIB_VERSION,a6)
  4133.     shs    d6
  4134.  
  4135.     move.l    a0,d2
  4136.     move.l    a1,d3
  4137.     move.l    a2,d4
  4138.     move.l    #mts_SIZEOF,d0
  4139.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1    No virtmem please!
  4140.     call    AllocMem
  4141.     tst.l    d0
  4142.     beq    .exit
  4143.     move.l    d0,a5
  4144.     move.l    a6,(mts_execbase,a5)
  4145.     move.l    d2,(mts_init_routine,a5)
  4146.     move.l    d3,(mts_time_routine,a5)
  4147.     move.l    d4,(mts_cleanup_routine,a5)
  4148.  
  4149.     tst.b    d6
  4150.     beq.b    .nov36a
  4151.     lea    (DeviceList,a6),a0
  4152.     lea    (.timername,pc),a1
  4153.     call    Forbid
  4154.     call    FindName
  4155.     call    Permit
  4156.     move.l    d0,(mts_timerbase,a5)
  4157.     beq    .free
  4158.     bra    .got_timerbase
  4159. .nov36a
  4160.     move.l    #709379,(mts_eclockfreq,a5)
  4161.     cmp.b    #50,(PowerSupplyFrequency,a6)
  4162.     beq.b    .was_pal
  4163.     move.l    #715909,(mts_eclockfreq,a5)
  4164.     cmp.b    #60,(PowerSupplyFrequency,a6)
  4165.     bne    .free
  4166. .was_pal
  4167.     lea    (.ciabname,pc),a1
  4168.     call    OpenResource
  4169.     move.l    d0,(mts_ciabbase,a5)
  4170.     beq    .free
  4171.  
  4172.     lea    (mts_IS+LN_TYPE,a5),a1
  4173.     move.w    #NT_INTERRUPT<<8+127,(a1)+
  4174.     lea    (.ciaintname,pc),a0
  4175.     move.l    a0,(a1)+
  4176.     lea    (mts_idata,a5),a0
  4177.     move.l    a0,(a1)+
  4178.     lea    (mts_icode,a5),a0
  4179.     move.l    a0,(a1)+
  4180.     move.l    #$2029<<16!mts_idata_add-mts_idata,(a0)+ ;move.l (mts_idata_add-mts_idata,a1),d0
  4181.     move.l    #$D1914E75,(a0)                 ;add.l d0,(a1); rts
  4182.     move.l    #$10000,(mts_idata_add,a5)
  4183.     bsr    .cacheclear
  4184.  
  4185.     call    Disable
  4186.     move.l    (mts_ciabbase,a5),a6
  4187.     moveq    #1,d2
  4188. .allocloop    move.l    d2,d0
  4189.      lea    (mts_IS,a5),a1
  4190.     call    AddICRVector
  4191.     tst.l    d0
  4192.     beq.b    .ciaok
  4193.     dbf    d2,.allocloop
  4194.     bra.b    .no_timer
  4195. .ciaok    move.w    d2,d0
  4196.     move.l    d2,(mts_timerbit,a5)
  4197.     moveq    #1,d0
  4198.     lsl.l    d2,d0
  4199.     move.l    d0,(mts_timermask,a5)
  4200.     call    SetICR            Clear timer interrupt
  4201.     or.w    #$80,d0
  4202.     move.w    d0,(mts_oldSetICRmask,a5)
  4203.     move.l    (mts_timermask,a5),d0    Disable timer interrupt
  4204.     call    AbleICR
  4205.     or.w    #$80,d0
  4206.     move.w    d0,(mts_oldAbleICRmask,a5)
  4207. .no_timer    move.l    (mts_execbase,a5),a6
  4208.     call    Enable
  4209.     tst.w    d2
  4210.     bmi    .free
  4211.     move.l    (mts_timerbit,a5),d0
  4212.     lsl.l    #8,d0
  4213.     lea    CIAB+ciacra,a0
  4214.     add.w    d0,a0
  4215.     move.l    a0,(mts_ciabcrx,a5)
  4216.     add.w    d0,d0
  4217.     lea    CIAB+ciatalo,a0
  4218.     add.w    d0,a0
  4219.     move.l    a0,(mts_ciabtxlo,a5)
  4220.     move.l    (mts_ciabcrx,a5),a0    Stop timer, set continuos mode, count 02 pulses
  4221.     clr.b    (a0)
  4222.     move.l    (mts_ciabtxlo,a5),a0    Set timeout (counter)
  4223.     st    (a0)
  4224.     st    ($100,a0)
  4225.     move.l    (mts_ciabbase,a5),a6
  4226.     move.l    (mts_timermask,a5),d0
  4227.     or.w    #$80,d0            Enable timer interrupt
  4228.     call    AbleICR
  4229.  
  4230.     move.l    (mts_init_routine,a5),d0
  4231.     beq.b    .noinita
  4232.     move.l    d0,a0
  4233.     jsr    (a0)
  4234. .noinita    movem.l    d0-d1/a0-a1,-(sp)
  4235.  
  4236.     move.l    (mts_ciabcrx,a5),a0    set OUTMODE(?), RUNODE=cont, LOAD counter, START
  4237.     move.b    #%00010101,(a0)
  4238.  
  4239.     movem.l    (sp)+,d0-d1/a0-a1
  4240.     move.l    (mts_time_routine,a5),a0
  4241.     jsr    (a0)
  4242.  
  4243.     move.l    (mts_ciabcrx,a5),a0    Stop timer.
  4244.     clr.b    (a0)
  4245.  
  4246.     move.l    (mts_cleanup_routine,a5),d0
  4247.     beq.b    .nocleana
  4248.     move.l    d0,a0
  4249.     jsr    (a0)
  4250. .nocleana
  4251.     ; stopped
  4252.     moveq    #0,d1
  4253.     move.l    (mts_ciabtxlo,a5),a0    Get timer counter
  4254.     move.l    #$FFFF,d0
  4255.     move.b    ($100,a0),d1
  4256.     lsl.l    #8,d1
  4257.     move.b    (a0),d1
  4258.     sub.l    d1,d0            d0=count
  4259.     add.l    (mts_fullrounds,a5),d0    Add full timer rounds (rounds*$10000)
  4260.     move.l    d0,d2
  4261.  
  4262.     move.l    (mts_execbase,a5),a6
  4263.     call    Disable
  4264.     move.l    (mts_ciabbase,a5),a6
  4265.     move.l    (mts_timermask,a5),d0    Clear timer interrupt
  4266.     call    SetICR
  4267.     move.l    (mts_timermask,a5),d0    Disable timer interrupt
  4268.     call    AbleICR
  4269.     move.w    (mts_oldSetICRmask,a5),d0
  4270.     call    SetICR            Set orig timer interrupt
  4271.     move.w    (mts_oldAbleICRmask,a5),d0
  4272.     call    AbleICR            Enable orig interrupt
  4273.     lea    (mts_IS,a5),a1
  4274.     call    RemICRVector
  4275.     move.l    (mts_execbase,a5),a6
  4276.     call    Enable
  4277.  
  4278.     ;d2=EV_LO
  4279.  
  4280. .free    move.l    (mts_execbase,a5),a6
  4281.     move.l    a5,a1
  4282.     move.l    #mts_SIZEOF,d0
  4283.     call    FreeMem
  4284.  
  4285. .exit    move.l    d7,d0
  4286.     movem.l    (sp)+,d1-a6
  4287.     rts
  4288.  
  4289.  
  4290. .cacheclear    move.w    (AttnFlags,a6),d0
  4291.     btst    #AFB_68020,d0
  4292.     beq.b    .cc_nocache
  4293.     move.l    a5,a0
  4294.     lea    (.cc_cachec,pc),a5
  4295.     jmp    (_LVOSupervisor,a6)
  4296. .cc_nocache    rts
  4297. .cc_cachec    move.l    a0,a5
  4298.     btst    #AFB_68040,d0
  4299.     bne.b    .cc_040p
  4300.     movec    cacr,d0
  4301.     or.w    #CACRF_ClearI!CACRF_ClearD,d0
  4302.     movec    d0,cacr
  4303.     rte
  4304. .cc_040p    dc.w    $F478        ; CPUSHA BC    flush the data into memory
  4305.     nop
  4306.     rte
  4307.  
  4308.  
  4309. .got_timerbase    lea    (.utilityname,pc),a1
  4310.     moveq    #36,d0
  4311.     call    OpenLibrary
  4312.     move.l    d0,(mts_utilitybase,a5)
  4313.     beq    .free
  4314.  
  4315.     move.l    (mts_init_routine,a5),d0
  4316.     beq.b    .noinitb
  4317.     move.l    d0,a0
  4318.     jsr    (a0)
  4319. .noinitb    movem.l    d0-d1/a0-a1/a6,-(sp)
  4320.  
  4321.     move.l    (mts_timerbase,a5),a6
  4322.     lea    (mts_beg_eclockval,a5),a0
  4323.     call    ReadEClock
  4324.  
  4325.     movem.l    (sp)+,d0-d1/a0-a1/a6
  4326.     move.l    (mts_time_routine,a5),a0
  4327.     jsr    (a0)
  4328.  
  4329.     move.l    (mts_timerbase,a5),a6
  4330.     lea    (mts_end_eclockval,a5),a0
  4331.     call    ReadEClock
  4332.     move.l    d0,(mts_eclockfreq,a5)
  4333.  
  4334.     move.l    (mts_cleanup_routine,a5),d0
  4335.     beq.b    .nocleanb
  4336.     move.l    d0,a0
  4337.     jsr    (a0)
  4338. .nocleanb
  4339.     move.l    (mts_end_eclockval+EV_HI,a5),d0
  4340.     cmp.l    (mts_beg_eclockval+EV_HI,a5),d0
  4341.     bne.b    .closeu
  4342.  
  4343.     ;efreqmul=2000
  4344.     ;evalmul=1000000/efreqmul
  4345.     ;micros=eval*evalmul/efreq*efreqmul
  4346.  
  4347. efreqmul    EQU    2000
  4348. evalmul    EQU    1000000/efreqmul
  4349.  
  4350.     move.l    (mts_utilitybase,a5),a6
  4351.  
  4352.     move.l    (mts_eclockfreq,a5),d0
  4353.     move.l    #efreqmul,d1
  4354.     call    UMult32
  4355.     move.l    d0,d2            efreq*efreqmul
  4356.     beq.b    .closeu
  4357.  
  4358.     move.l    (mts_end_eclockval+EV_LO,a5),d0
  4359.     sub.l    (mts_beg_eclockval+EV_LO,a5),d0
  4360.     IFGT    0
  4361.     move.l    #evalmul,d1
  4362.     call    UMult32            eval*evalmul
  4363.  
  4364.     move.l    d2,d1
  4365.     call    UDivMod32
  4366.     ;d0=micros=eval*evalmul/efreq*efreqmul
  4367.     ENDC
  4368.     move.l    d0,d7
  4369.  
  4370. .closeu    move.l    (mts_execbase,a5),a6
  4371.     move.l    (mts_utilitybase,a5),a1
  4372.     call    CloseLibrary
  4373.     bra    .free
  4374.  
  4375.  
  4376. .timername    dc.b    'timer.device',0
  4377. .utilityname    dc.b    'utility.library',0
  4378. .ciabname    dc.b    'ciab.resource',0
  4379. .ciaintname    dc.b    'TimeRoutine cia-b interrupt',0
  4380.     CNOP    0,4
  4381.  
  4382.  
  4383. ; Test 68030, 68040 and 68882 WITHOUT system (for KS1.x use)
  4384. ;  IN: d2=attnflags, a6=execbase
  4385. ; OUT: d0=updated attnflags
  4386. Test030_040_882    move.l    a5,-(sp)
  4387.     lea    (.sv,pc),a5
  4388.     call    Supervisor
  4389.     move.l    (sp)+,a5
  4390.     rts
  4391.  
  4392. .sv    moveq    #0,d0
  4393.     btst    #AFB_68020,d2
  4394.     beq.b    .not68020
  4395.     movec    cacr,d1
  4396.     move.l    d1,-(sp)
  4397.     or.w    #CACRF_WriteAllocate,d1
  4398.     movec    d1,cacr
  4399.     movec    cacr,d1
  4400.     btst    #CACRB_WriteAllocate,d1
  4401.     beq.b    .not68030
  4402.     bset    #AFB_68030,d0
  4403. .not68030    move.l    (sp)+,d1
  4404.     movec    d1,cacr
  4405.  
  4406.     movec    cacr,d1
  4407.     move.l    d1,-(sp)
  4408.     or.w    #CACRF_EnableI!CACRF_ClearI!CACRF_ClearD!CACRF_WriteAllocate,d1
  4409.     movec    d1,cacr
  4410.     movec    cacr,d1
  4411.     btst    #CACRB_EnableI,d1
  4412.     bne.b    .not68040
  4413.     or.b    #AFF_68040!AFF_68030,d0
  4414. .not68040    move.l    (sp)+,d1
  4415.     or.w    #CACRF_ClearI!CACRF_ClearD!CACRF_WriteAllocate,d1
  4416.     movec    d1,cacr
  4417. .not68020
  4418.     btst    #AFB_68881,d2
  4419.     beq.b    .no882
  4420.  
  4421.     moveq    #0,d1
  4422.     dc.w    $F201,$9000
  4423.     dc.w    $F201,$B000
  4424.  
  4425.     dc.w    $F327
  4426.     dc.w    $0C2F,$0018,$0001        cmp.b    #$18,(1,sp)
  4427.     beq.b    .flushstack
  4428.     bset    #AFB_68882,d0
  4429. .flushstack    dc.w    $F35F
  4430. .no882    nop                sync pipelines
  4431.     rte
  4432.  
  4433.  
  4434.  
  4435.  
  4436.     IFGT    0
  4437.  
  4438.  >> Information taken from '68060 Upgrade Software Guide' <<
  4439.  
  4440. 2) Inststructions supported by the 68040 but not by the 68060 directly that
  4441.    can hurt performance:
  4442.  
  4443.  o divx.l (64bit divide)
  4444.  o mulx.l (64bit multiply)
  4445.  o fdbcc
  4446.  o fscc
  4447.  o movep
  4448.  o There are other instructions that are not supported or have to
  4449.    be emulated but these aren't relevant for user applications.
  4450.     ENDC
  4451.  
  4452. Test060    move.l    a5,-(sp)
  4453.     lea    (.test060,pc),a5
  4454.     call    Disable            No others playing around, please.
  4455.     call    Supervisor        Ramsey revision:
  4456.     call    Enable
  4457.     move.l    (sp)+,a5
  4458.     rts
  4459.  
  4460. .test060    movec    vbr,a0            Hijack illegal instr. trap
  4461.     move.l    ($10,a0),-(sp)
  4462.     move.l    ($2C,a0),-(sp)
  4463.     move.l    a0,-(sp)
  4464.     lea    (.illegal,pc),a1
  4465.     move.l    a1,($10,a0)
  4466.     move.l    a1,($2C,a0)
  4467.     bsr    _flush040
  4468.  
  4469.     moveq    #0,d0
  4470.  
  4471.     dc.w    $4E7A,$0008        movec    BUSCR,d0
  4472.     dc.w    $4E7A,$0808        movec    PCR,d0
  4473.  
  4474.     nop
  4475.     nop
  4476.     moveq    #1,d0
  4477. .exit_illegal
  4478.     move.l    (sp)+,a0        Restore illegal instr. trap
  4479.     move.l    (sp)+,($2C,a0)
  4480.     move.l    (sp)+,($10,a0)
  4481.     move.l    d0,-(sp)
  4482.     bsr    _flush040
  4483.     move.l    (sp)+,d0
  4484.     beq.b    .no060
  4485.  
  4486.     or.w    #AFF_68060,d2
  4487. .no060    nop
  4488.     rte
  4489.  
  4490.     CNOP    0,4
  4491. .illegal    lea    (.exit_illegal,pc),a0
  4492.     move.l    a0,(2,sp)
  4493.     nop                sync pipelines
  4494.     rte
  4495.  
  4496.  
  4497.  
  4498. CacheClearU    moveq    #0,d1
  4499. CacheControl    movem.l    d1-d2/a0/a1/a5/a6,-(sp)
  4500.     move.l    (4).w,a6        Use (4).w!!!
  4501.     or.w    #CACRF_ClearI!CACRF_ClearD!CACRF_WriteAllocate,d0
  4502.     or.w    #CACRF_ClearI!CACRF_ClearD!CACRF_WriteAllocate,d1
  4503.     cmp.w    #37,(LIB_VERSION,a6)
  4504.     blo.b    .oldkick
  4505.     call    CacheControl
  4506.     bra.b    .xit
  4507.  
  4508. .oldkick    btst    #AFB_68020,_AttnFlags+1
  4509.     beq.b    .xit
  4510.     lea    (.sv,pc),a5
  4511.     call    Supervisor
  4512. .xit    movem.l    (sp)+,d1-d2/a0/a1/a5/a6
  4513.     rts
  4514.  
  4515. .sv    movec    cacr,d2
  4516.     move.l    d2,-(sp)
  4517.     and.l    d1,d0
  4518.     not.l    d1
  4519.     and.l    d1,d2
  4520.     or.l    d2,d0
  4521.     movec    d0,cacr
  4522.     move.l    (sp)+,d0
  4523.     nop                sync pipelines
  4524.     rte
  4525.  
  4526.  
  4527. ;  IN: (extended attnflags field, MMU routines available)
  4528. ; OUT: d0=24 or 32
  4529. GetAddressBits    movem.l    d1-a6,-(sp)
  4530.     moveq    #32,d7
  4531.  
  4532.     tst.l    DraCoID            DraCo has 32bit 68060!
  4533.     bne.b    .xit
  4534.  
  4535.     lea    (_getaddrbits,pc),a0
  4536.     moveq    #1,d0
  4537.     bsr    RunNoMMU
  4538. .xit    move.l    d7,d0
  4539.     movem.l    (sp)+,d1-a6
  4540.     rts
  4541.  
  4542. _getvbr    sub.l    a0,a0
  4543.     btst    #AFB_68010,_AttnFlags+1
  4544.     beq.b    .novbr
  4545.     movec    vbr,a0
  4546. .novbr    rts
  4547.  
  4548. _getaddrbits    bsr.b    _getvbr
  4549.     move.l    ($08,a0),-(sp)        Save Access Fault vector
  4550.     move.l    a0,-(sp)        Save VBR
  4551.     lea    (.busfailure,pc),a1    Set new Access Fault vector:
  4552.     move.l    a1,($08,a0)
  4553.  
  4554.     lea    AddrChipData,a0        16 byte chip buffer
  4555.     move.l    #$BADCAFFE,d1
  4556.     move.l    #$DEADBABE,d2
  4557.     move.l    #'lOVE',d3
  4558.     move.l    #'8biT',d4
  4559.  
  4560.     move.w    #256-1-1,d5
  4561.     movem.l    d1-d4,(a0)
  4562.     move.l    a0,a1
  4563. .loop    add.l    #$1000000,a1
  4564.  
  4565.     moveq    #4-1,d0
  4566.     move.l    a0,a2
  4567.     move.l    a1,a3
  4568. .compare    cmpm.l    (a2)+,(a3)+
  4569.     dbne    d0,.compare
  4570.     tst.w    d0
  4571.     dbpl    d5,.loop
  4572.  
  4573.     tst.w    d5
  4574.     bpl.b    .exit            Is 32bit
  4575.  
  4576.     exg    d1,d4
  4577.     exg    d2,d3
  4578.     movem.l    d1-d4,(a0)
  4579.     movem.l    (a1),d5-d6/a4-a5
  4580.     movem.l    d1-d4,(a1)
  4581.  
  4582.     moveq    #4-1,d0
  4583.     move.l    a0,a2
  4584.     move.l    a1,a3
  4585. .compare2    cmpm.l    (a2)+,(a3)+
  4586.     dbne    d0,.compare2
  4587.  
  4588.     movem.l    d5-d6/a4-a5,(a1)
  4589.  
  4590.     tst.w    d0
  4591.     bmi.b    .exit            Isn't 24bit
  4592.  
  4593.     moveq    #24,d7
  4594.  
  4595. .exit
  4596. .busfproceed    move.l    (sp)+,a0        Restore VBR
  4597.     move.l    (sp)+,($08,a0)        Restore Access Fault vector
  4598. .xit    move.l    d7,d0
  4599.     rts
  4600.  
  4601.     CNOP    0,4
  4602. .busfailure    bclr    #0,(10,sp)
  4603.     beq.b    .bf_exit
  4604.     moveq    #32,d7            If CPU can generate bus failure then it's 32bit
  4605.     lea    (.busfproceed,pc),a0
  4606.     move.l    a0,(2,sp)
  4607. .bf_exit    nop                sync pipelines
  4608.     rte
  4609.  
  4610.  
  4611.     CNOP    0,4
  4612. GetVbr    move.l    a5,-(sp)
  4613.     sub.l    a0,a0
  4614.     btst    #AFB_68010,_AttnFlags+1
  4615.     beq.b    .novbr
  4616.     lea    (.getvbr,pc),a5
  4617.     call    Supervisor
  4618. .novbr    move.l    (sp)+,a5
  4619.     rts
  4620. .getvbr    movec    vbr,a0
  4621.     nop                sync pipelines
  4622.     rte
  4623.  
  4624.  
  4625.     CNOP    0,4
  4626. ChipTiming2    bsr    Disable
  4627.  
  4628.     IFGT    0
  4629.     tst.l    NoHW
  4630.     bne.b    .nohw1
  4631.     move.w    (dmaconr,a4),d0
  4632.     and.w    #$000F,d0        only audio dma please...
  4633.     or.w    #$8000,d0        set
  4634.     move.w    #$000F,(dmacon,a4)    Disable audio dma
  4635.     move.l    d0,-(sp)
  4636. .nohw1
  4637.     ENDC
  4638.  
  4639.     move.l    #CACRF_EnableI,d0    Disable all but inst cache for test
  4640.     move.l    #~CACRF_WriteAllocate,d1 WAS: -1
  4641.     bsr    CacheControl
  4642.     move.l    d0,-(sp)        Save prev cache state
  4643.  
  4644.     jsr    turnon060caches
  4645.  
  4646.     move.l    TimerBit,d0
  4647.     lsl.l    #8,d0
  4648.     lea    CIAB+ciacra,a2
  4649.     add.w    d0,a2
  4650.     add.w    d0,d0
  4651.     lea    CIAB+ciatalo,a3
  4652.     add.w    d0,a3
  4653.  
  4654.     move.l    CiabResource,a6
  4655.     move.l    TimerMask,d0        Clear timer interrupts
  4656.     call    SetICR
  4657.     moveq    #$7F,d0            Disable all timer interrupts
  4658.     call    AbleICR
  4659.     move.l    d0,-(sp)
  4660.     clr.b    (a2)            Stop timer, set continuos mode, count 02 pulses
  4661.     st    (a3)            Set timeout
  4662.     st    ($100,a3)
  4663.     move.l    TimerMask,d0
  4664.     or.w    #1<<7,d0        Enable timer interrupt
  4665.     call    AbleICR
  4666.  
  4667.     move.l    (ExecBase02,pc),a6
  4668.     bsr    ChipTiming
  4669.     move.l    d0,d7
  4670.  
  4671.     move.l    CiabResource,a6
  4672.     moveq    #$7F,d0            Disable all timer interrupts
  4673.     call    AbleICR
  4674.     move.l    (sp)+,d0        Restore old timer interrupts
  4675.     or.w    #1<<7,d0
  4676.     call    AbleICR
  4677.  
  4678.     jsr    restore060caches
  4679.  
  4680.     move.l    (ExecBase02,pc),a6    Restore cache state
  4681.     move.l    (sp)+,d0
  4682.     moveq    #-1,d1
  4683.     bsr    CacheControl
  4684.  
  4685.     IFGT    0
  4686.     tst.l    NoHW
  4687.     bne.b    .nohw2
  4688.     move.l    (sp)+,d0
  4689.     move.w    d0,(dmacon,a4)        Enable audio dma
  4690. .nohw2
  4691.     ENDC
  4692.  
  4693.     bsr    Enable
  4694.     move.l    d7,d0
  4695.     rts
  4696.  
  4697. Disable    tst.l    NoHW
  4698.     bne.b    .nohw
  4699.     jmp    (_LVODisable,a6)
  4700. .nohw    jmp    (_LVOForbid,a6)
  4701.  
  4702. Enable    tst.l    NoHW
  4703.     bne.b    .nohw
  4704.     jmp    (_LVOEnable,a6)
  4705. .nohw    jmp    (_LVOPermit,a6)
  4706.  
  4707.  
  4708.     CNOP    0,4
  4709. ChipTiming    tst.l    NoHW
  4710.     bne.b    .nohw1
  4711.  
  4712.     move.w    (intenar,a4),d7
  4713.     move.w    #$7FFF,(intena,a4)    Disable all interrupts
  4714.     or.w    #$8000,d7        set
  4715.     move.w    #$E000,(intena,a4)    Enable level6 ints
  4716.  
  4717.     bsr    GetVbr            Set new level 6 int
  4718.     lea    ($60+6*4,a0),a0
  4719.     move.l    (a0),-(sp)
  4720.     move.l    a0,-(sp)        Can be done 'cause we're in a disabled state!!
  4721.     lea    (Level6Trap,pc),a1    Otherwise should get vbr again on restore.
  4722.     move.l    a1,(a0)
  4723. .nohw1
  4724.  
  4725.     move.l    a5,a0
  4726.     moveq    #0,d0            No disable!
  4727.     bsr    RunNoMMU
  4728.  
  4729.     tst.l    NoHW
  4730.     bne.b    .nohw2
  4731.  
  4732.     move.l    (sp)+,a0        Restore old level 6 int
  4733.     move.l    (sp)+,(a0)
  4734.  
  4735.     move.w    #$7FFF,(intena,a4)    Disable all ints
  4736.     move.w    d7,(intena,a4)        Enable interrupts
  4737. .nohw2
  4738.  
  4739.     lea    CiaIntData,a0
  4740.     move.l    (a0),d0
  4741.     clr.l    (a0)
  4742.     not.l    d0
  4743.     rts
  4744.  
  4745.  
  4746.     CNOP    0,8
  4747. Level6Trap    movem.l    d0-d1/a0-a1,-(sp)
  4748.     move.b    CIAB+ciaicr,d0
  4749.     move.b    TimerBit+3,d1
  4750.     btst    d1,d0
  4751.     beq.b    .xit_argh
  4752.     lea    CiaIntData,a1
  4753.     bsr.b    CiaIntCode
  4754. .xit_argh    move.w    #INTF_EXTER,$DFF000+intreq
  4755.     movem.l    (sp)+,d0-d1/a0-a1
  4756.     nop                sync pipelines
  4757.     rte
  4758.  
  4759.  
  4760.     CNOP    0,8
  4761. CiaIntCode    subq.l    #1,(a1)            more loops to do?
  4762.     bne.b    .skip
  4763.     move.l    d4,(a1)            store result
  4764.     moveq    #1,d4            exit loop
  4765. .skip    rts
  4766.  
  4767.  
  4768. ; Loop to time CPU:
  4769.  
  4770.     CNOP    0,8
  4771. CPU_chiptiming    addq.l    #5,CiaIntData        Number of loops
  4772.     moveq    #-1,d4            Init counter
  4773.     move.b    #%00010101,(a2)        Start timer
  4774.     bra.b    .loop
  4775.     CNOP    0,8
  4776. .loop    subq.l    #1,d4            Main timing loop
  4777.     bne.b    .loop
  4778.     clr.b    (a2)            Stop timer
  4779.     rts
  4780.  
  4781. CPUTIMER_SIZEOF    EQU    (*-CPU_chiptiming+7)&-8
  4782.  
  4783. ; Loop to time FPU:
  4784.  
  4785.     CNOP    0,8
  4786. FPU_chiptiming    addq.l    #3,CiaIntData        Number of loops
  4787.     moveq    #-1,d4            Init counter
  4788.     fmove.x    #0.000000001,fp0
  4789.     fmove.x    fp0,fp1
  4790.  
  4791.     move.b    #%00010101,(a2)        Start timer
  4792.     bra.b    .loop
  4793.  
  4794.     CNOP    0,8
  4795. .loop    fadd.x    fp1,fp0            Main timing loop
  4796.     fsub.x    fp1,fp0
  4797.     subq.l    #1,d4
  4798.     bne.b    .loop
  4799.     clr.b    (a2)            Stop timer
  4800.     rts
  4801.  
  4802.  
  4803.  
  4804.     CNOP    0,4
  4805. getromver_novmem
  4806.     lea    (.novirtmempart,pc),a0
  4807.     moveq    #1,d0
  4808.     bra    RunNoMMU
  4809. ;;    bsr    RunNoMMU
  4810. ;;    rts
  4811.  
  4812. .novirtmempart
  4813.     lea    $1000000,a0
  4814.     tst.l    Phase5ID
  4815.     beq.b    .nophaserom
  4816.     lea    $0B80000,a1
  4817.     moveq    #8,d0
  4818.     swap    d0
  4819.     cmp.l    (-$14,a1),d0
  4820.     bne.b    .nophaserom
  4821.     neg.l    d0
  4822.     move.l    (a1,d0.l),d0
  4823.     and.l    #$FFF8FFFF,d0
  4824.     cmp.l    #$11104EF9,d0
  4825.     bne.b    .nophaserom
  4826.     move.l    a1,a0
  4827. .nophaserom
  4828.     move.l    (-$14,a0),d0
  4829.     move.l    d0,d1
  4830.     and.l    #$0003FFFF,d1
  4831.     bne.b    .no_rom
  4832.     cmp.l    #$00100000,d0
  4833.     bhi.b    .no_rom
  4834.     sub.l    d0,a0
  4835.     move.l    (a0),d1
  4836.     and.l    #$FFF8FFFF,d1
  4837.     cmp.l    #$11104EF9,d1
  4838.     bne.b    .no_rom
  4839.     move.l    (12,a0),d7
  4840.  
  4841.     bsr.b    ROMReSum
  4842.     move.l    d0,d6
  4843. .exit    rts
  4844. .no_rom    moveq    #0,d7
  4845.     moveq    #0,d6
  4846.     bra.b    .exit
  4847.  
  4848.  
  4849. ;  IN: d0=rom size, a0=rom start
  4850. ; OUT: d0=chksum
  4851. ROMReSum    move.l    d0,d1
  4852.     lsr.l    #3,d1
  4853.     move.l    -$18(a0,d0.l),d0
  4854.     not.l    d0
  4855. .loop    add.l    (a0)+,d0
  4856.     bcc.b    .skip1
  4857.     addq.l    #1,d0
  4858. .skip1    add.l    (a0)+,d0
  4859.     bcc.b    .skip2
  4860.     addq.l    #1,d0
  4861. .skip2    subq.l    #1,d1
  4862.     bne.b    .loop
  4863.     not.l    d0
  4864.     rts
  4865.  
  4866.  
  4867.     CNOP    0,4
  4868. ; a0=code to run without MMU, d0=disable flag
  4869. ; Code should be in Chip memory (in case of VMM or similar)
  4870. RunNoMMU    movem.l    d0/a5/a6,-(sp)
  4871.     move.l    (ExecBase02,pc),a6    Use (4).w??
  4872.     lea    (.super,pc),a5
  4873.     DBG    'RNM1'
  4874.     tst.l    d0
  4875.     beq.b    .nodis
  4876.     call    Disable
  4877. .nodis    tst.l    NoHW
  4878.     bne.b    .nohw1
  4879.     subq.l    #4,sp
  4880.     move.w    $DFF000+dmaconr,(sp)
  4881.     move.w    #$000F,$DFF000+dmacon
  4882.     or.w    #$8000,(sp)
  4883. .nohw1    call    Supervisor
  4884.     tst.l    NoHW
  4885.     bne.b    .nohw2
  4886.     move.w    (sp),$DFF000+dmacon
  4887.     addq.l    #4,sp
  4888. .nohw2    tst.l    (sp)+
  4889.     beq.b    .noen
  4890.     call    Enable
  4891. .noen    movem.l    (sp)+,a5/a6
  4892.     DBG    'RNM2'
  4893.     tst.l    d0
  4894.     rts
  4895.  
  4896.     CNOP    0,4
  4897. .super
  4898. ;;    or.w    #$700,sr
  4899.     tst.l    _MMUID
  4900.     beq.b    .nommua
  4901.     btst    #AFB_68040,_AttnFlags+1
  4902.     beq    .is030a
  4903.     bsr    _flush040
  4904.     move.l    d0,-(sp)
  4905.     movec    TC,d0
  4906.     move.l    d0,-(sp)
  4907.     movec    URP,d0
  4908.     move.l    d0,-(sp)
  4909.     movec    SRP,d0
  4910.     move.l    d0,-(sp)
  4911.     movec    DTT1,d0
  4912.     move.l    d0,-(sp)
  4913.     movec    DTT0,d0
  4914.     move.l    d0,-(sp)
  4915.     movec    ITT1,d0
  4916.     move.l    d0,-(sp)
  4917.     movec    ITT0,d0
  4918.     move.l    d0,-(sp)
  4919.     move.l    #$00FFC000,d0
  4920.     movec    d0,ITT0
  4921.     movec    d0,ITT1
  4922.     movec    d0,DTT1
  4923.     move.l    #$0000C040,d0
  4924.     movec    d0,DTT0
  4925.     move.l    #$00030000,d0
  4926.     movec    d0,URP
  4927.     movec    d0,SRP
  4928.     moveq    #0,d0
  4929.     movec    d0,TC
  4930.     bsr    _flush040
  4931.     move.l    (7*4,sp),d0
  4932. .nommua    jsr    (a0)
  4933.     tst.l    _MMUID
  4934.     beq.b    .nommub
  4935.     btst    #AFB_68040,_AttnFlags+1
  4936.     beq.b    .is030b
  4937.     bsr    _flush040
  4938.     move.l    d0,-(sp)
  4939.     move.l    (1*4,sp),d0
  4940.     movec    d0,ITT0
  4941.     move.l    (2*4,sp),d0
  4942.     movec    d0,ITT1
  4943.     move.l    (3*4,sp),d0
  4944.     movec    d0,DTT0
  4945.     move.l    (4*4,sp),d0
  4946.     movec    d0,DTT1
  4947.     move.l    (5*4,sp),d0
  4948.     movec    d0,SRP
  4949.     move.l    (6*4,sp),d0
  4950.     movec    d0,URP
  4951.     bsr    _flush040
  4952.     move.l    (7*4,sp),d0
  4953.     movec    d0,TC
  4954.     move.l    (sp)+,d0
  4955.     lea    (7*4,sp),sp
  4956. .nommub2    addq.l    #4,sp
  4957. .nommub    nop                sync pipelines
  4958.     rte
  4959.  
  4960. .is030a    clr.l    -(sp)
  4961.     pmove.l    tc,(sp)
  4962.     move.l    (sp),-(sp)
  4963.     bclr    #7,(sp)
  4964.     pmove.l    (sp),tc
  4965.     addq.l    #4,sp
  4966.     bra.b    .nommua
  4967.  
  4968. .is030b    pmove.l    (sp),tc
  4969.     bra.b    .nommub2
  4970.  
  4971.  
  4972. _flush040    dc.w    $F518        ; PFLUSHA    flush the address translation cache
  4973.     dc.w    $F4F8        ; CPUSHA BC    flush the caches into memory
  4974.     dc.w    $F4D8        ; INVA    BC    invalidate the data and inst caches
  4975.     rts
  4976.  
  4977.  
  4978.     CNOP    0,4
  4979. ; OUT: d0=0 no mmu, d0=1 68851 mmu, d0=2 68030 MMU, d0=3 68040 MMU, d0=4 68060 MMU
  4980. ;      d1=mmu activity status, valid if d0>0
  4981. GetMMU
  4982. ; Must be called from user state!!
  4983. ;  OUT: d0=success if working MMU exists, null otherwise
  4984. ;       d0=0 for no MMU
  4985. ;          4 for 68060 or 68LC060 internal MMU
  4986. ;          3 for 68040 or 68LC040 internal MMU
  4987. ;          2 for 68030 internal MMU
  4988. ;          1 for 68020 + 68851 MMU
  4989. ;       d1=mmu activity status, valid if d0>0
  4990. TestForMMU    movem.l    d2-a6,-(sp)
  4991.     moveq    #0,d7
  4992.  
  4993.     move.l    (ExecBase02,pc),a6
  4994.     move.w    _AttnFlags,d0
  4995.     btst    #AFB_68020,d0        No MMU below 68020!
  4996.     beq.b    .exit
  4997.     cmp.w    #37,(LIB_VERSION,a6)
  4998.     blo.b    .oldtest
  4999.     lea    (.test040plus,pc),a5
  5000.     moveq    #MC68060m,d6
  5001.     tst.b    d0            Test #AFB_68060
  5002.     bmi.b    .test
  5003.     subq.l    #1,d6
  5004.     btst    #AFB_68040,d0
  5005.     bne.b    .test
  5006. .otcont    lea    (.test020plus,pc),a5
  5007.     subq.l    #1,d6
  5008.     btst    #AFB_68030,d0
  5009.     bne.b    .test
  5010.     subq.l    #1,d6
  5011. .test
  5012.     DBG    'MMU1'
  5013.     jsr    (a5)
  5014.     DBG    'MMU2'
  5015.  
  5016. .exit    move.l    d7,d0
  5017.     beq.b    .fail
  5018.     move.l    d6,d0
  5019. .fail    movem.l    (sp)+,d2-a6
  5020.     rts
  5021.  
  5022. .oldtest    moveq    #MC68030m+1,d6
  5023.     bra.b    .otcont
  5024.  
  5025. .test040plus    lea    (.gogo040,pc),a5
  5026.     call    Disable
  5027.     call    Supervisor
  5028.     jmp    (_LVOEnable,a6)
  5029. .gogo040    or.w    #$700,sr        Disable interrupts.
  5030.     movec    vbr,a0            Get VBR
  5031.     move.l    ($10,a0),-(sp)        Save Illegal Instruction vector
  5032.     move.l    ($2C,a0),-(sp)        Save F-Line Emul vector
  5033.     move.l    a0,-(sp)        Save VBR
  5034.  
  5035.     lea    (.illegal040,pc),a1
  5036.     move.l    a1,($10,a0)
  5037.     move.l    a1,($2C,a0)
  5038.     bsr    _flush040
  5039.  
  5040.     moveq    #0,d0            IMPORTANT!
  5041.     moveq    #-1,d7
  5042.     movec    tc,d0            $4e7a0003    Test some "common" MMU regs:
  5043.     movec    urp,d1            $4e7a1806    Test 040/060 MMU only reg!!
  5044.     movec    srp,d1            $4e7a1807
  5045. .exit040    nop
  5046.     nop
  5047.     ; d0=mmu TC (or null)
  5048.  
  5049.     moveq    #0,d1
  5050.     tst.l    d7
  5051.     beq.b    .gm4_nommu
  5052.     btst    #15,d0            Bit 15: On/Off!!
  5053.     beq.b    .gm4_nommu
  5054.     moveq    #1,d1
  5055. .gm4_nommu
  5056.     move.l    (sp)+,a0
  5057.     move.l    (sp)+,($2C,a0)        Restore F-Line Emul vector
  5058.     move.l    (sp)+,($10,a0)        Restore Illegal Instruction vector
  5059.     bsr    _flush040
  5060.     nop                sync pipelines
  5061.     rte
  5062.  
  5063.     CNOP    0,4
  5064. .illegal040    moveq    #0,d7
  5065.     lea    (.exit040,pc),a0
  5066.     move.l    a0,(2,sp)
  5067.     bsr    _flush040
  5068.     nop                sync pipelines
  5069.     rte
  5070.  
  5071.  
  5072. .simpletest    call    Disable
  5073.     lea    (.gogos020,pc),a5
  5074.     call    Supervisor
  5075.     jmp    (_LVOEnable,a6)
  5076.  
  5077. .gogos020    or.w    #$700,sr        Disable interrupts.
  5078.  
  5079.     movec    vbr,a0            Get VBR
  5080.     move.l    ($10,a0),-(sp)        Save Illegal Instruction vector
  5081.     move.l    ($2C,a0),-(sp)        Save F-Line Emul vector
  5082.     move.l    a0,-(sp)        Save VBR
  5083.  
  5084.     lea    (.mmuinstfailures,pc),a1
  5085.     move.l    a1,($10,a0)
  5086.     move.l    a1,($2C,a0)
  5087.  
  5088.     bsr    _flush020
  5089.  
  5090.     moveq    #-1,d7
  5091.     clr.l    -(sp)
  5092.     pmove.l    tc,(sp)
  5093. .exitsupers    move.l    (sp)+,d5
  5094.  
  5095.     moveq    #0,d1
  5096.     tst.l    d7
  5097.     beq.b    .gm2_nommus
  5098.     tst.l    d5            Bit 31: On/Off!!
  5099.     bpl.b    .gm2_nommus
  5100.     moveq    #1,d1
  5101. .gm2_nommus
  5102.     move.l    (sp)+,a0        Restore VBR
  5103.     move.l    (sp)+,($2C,a0)        Restore F-Line Emul vector
  5104.     move.l    (sp)+,($10,a0)        Restore Illegal Instruction vector
  5105.     bsr    _flush020
  5106.     rte
  5107.  
  5108. .mmuinstfailures
  5109.     lea    (.exitsupers,pc),a0    Invalid mmu instruction!
  5110.     moveq    #0,d7
  5111.     move.l    a0,(2,sp)
  5112.     rte
  5113.  
  5114.  
  5115.  
  5116. .test020plus
  5117. ;;GVP's    move.l    #$07E1<<16!$FFFF,d0    Try to find any 'Great Valley Products' board
  5118. ;;works    jsr    FindConfigDev
  5119. ;;now??    bne.b    .simpletest        If found test MMU with simple code (following one crashes!)
  5120.  
  5121.     lea    $D0000000,a2
  5122.     move.w    #$10000000/(512*1024)-1-1,d2
  5123. .tloop    move.l    a2,a1
  5124.     call    TypeOfMem
  5125.     tst.l    d0
  5126.     bne    .simpletest
  5127.     add.l    #512*1024,a2
  5128.     dbf    d2,.tloop
  5129.  
  5130.     move.l    #((1<<8)+.TTable1End-.TTable1),d0
  5131.     moveq    #MEMF_PUBLIC,d1
  5132.     call    AllocMem
  5133.     tst.l    d0
  5134.     beq    .simpletest
  5135.     move.l    d0,a4
  5136.  
  5137.     add.l    #(1<<7)-1,d0
  5138.     and.w    #-(1<<7),d0
  5139.     move.l    d0,a2
  5140.     lea    (.TTable1,pc),a0
  5141.     move.l    a2,a1
  5142.     moveq    #(.TTable1End-.TTable1),d0
  5143.     call    CopyMem            Used to use CopyMemQuick... Is it KS1.3+?
  5144.  
  5145.     call    Disable
  5146.     lea    (.gogo020,pc),a5
  5147.     call    Supervisor
  5148.     call    Enable
  5149.  
  5150.     movem.l    d0-d1,-(sp)
  5151.     move.l    #((1<<8)+.TTable1End-.TTable1),d0
  5152.     move.l    a4,a1
  5153.     call    FreeMem
  5154.     movem.l    (sp)+,d0-d1
  5155.     rts
  5156.  
  5157. .gogo020    or.w    #$700,sr        Disable interrupts.
  5158.     moveq    #0,d5            IMPORTANT!
  5159.  
  5160.     move.l    #$D0000000,d0        Test for our usage of area $D0000000:
  5161.     move.l    #$F0000000,d1
  5162.     move.l    sp,d2            SSP uses $D0000000?
  5163.     and.l    d1,d2
  5164.     cmp.l    d0,d2
  5165.     beq    .exitall
  5166.     move.l    #.test020plus,d2    PC?
  5167.     and.l    d1,d2
  5168.     cmp.l    d0,d2
  5169.     beq    .exitall
  5170.  
  5171.     movec    vbr,a0            Get VBR
  5172.     move.l    ($08,a0),-(sp)        Save Access Fault vector
  5173.     move.l    ($10,a0),-(sp)        Save Illegal Instruction vector
  5174.     move.l    ($2C,a0),-(sp)        Save F-Line Emul vector
  5175.     move.l    ($E0,a0),-(sp)        Save MMU Config Error vector
  5176.     move.l    ($E4,a0),-(sp)        Save MMU Illegal Operation Error vector
  5177.     move.l    ($E8,a0),-(sp)        Save MMU Access Level Violation Error vector
  5178.     move.l    a0,-(sp)        Save VBR
  5179.  
  5180.     subq.l    #8,sp
  5181.  
  5182.     lea    (.mmufailure_es,pc),a1    Set new vectors:
  5183.     move.l    a1,($08,a0)
  5184.     move.l    a1,($10,a0)
  5185.     move.l    a1,($2C,a0)
  5186.     move.l    a1,($E0,a0)
  5187.     move.l    a1,($E4,a0)
  5188.     move.l    a1,($E8,a0)
  5189.  
  5190.     bsr    _flush020
  5191.  
  5192.     pmove.l    tc,(sp)            Save tc:
  5193.     moveq    #-1,d7
  5194.     move.l    (sp),d5
  5195.     bmi    .exitsuper        MMU in use!
  5196.     moveq    #0,d7
  5197.  
  5198.     dc.w    $F017,$4E00        pmove.q    crp,(sp)
  5199.     move.l    (sp),d3            Save crp:
  5200.     move.l    (4,sp),d4
  5201.  
  5202.     lea    (.mmufailure,pc),a1
  5203.     move.l    a1,($08,a0)
  5204.     move.l    a1,($10,a0)
  5205.     move.l    a1,($2C,a0)
  5206.     move.l    a1,($E0,a0)
  5207.     move.l    a1,($E4,a0)
  5208.     move.l    a1,($E8,a0)
  5209.  
  5210.     bsr    _flush020
  5211.  
  5212.     clr.l    (sp)            Clear translation control register
  5213.     pmove.l    (sp),tc
  5214.     nop
  5215.  
  5216.     move.l    #$80000002,(sp)        Set our crp: (was: 202)
  5217.     move.l    a2,(4,sp)
  5218.     dc.w    $F017,$4C00        pmove.q (sp),crp
  5219.  
  5220.     move.l    #$80D04780,(sp)        Enable mmu mapping:
  5221.     pmove.l    (sp),tc
  5222.  
  5223.     bsr    _flush020
  5224.  
  5225.     clr.b    (.TTableD-.TTable1,a2)    Make it map to address 0.
  5226.     bsr    _flush020
  5227.  
  5228.     lea    (.chipaddr,pc),a3    Test memory mapping a bit... :)
  5229.     move.l    a3,d0            (This should _finally_ catch
  5230.     or.l    #$D0000000,d0        nonfunctional 030 MMU)
  5231.     move.l    d0,a1
  5232.     move.l    #'MMUt',d0
  5233.     move.l    d0,(a3)
  5234.     nop
  5235.     cmp.l    (a1),d0
  5236.     bne.b    .remove
  5237.     not.l    d0            Test write mapping:
  5238.     move.l    (a1),-(sp)
  5239.     move.l    d0,(a1)
  5240.     nop
  5241.     move.l    (a3),d1
  5242.     move.l    (sp)+,(a1)
  5243.     cmp.l    d1,d0
  5244.     bne.b    .remove
  5245.     clr.l    (a3)
  5246.     nop
  5247.     tst.l    (a1)
  5248.     bne.b    .remove
  5249.  
  5250.  
  5251.     ;move.l    sp,$200.w        debug
  5252.  
  5253.     move.l    #$D0000060,(.TTableD-.TTable1,a2) Make it invalid
  5254.     bsr    _flush020
  5255.     nop                Sync pipelines
  5256.     move.l    a0,a1
  5257.     lea    $DFFFFFFC,a0        Test memory (in)validity:
  5258.     dc.w    $F010,$9C15        ptestw    #5,(a0),#7
  5259.     dc.w    $F017,$6200        pmove.w    mmusr,(sp)
  5260.     move.w    (sp),d0
  5261.     btst    #10,d0
  5262.     beq.b    .remove            Memory isn't invalid!!
  5263.  
  5264.     lea    (.busfailure,pc),a2
  5265.     move.l    a2,($08,a1)
  5266.  
  5267.     bsr    _flush020
  5268.  
  5269.     move.l    (a0),d0            Cause bus failure.
  5270. .busfproceed
  5271. .remove
  5272. .restoremmu    clr.l    (sp)            Disable mapping:
  5273.     pmove.l    (sp),tc
  5274.     nop
  5275.  
  5276.     move.l    d3,(sp)            Restore crp:
  5277.     move.l    d4,(4,sp)
  5278.     dc.w    $F017,$4C00        pmove.q (sp),crp
  5279.  
  5280.     move.l    d5,(sp)            Restore tc:
  5281.     pmove.l    (sp),tc
  5282.  
  5283.     ;move.l    #'rest',($200).w    debug
  5284.     ;move.l    d5,($204).w
  5285.  
  5286. .exitsuper    addq.l    #8,sp
  5287.  
  5288.     moveq    #0,d1
  5289.     tst.l    d7
  5290.     beq.b    .gm2_nommu
  5291.     tst.l    d5            Bit 31: On/Off!!
  5292.     bpl.b    .gm2_nommu
  5293.     moveq    #1,d1
  5294. .gm2_nommu
  5295.     move.l    (sp)+,a0        Restore VBR
  5296.     move.l    (sp)+,($E8,a0)        Restore MMU Access Level Violation Error vector
  5297.     move.l    (sp)+,($E4,a0)        Restore MMU Illegal Operation vector
  5298.     move.l    (sp)+,($E0,a0)        Restore MMU Config Error vector
  5299.     move.l    (sp)+,($2C,a0)        Restore F-Line Emul vector
  5300.     move.l    (sp)+,($10,a0)        Restore Illegal Instruction vector
  5301.     move.l    (sp)+,($08,a0)        Restore Access Fault vector
  5302. .exitall    bsr    _flush020
  5303.     rte
  5304.  
  5305. .mmufailure    lea    (.restoremmu,pc),a0    Invalid mmu table!?
  5306. .exitrt    moveq    #0,d7
  5307. .exitrt2    move.l    a0,(2,sp)
  5308. .be_exitrte    rte
  5309.  
  5310. .mmufailure_es    lea    (.exitsuper,pc),a0    Invalid mmu instruction!
  5311.     bra.b    .exitrt
  5312.  
  5313. .busfailure    bclr    #0,(10,sp)
  5314.     beq.b    .be_exitrte
  5315.     moveq    #-1,d7
  5316.     lea    (.busfproceed,pc),a0
  5317.     bra.b    .exitrt2
  5318.  
  5319.  
  5320. ; Pagesize is 8K (=1<<%1101)
  5321. ; Initial shift is 0 (%0000)
  5322. ; TIA is 4 (%0100)  [$10000000<<4=$100000000]
  5323. ; TIB is 7 (%0111)  [$00200000<<7=$10000000]
  5324. ; TIC is 8 (%1000)  [$00002000<<8=$00200000]
  5325. ; TID is 0 (%0000)
  5326. ;  TC = $80D04780
  5327. ; CRP = $80000002 TranslationTable
  5328.  
  5329.     CNOP    0,4
  5330. .TTable1    dc.l    $00000061,$10000061,$20000061,$30000061
  5331.     dc.l    $40000061,$50000061,$60000061,$70000061
  5332.     dc.l    $80000061,$90000061,$A0000061,$B0000061
  5333.     dc.l    $C0000061
  5334. .TTableD    dc.l    $D0000061
  5335.     dc.l    $E0000061,$F0000061
  5336. .TTable1End
  5337. .chipaddr    dc.l    0
  5338.  
  5339. _flush020    move.l    d0,-(sp)
  5340.     movec    cacr,d0
  5341.     or.w    #CACRF_ClearI!CACRF_ClearD,d0
  5342.     movec    d0,cacr
  5343.     move.l    (sp)+,d0
  5344.     rts
  5345.  
  5346.  
  5347.  
  5348.     CNOP    0,4
  5349. ;;    SECTION    BSS_C,BSS_C    Our megademo uses great chip-buffers :-)
  5350.  
  5351. ;;ExecBase03    ds.l    1
  5352.  
  5353. NoHW    ds.l    1
  5354. _MMUID    ds.l    1
  5355. TimerBit    ds.l    1
  5356. TimerMask    ds.l    1
  5357. CiabResource    ds.l    1
  5358. CiaIntData    ds.l    1
  5359. _GfxBase    ds.l    1
  5360.     ds.l    0    Align
  5361. _AttnFlags    ds.w    1
  5362.  
  5363. AddrChipData    ds.l    4    16 bytes
  5364.  
  5365.     END
  5366.